10 REM +++++++++++++++++++++++++++++++++
20 REM ! Program ....   KONTOBOK
30 REM ! Utg}va  2.3    850120
40 REM ! av (c) Michael Widell
50 REM ! Minne 16 Kbytes f|r flexskiva
60 REM ! Ins{nt av Michael Widell
70 REM +++++++++++++++++++++++++++++++++
80 REM 80-kolumners bildsk{rm (Tkn-80)
90 REM m}ste vara monterad.
100 REM *** Bokslut KONTOBOK Ver 2.3 ***
110 DIM M$(12)=25
120 A0%=INP(4) : GOSUB 640
130 FOR I=22768 TO 22773
140 D$=D$+CHR$(PEEK(I))
150 NEXT I
160 M%=VAL(MID$(D$,3,2))
170 IF VAL(MID$(D$,5,2))<15% M%=M%-1% : IF M%=0% M%=12%
180 M0%=M%-1% : IF M0%<1% M0%=12%
190 IF M%<1% OR M%>12% M%=0% : M0%=0%
200 FOR I%=0% TO 12%
210 READ M$(I%)
220 NEXT I%
230 ; : ; TAB(10)'Vill du g|ra bokslut f|r 'M$(M%)' m}nad ';
240 INPUT A$ : IF (ASC(A$) AND 223%)<>74% THEN 620
250 ; : ; TAB(10)'Har du gjort printerutskrift av 'M$(M%)' m}nads uppgifter ';
260 INPUT A$ : IF (ASC(A$) AND 223%)<>74% THEN 620
270 ; : ; TAB(10)'Du {r medveten om att 'M$(M0%)' m}nads uppgifter tas bort';
280 INPUT A$ : IF (ASC(A$) AND 223%)<>74% THEN 620
290 OPEN 'KLISTA.DAT' ASFILE 1
300 INPUT #1,A0%
310 DIM K0$(A0%)=10,B0$(A0%)=40,M0(A0%),B0%(A0%),S0(A0%)
320 FOR I%=1% TO A0%
330 INPUT #1,K0$(I%)
340 INPUTLINE #1,A$ : B0$(I%)=LEFT$(A$,LEN(A$)-2%)
350 INPUT #1,M0(I%),B0%(I%),S0(I%)
360 NEXT I% : CLOSE 1
370 ONERRORGOTO 400
380 KILL 'KPOSTER.OLD'
390 KILL 'KLISTA.OLD'
400 ONERRORGOTO 440
410 NAME 'KPOSTER.DAT' AS 'KPOSTER.OLD'
420 NAME 'KLISTA.DAT' AS 'KLISTA.OLD'
430 ONERRORGOTO 0
440 S%=0% : FOR I%=1% TO A0%
450 S0(I%)=S0(I%)+M0(I%)
460 M0(I%)=B0%(I%)
470 S%=S%+B0%(I%)
480 NEXT I%
490 PREPARE 'KLISTA.DAT' ASFILE 1
500 ; #1,A0%
510 FOR I%=1% TO A0%
520 ; #1,K0$(I%) : ; #1,B0$(I%) : ; #1,M0(I%) : ; #1,B0%(I%) : ; #1,S0(I%)
530 NEXT I% : CLOSE 1
540 PREPARE 'KPOSTER.DAT' ASFILE 1
550 ; #1,'L\N'
560 ; #1,D$
570 ; #1,'INS[TTNING AV L\N'
580 ; #1,-S%
590 CLOSE 1
600 ; : ; : ; TAB(22)'### BOKSLUTET KLART ###'
610 CHAIN 'CMWKONTO'
620 ; : ; : ; TAB(18)'#### Bokslutet utf|rs ej ####'
630 GOTO 610
640 ; CHR$(12);TAB(24)'CMW-Konto Bokslut'
650 ; TAB(22)CHR$(151)STRING$(19,35) : ; : RETURN 
660 DATA 'Icke Existerande',Januari,Februari,Mars,April,Maj
670 DATA Juni,Juli,Augusti,September,Oktober,November,December