10 REM +++++++++++++++++++++++++++++++++
20 REM ! Program ....   CMWKONTO
30 REM ! Utg}va  2.4    850120
40 REM ! av (c) Michael Widell
50 REM ! Minne 16 Kbytes f|r flexskiva
60 REM ! Ins{nt av Michael Widell
70 REM +++++++++++++++++++++++++++++++++
80 REM 80-kolumners bildsk{rm (Tkn-80)
90 REM m}ste vara monterad.
100 REM *** Huvud-meny CMWKONTO Ver 2.4 ***
110 A=INP(4)
120 DIM P$(12)=12,M$=15
130 RESTORE 
140 C=PEEK(22774)+PEEK(22775)*256
150 M$='' : FOR I=22768 TO 22773
160 V=PEEK(I) : M$=M$+CHR$(V)
170 C=C-V : NEXT I
180 IF C<>0 THEN M$=''
190 GOSUB 530
200 IF C=0 THEN 300
210 ; CUR(7,16)'Datum: '; : INPUTLINE M$
220 IF LEN(M$)<>8 THEN 210
230 M$=LEFT$(M$,6)
240 C=0 : FOR I=1 TO 6
250 V=ASC(RIGHT$(M$,I)) : IF V<48 OR V>57 THEN 210
260 C=C+V
270 POKE 22767+I,V : NEXT I
280 POKE 22774,C,SWAP%(C)
290 GOSUB 530
300 A=-1 : ONERRORGOTO 350
310 READ A$,P$(A+1)
320 A=A+1
330 ; TAB(16)A'. '+A$
340 ; : GOTO 310
350 ; TAB(16)' S. Slut'
360 ; CUR(22,17)'V[LJ ALTERNATIV ';
370 GET A$
380 IF A$='S' OR A$='s' THEN ; CHR$(12); : END 
390 ONERRORGOTO 370
400 V=VAL(A$)
410 ONERRORGOTO 0
420 IF V>A THEN 370
430 IF V=0 THEN POKE 22774,PEEK(22774)+1 : GOTO 130
440 CHAIN P$(V)
450 DATA '[ndring av datum',''
460 DATA 'Inmatning av transaktioner',KONTOINM
470 DATA 'Utlistning och {ndring av transaktioner',KONTOLIS
480 DATA 'Konto-utdrag f|r aktuell period',KONTOUTD
490 DATA 'Bokslut vid m}nads-skifte',KONTOBOK
500 DATA 'Budgetering och kontoplanering',KONTOBUD
510 DATA 'Backup f|r aktuell period',KONTOBCK
520 DATA 'Initiering av printer-drivrutin',SERIE2
530 ; CHR$(12)TAB(17)'CMW-Konto Meny      Datum: 'M$
540 ; TAB(15)CHR$(151)STRING$(35,35) : ; 
550 RETURN