2 REM INS[NT AV 4492
10 REM ********** PROGRAMNAMN **********
20 REM ********** MULTSTOR.TAL *********
30 REM *********************************
40 REM INL[MNINGSUPPGIFT 1
50 REM 1983-11-12 PI
60 REM 
70 GOSUB 1000 : REM INLEDNINGSBILD
80 GOSUB 2000 : REM INL[GGNING AV TALEN T1 OCH T2
90 GOSUB 3000 : REM L[SNING SIFFRA F\R SIFFRA S1(I) RESP S2(J)
100 GOSUB 4000 : REM UTSKRIFT AV T1 OCH T2 I ALGORITMEN
110 GOSUB 5000 : REM UTSKRIFT AV RADERNA E(I) I ALGORITMEN
120 GOSUB 6000 : REM UTSKRIFT AV SLUTRAD R(I) I ALGORITMEN
130 GOSUB 7000 : REM J[MF\RELSE ASCII-MULT OCH ALGORITMRESULTAT
140 END 
1000 REM ************ SUBPROGRAM ************
1005 REM ********** INLEDNINGSBILD **********
1007 REM ************************************
1010 ; CHR$(12)
1020 ; ,'MULTIPLIKATION'
1030 ; ,'AV  STORA  TAL'
1040 ; ,'______________'
1050 ; CUR(8,0)'DU KOMMER NU ATT KUNNA MULTIPLICERA'
1060 ; CUR(10,0)'TV] HELTAL MED VARANDRA OCH D[RVID'
1070 ; CUR(12,0)'F] L\SNINGEN I ALGORITMFORM IFALL'
1080 ; CUR(14,0)'SK[RMEN R[CKER TILL'
1085 ONERRORGOTO 1085
1090 ; CUR(22,0)'TRYCK <RETURN> F\R FORTS[TTNING';
1100 GET S$
1110 RETURN 
2000 REM ********** SUBPROGRAM **********
2010 REM ***** INL[GGNING AV HELTALEN ***
2020 REM ********************************
2030 ; CHR$(12)
2040 ; CUR(8,0)'ANGE ETT GODTYCKLIGT HELTAL !'
2050 ONERRORGOTO 2050
2060 ; CUR(10,0)'T1 = '; : INPUT T1$ : REM T1 L[ST SOM EN STR[NG
2070 ; CUR(13,0)'ANGE [NNU ETT HELTAL ST\RRE [N DET OVAN'
2080 ONERRORGOTO 2080
2090 ; CUR(15,0)'T2 = '; : INPUT T2$ : REM T2 L[ST SOM EN STR[NG
2100 IF VAL(T2$)<VAL(T1$) GOTO 2080
2110 ONERRORGOTO 2110
2120 ; CUR(19,0)'[R TALEN KORREKTA (J/N)';
2130 GET S$ : IF S$='J' THEN RETURN 
2140 ONERRORGOTO 2140
2150 ; CUR(21,0)'VILKET TAL VILL DU [NDRA? (SVARA 1/2);'
2160 GET S$ : IF S$='1' THEN 2050 ELSE 2080
3000 REM ********** SUBPROGRAM **********
3010 REM *** L[SNING SIFFRA F\R SIFFRA ***
3020 REM *********************************
3030 REM TALEN T BESKRIVS AV SIFFERF\LDEN
3040 REM S(L),S(L-1).......S(3),S(2),S(1)
3050 REM S(1) ANGER ENTAL OCH SKRIVS SIST
3060 REM 
3070 REM INL[SNING SIFFERV[RDEN I TAL T1
3075 REM TALET T1
3080 L1=LEN(T1$) : REM ANTAL SIFFROR I T1
3090 DIM S1(L1+1) : REM DIMENSIONERING T1
3100 FOR K=1 TO L1
3110 S1(L1+1-K)=VAL(MID$(T1$,K,1))
3120 NEXT K
3125 REM TALET T2
3130 L2=LEN(T2$) : REM ANTAL SIFFROR I T2
3140 DIM S2(L2+1) : REM DIMENSIONERING T2
3150 FOR K=1 TO L2
3160 S2(L2+1-K)=VAL(MID$(T2$,K,1))
3170 NEXT K
3180 RETURN 
4000 REM ********** SUBPROGRAM **********
4010 REM ***** UTSKRIFT AV TALEN T1 *****
4020 REM ***** OCH T2 I ALGORITMEN  *****
4030 REM ********************************
4035 ; CHR$(12)
4040 REM UTSKRIFT FR]N H\GER TILL V[NSTER
4050 REM MED ETT TOMRUM MELLAN VARJE SIFFRA
4055 REM 
4060 FOR K=1 TO L2 : REM L[NGSTA TALET \VERST
4070 ; CUR(0,38-2*K)S2(K) : NEXT K
4080 FOR K=1 TO L1 : REM MINDRE TALET UNDERST
4090 ; CUR(2,38-2*K)S1(K) : NEXT K
4100 ; CUR(2,38-2*L2)'*' : REM MULT.TECKEN
4110 REM MELLANSTRECK I ALGORITMEN
4120 FOR K=1 TO 2*(L2+1) : REM DUBBLA TALL[NGDEN
4130 ; CUR(3,38-K)'_' : NEXT K
4140 RETURN 
5000 REM ********** SUBPROGRAM **********
5010 REM ***** UTSKRIFT AV RADERNA ******
5020 REM *****    I ALGORITMEN     ******
5030 REM ********************************
5040 REM UTSKRIFT ENDAST OM ALGORITMEN F]R PLATS
5050 IF L1+L2<18 THEN 5060 ELSE RETURN 
5060 REM *********************************
5070 DIM P(L2+1) : REM DIMENSIONERING
5090 FOR I=1 TO L1 : REM L1 RADER
5095 M=0 : REM F\R VARJE RADS F\RSTA MULT.[R FINNS INGEN 'GAMMAL' MINNESSIFFRA
5100 FOR J=1 TO L2 : REM L2 RADL[NGD (+1)
5120 REM D] I :  TE SIFFRAN I TALET T1 MULT
5130 REM MED J :  TE SIFFRAN I TALET T2
5140 REM ERH]LLES PRODUKTEN P(J)
5150 P(J)=S1(I)*S2(J)
5160 REM TILL P(J) L[GGES MINNESSIFFRAN M FR]N DEN J-1 :  TA PRODUKTEN
5170 P(J)=P(J)+M
5180 REM DET TAL SOM F\RS NED P] RADEN I
5190 REM BLIR "ENTALSDELEN" AV P(J)
5200 IF P(J)>=10 THEN GOSUB 5500 ELSE M=0
5210 REM ********** UTSKRIFT ***********
5260 ; CUR(2+2*I,40-2*I-2*J)P(J)
5270 NEXT J
5280 REM EV MINNESSIFFRA L[GGS IN L[NGST FRAM
5290 ; CUR(2+2*I,38-2*I-2*L2)M : P(L2+1)=M
5295 GOSUB 5700 : REM SUCCESIV ADDITION AV RADERNA
5300 NEXT I
5310 ; CUR(2*I,36-2*L1-2*L2)'+' : REM ADDTECKEN
5320 FOR J=1 TO 2*L1+2*L2+2
5330 ; CUR(3+2*L1,38-J)'_' : NEXT J
5340 RETURN 
5350 REM 
5500 REM ***** SUBPROGRAM M>0 *********
5510 M=INT(P(J)/10) : REM NY MINNESSIFFRA
5520 P(J)=P(J)-M*10 : REM "ENTALSSIFFRA"
5530 RETURN 
5540 REM ********************************
5700 REM ********** SUBPROGRAM **********
5710 REM SUCCESIV ADDITION AV RADERNA
5720 IF I=1 THEN GOSUB 5900 : REM DIM/NOLLST[LLNING
5730 M=0 : REM F\RSTA ADDITIONEN HAR M=0
5740 FOR J=1 TO L2+1
5750 K=I+J-1
5760 S(K)=S(K)+P(J)+M
5770 M=INT(S(K)/10) : REM NY MINNESSIFFRA
5780 S(K)=S(K)-M*10 : REM "ENTALSSIFFRA"
5790 NEXT J
5800 RETURN 
5900 REM ********** SUBPROGRAM **********
5910 DIM S(L1+L2+1) : REM DIMENSIONERING
5920 REM NOLLST[LLNING SUMMAVARIABELN S
5930 FOR J=1 TO L1+L2+1
5940 S(J)=0 : NEXT J
5950 RETURN 
6000 REM ********** SUBPROGRAM **********
6010 REM ***** UTSKRIFT AV SLUTRAD ******
6020 REM *****    I ALGORITMEN     ******
6030 REM ********************************
6040 REM UTSKRIFT ENDAST OM ALGORITMEN F]R PLATS
6050 IF L1+L2<18 THEN 6060 ELSE RETURN 
6060 FOR J=1 TO L1+L2+1
6070 ; CUR(4+2*L1,38-2*J)S(J)
6080 NEXT J
6090 RETURN 
7000 REM ********** SUBPROGRAM **********
7010 REM ***** J[MF\RELSE ASCII-MULT *****
7020 REM ***** OCH ALGORITMRESULTAT  *****
7030 REM *********************************
7040 T$=MUL$(T1$,T2$,0)
7050 L=LEN(T$)
7060 DIM R(L)
7070 REM ***** L[SNING SIFFRA F\R SIFFRA
7080 FOR K=1 TO L
7090 R(L+1-K)=VAL(MID$(T$,K,1))
7100 NEXT K
7110 REM ***** UTSKRIFT UNDER ALGORITM
7120 IF L1+L2<18 THEN 7130 ELSE 7500
7130 FOR K=1 TO L
7140 ; CUR(6+2*L1,38-2*K)R(K)
7150 NEXT K
7155 RETURN 
7500 REM ***** UTSKRIFT VID STOR PRODUKT*****
7505 ; 'VILL DU SE FACIT ?'; : GET S$ : ; CHR$(12)
7510 ; CUR(11,12)'FACITV[RDE'
7520 ; CUR(13,0)T$
7530 RETURN