1 REM Ins{nt av 2839
100 REM ..............................
110 REM . ASMDATA.BAC
120 REM . -----------
130 REM .
140 REM . Detta program sparar ass-
150 REM . embler rutiner i minnet
160 REM . som DATA-satser i ett
170 REM . BASIC-program.
180 REM .
190 REM .  (c) Lars-B|rje Cid
200 REM .      Tel. 0150-539 43
210 REM .      DDK 1983-07-30 
220 REM .
230 REM ..............................
240 REM 
250 DIM T$=85%,F$=85%
260 R%=2%
270 ; CHR$(12%)TAB(15%)"ASM-DATA" : ; TAB(15%)"========"
280 ; : ; '   Sparar assembler-rutiner i'
290 ; '   minnet som  data-satser i'
300 ; '   ett BASIC-prog.'
310 ; : ; : ; '  Ange startadress: '; : INPUTLINE A$
320 ONERRORGOTO 530 : A%=VAL(LEFT$(A$,LEN(A$)-2%))
330 ; : ; : ; '  Ange slut-adress: '; : INPUTLINE A$
340 ONERRORGOTO 530 : B%=VAL(LEFT$(A$,LEN(A$)-2%))
350 IF B%<=A% THEN 530 ELSE ; 
360 ; : ; '  Progsize: '(B%-A%)/1024'Kbytes.'
370 ; : ; '  Entry ('RIGHT$(NUM$(A%),2%)') '; : INPUTLINE A$ : IF LEN(A$)=2% 380 ELSE 390
380 D%=A% : ; CHR$(8%)A%; : GOTO 400
390 D%=VAL(LEFT$(A$,LEN(A$)-2%))
400 ; : ; : ; '  CALL (JA): '; : GET Z$ : IF INSTR(1%,"Jj"+CHR$(13%),Z$) D$=':A%=CALL('+NUM$(D%)+')' ELSE D$=''
410 ; : ; '  Prognamn: '; : INPUTLINE A$ : ; : ; 
420 ONERRORGOTO 530 : PREPARE LEFT$(A$,LEN(A$)-2%) ASFILE 1%
430 ; #1%"1 FOR I%=1% TO"B%-A%"% STEP 12%:READ A%:FOR J%=0% TO 11%:READ B%"
440 ; #1%"2 POKE A%+J%,B%:NEXT J%:NEXT I%"D$
450 ONERRORGOTO 540
460 REM 
470 REM  LOOP 
480 REM 
490 FOR I%=A% TO B% STEP 12% : R%=R%+1%
500 F$=RIGHT$(NUM$(R%),2%)+' DATA'+NUM$(D%) : FOR J%=0% TO 11% : D%=D%+1% : IF D%>65535 D%=0
510 A%=PEEK(I%+J%) : T$=RIGHT$(NUM$(A%),2%)
520 F$=F$+','+T$ : NEXT J% : ; F$ : ; #1%F$ : NEXT I% : IF LEN(F$) ; #1%F$
530 ; : ; : END 
540 ; : ; "Error"ERRCODE