10 REM +++++++++++++++++++++++++++++++++
20 REM ! Program ....   KONTOBCK
30 REM ! Utg}va  1.2    850120
40 REM ! av (c) Michael Widell
50 REM ! Minne 16 Kbytes f|r flexskiva
60 REM ! Ins{nt av Michael Widell
70 REM +++++++++++++++++++++++++++++++++
80 REM 80-kolumners bildsk{rm (Tkn-80)
90 REM m}ste vara monterad.
100 REM *** Backup f|r aktuell period KONTOBCK Ver 1.2 ***
110 A0%=INP(4) : GOSUB 520
120 FOR I=22768 TO 22773
130 D$=D$+CHR$(PEEK(I))
140 NEXT I
150 ; : ; TAB(10)'Backup-datum: 'D$;
160 ; TAB(40)'[r detta Ok ';
170 INPUT A$ : IF (ASC(A$) AND 223%)<>74% THEN 500
180 ; : ; TAB(40)'Absolut s{ker ';
190 INPUT A$ : IF (ASC(A$) AND 223%)<>74% THEN 500
200 ONERRORGOTO 230
210 NAME 'KPOSTER.BCK' AS 'KPOSTER.KIL'
220 NAME 'KLISTA.BCK' AS 'KLISTA.KIL'
230 ONERRORGOTO 0
240 OPEN 'KLISTA.DAT' ASFILE 1%
250 PREPARE 'KLISTA.BCK' ASFILE 2%
260 INPUT #1%,A0%
270 ; #2%,A0%
280 FOR I%=1% TO A0%
290 INPUT #1%,K0$
300 INPUTLINE #1%,B0$ : B0$=LEFT$(B0$,LEN(B0$)-2%)
310 INPUT #1%,M0,B0%,S0
320 ; #2%,K0$ : ; #2%,B0$ : ; #2%,M0 : ; #2%,B0% : ; #2%,S0
330 NEXT I% : CLOSE 1 : CLOSE 2
340 OPEN 'KPOSTER.DAT' ASFILE 1%
350 PREPARE 'KPOSTER.BCK' ASFILE 2%
360 ONERRORGOTO 420
370 INPUT #1%,A$,A1$
380 INPUTLINE #1%,A0$ : A0$=LEFT$(A0$,LEN(A0$)-2%)
390 INPUT #1%,J
400 ; #2%,A$ : ; #2%,A1$ : ; #2%,A0$ : ; #2%,J
410 GOTO 370
420 ; #2%,' ' : ; #2%,D$ : ; #2%,'BACKUP-DATUM' : ; #2%,0%
430 CLOSE 1% : CLOSE 2%
440 ONERRORGOTO 480
450 KILL 'KLISTA.KIL'
460 KILL 'KPOSTER.KIL'
470 ONERRORGOTO 0
480 ; : ; : ; TAB(18)'### BACKUP-TAGNINGEN KLAR ###'
490 CHAIN 'CMWKONTO'
500 ; : ; : ; TAB(16)'#### Backup-tagning utf|rs ej ####'
510 GOTO 490
520 ; CHR$(12);TAB(24)'CMW-Konto Backup'
530 ; TAB(22)CHR$(151)STRING$(18,35) : ; : RETURN