1 REM Ins{nt av 2314
10 ; CHR$(12)"  MULTIPEL LINJ[R REGRESSION"
20 ; 
30 DIM X(31),S(31),T(31),A(31,32)
40 ; "ANTALET K[NDA PUNKTER";
50 INPUT N
60 ; "ANTALET OBEROENDE VARIABLER";
70 INPUT V
80 X(1)=1
90 FOR I=1 TO N
100 ; "PUNKT";I
110 FOR J=1 TO V
120 ; "VARIABEL";J;
130 INPUT X(J+1)
140 NEXT J
150 ; "BEROENDE VARIABEL";
160 INPUT X(V+2)
170 FOR K=1 TO V+1
180 FOR L=1 TO V+2
190 A(K,L)=A(K,L)+X(K)*X(L)
200 S(K)=A(K,V+2)
210 NEXT L
220 NEXT K
230 S(V+2)=S(V+2)+X(V+2)^2%
240 NEXT I
250 FOR I=2 TO V+1
260 T(I)=A(1,I)
270 NEXT I
280 FOR I=1 TO V+1
290 J=I
300 IF A(J,I)<>0 THEN 350
310 J=J+1
320 IF J<=V+1 THEN 300
330 ; CHR$(12)CUR(12,12)"INGEN UNIK L\SNING!!!"
340 GOTO 820
350 FOR K=1 TO V+2
360 B=A(I,K)
370 A(I,K)=A(J,K)
380 A(J,K)=B
390 NEXT K
400 Z=1/A(I,I)
410 FOR K=1 TO V+2
420 A(I,K)=Z*A(I,K)
430 NEXT K
440 FOR J=1 TO V+1
450 IF J=I THEN 500
460 Z=-A(J,I)
470 FOR K=1 TO V+2
480 A(J,K)=A(J,K)+Z*A(I,K)
490 NEXT K
500 NEXT J
510 NEXT I
520 ; 
530 ; CHR$(12)TAB(10)"EKVATIONENS KOEFICIENTER"
540 ; "   KONSTANT";A(1,V+2)
550 FOR I=2 TO V+1
560 ; "VARIABEL(";I-1;"):";A(I,V+2)
570 NEXT I
580 P=0
590 FOR I=2 TO V+1
600 P=P+A(I,V+2)*(S(I)-T(I)*S(1)/N)
610 NEXT I
620 R=S(V+2)-S(1)^2%/N
630 Z=R-P
640 L=N-V-1
650 ; 
660 I=P/R
670 ; "R2=";I
680 ; "MULTIPLA RXY";SQR(I)
690 ; "FELET=";SQR(ABS(Z/L))
700 ; 
710 ; "INTERPOLATION 0=SLUTA"
720 P=A(1,V+2)
730 FOR J=1 TO V
740 ; "VARIABEL";J;
750 INPUT X
760 IF X=0 THEN 820
770 P=P+A(J+1,V+2)*X
780 NEXT J
790 ; "BEROENDE VARIABEL=";P
800 ; 
810 GOTO 720
820 REM 
830 END