1 REM +++++++++++++++++++++++++++++++++
2 REM ! Program ....   BTGANLYS
3 REM ! Utg}va  1.1    820208
4 REM ! av ELO-521
5 REM ! {ndrat av ELO
6 REM ! Copyright BM-CTH
7 REM ! Minne 16 Kbytes f|r flexskiva
8 REM ! Ins{nt av ELO
9 REM +++++++++++++++++++++++++++++++++
10 REM Exempel p} sk{rmorienterat program
11 REM Att anv{ndas till efteranalys av BTGPROP
100 REM ***** ECA PROP ***** Ver. 1.0 82-02-08 Bengt Hedberg BM-CTH
101 ; INP(4%)CHR$(12%)TAB(41%)'ELO-BM-CTH 8202'
102 ; TAB(9%)'----- BETONGSAMMANS[TTNING -----'TAB(55%)' = PER KUBIKMETER ='
103 ; TAB(2%)'TYP'TAB(10%)'MASSA kg'TAB(22%)'VOLYM lit.'TAB(34%)'DENS. kg/m3';
104 ; TAB(56%)'MASSA'TAB(68%)'VOLYM'
105 ; STRING$(80%,61%);CUR(3%,0%)
106 ; 'CEMENT' : ; 'SAND' : ; 'FRAK 1' : ; 'FRAK 2' : ; 'VATTEN'
107 ; STRING$(80%,45%)'SA :'CUR(12%,0%)'F{rskdensitet'
108 FOR I%=1% TO 9% : ; CUR(I%,50%)':' : NEXT I%
109 ; CUR(12%,30%)'Vct :'; : ; TAB(50%)'Luft i bruk (%):'
110 ; TAB(50%)'  "  "  btg (%):' : ; TAB(50%)'Total  luft (%):'
111 ; CUR(13%,0%)'Fast-densitet'TAB(30%)'Vlct:'
112 ; CUR(16%,0%)'CEMENT' : ; 'SAND' : ; 'FRAK 1' : ; 'FRAK 2' : ; 'VATTEN' : ; 
113 ; CUR(14%,0%)'Bruk-densitet'TAB(26%)'Bruk (%):'
114 ; CUR(11%,0%)STRING$(35%,95%)'  ANALYS  'STRING$(35%,95%);
115 FOR I%=1% TO 5%
116 ONERRORGOTO 116
117 R%=3%+I% : K%=8% : ; CUR(R%,K%); : INPUT A(I%) : B$=NUM$(A(I%))
118 GOSUB 180 : NEXT I%
119 FOR I%=1% TO 5%
120 ONERRORGOTO 120
121 R%=3%+I% : K%=32% : ; CUR(R%,K%); : INPUT D(I%) : B$=NUM$(D(I%))
122 GOSUB 180 : NEXT I%
123 ONERRORGOTO 123
124 R%=12% : K%=13% : ; CUR(R%,K%); : INPUT D : B$=NUM$(D) : GOSUB 180
125 FOR I%=1% TO 5% : IF D(I%)=0 V(I%)=0% : GOTO 127
126 V(I%)=1000%*A(I%)/D(I%)
127 NEXT I%
128 FOR I%=1% TO 5% : R%=3%+I% : K%=20% : B$=NUM$(INT(V(I%)+.5)) : GOSUB 180
129 NEXT I%
130 A(6%)=0% : FOR I%=1% TO 5% : A(6%)=A(6%)+A(I%) : NEXT I%
131 R%=10% : K%=8% : B$=NUM$(A(6%)) : GOSUB 180
132 V(6%)=0% : FOR I%=1% TO 5% : V(6%)=V(6%)+V(I%) : NEXT I%
133 R%=10% : K%=20% : B$=NUM$(INT(V(6%))) : GOSUB 180
134 D1=A(6%)/V(6%) : V=1000%/V(6%)
135 FOR I%=1% TO 5% : A1(I%)=V*A(I%) : R%=3%+I% : K%=53% : B$=NUM$(INT(A1(I%)+.5))
136 GOSUB 180 : NEXT I%
137 FOR I%=1% TO 5% : V1(I%)=V*V(I%) : R%=3%+I% : K%=65% : B$=NUM$(INT(V1(I%)+.5))
138 GOSUB 180 : NEXT I% : D1=INT(D1*1000%)
139 ; CUR(10%,69%)'1000'
140 R%=13% : K%=13% : B$=NUM$(D1) : GOSUB 180
141 R%=10% : K%=53% : B$=NUM$(D1) : GOSUB 180
142 IF A(1%)=0 THEN 143 ELSE V=INT(100*A(5%)/A(1%))/100 : ; CUR(12%,35%)V''
143 IF D1=0 THEN 144 ELSE L=(1%-D/D1) : L%=L*1000%
144 ; CUR(13%,67%)L%/10'   '
145 F=(1-L) : L1=INT(L*1000%)
146 R%=21% : K%=20% : B$=NUM$(L1) : GOSUB 180
147 FOR I%=1% TO 5% : M(I%)=F*A1(I%) : R%=15%+I% : K%=8% : B$=NUM$(INT(M(I%)+.5))
148 GOSUB 180 : NEXT I%
149 FOR I%=1% TO 5% : N(I%)=F*V1(I%) : R%=15%+I% : K%=20% : B$=NUM$(INT(N(I%)+.5))
150 GOSUB 180 : NEXT I%
151 L2%=L1/(L1+N(1%)+N(2%)+N(5%))*1000% : ; CUR(12%,67%)L2%/10'   '
152 V1=INT(100*((N(5%)+L1)/M(1%)))/100 : ; CUR(13%,35%)V1'      '
153 A=N(2%)+N(3%)+N(4%) : B=(M(2%)+M(3%)+M(4%))/2.65
154 L3%=L1+A-B : ; CUR(14%,67%)L3%/10'   '
155 B1%=N(1%)+N(2%)+N(5%)+L1 : ; CUR(14%,35%)B1%/10'     '
156 A=M(1%)+M(2%)+M(5%) : B=N(1%)+N(2%)+N(5%)+L1
157 R%=14% : K%=13% : B$=NUM$(INT(A/B*1000%)) : GOSUB 180
158 ; CUR(23%,5%)'[NDRA:  <M>-massa  <D>-dens. <F>-f{rsk <P>-print <E>-exit <N>-'
159 GET G$ : ON INSTR(1%,'MDFPEN',G$)+1% GOTO 158,160,163,166,169,182,100
160 FOR I%=1% TO 5% : R%=3%+I% : K%=8%
161 ; CUR(R%,K%); : ONERRORGOTO 162 : INPUT Q : A(I%)=Q
162 B$=NUM$(A(I%)) : GOSUB 180 : NEXT I% : GOTO 125
163 FOR I%=1% TO 5% : R%=3%+I% : K%=32%
164 ; CUR(R%,K%); : ONERRORGOTO 165 : INPUT Q : D(I%)=Q
165 B$=NUM$(D(I%)) : GOSUB 180 : NEXT I% : GOTO 125
166 R%=12% : K%=13% : ; CUR(R%,K%);
167 ONERRORGOTO 168 : INPUT Q : D=Q
168 B$=NUM$(D) : GOSUB 180 : GOTO 125
169 OPEN 'PR:' ASFILE 1 : ; CUR(23%,0%)STRING$(70%,32%)'<';
170 ; CUR(23%,0%)'SKRIV:'; : INPUTLINE P$ : ; #1 : ; #1 : ; #1
171 P$=LEFT$(P$,LEN(P$)-2%) : ; #1,TAB(6%)STRING$(74%,36%)
172 ; #1,TAB(6%)'IDENTITET: 'P$ : ; #1,TAB(6%)STRING$(74%,36%) : ; #1 : ; #1
173 P%=22528% : P1%=0% : ; CUR(23%,0%)STRING$(60%,42%)' END *****';
174 FOR I1%=1% TO 3% : FOR I2%=0% TO 7% : P$='' : P1%=P%+I2%*256%
175 FOR I3%=1% TO 74% : P$=P$+CHR$(PEEK(P1%)) : P1%=P1%+1%
176 NEXT I3% : ; #1,TAB(6%)P$ : ; #1
177 NEXT I2% : P%=P%+80% : P1%=0%
178 NEXT I1% : ; #1 : ; #1 : ; #1 : ; #1 : ; #1 : CLOSE 1
179 ; CUR(23%,0%)STRING$(79%,32%); : GOTO 158
180 IF LEN(B$)>8% B$=''
181 B$=STRING$(8%-LEN(B$),32%)+B$ : ; CUR(R%,K%)B$; : RETURN 
182 CHAIN 'MENY'