10 REM +++++++++++++++++++++++++++++++++
20 REM ! Program ....   KONTOUTD
30 REM ! Utg}va  2.0    850120
40 REM ! av (c) Michael Widell
50 REM ! Minne 16 Kbytes f|r flexskiva
60 REM ! Ins{nt av Michael Widell
70 REM +++++++++++++++++++++++++++++++++
80 REM 80-kolumners bildsk{rm (Tkn-80)
90 REM m}ste vara monterad.
100 REM *** Konto-utdrag KONTOUTD Ver 2.0 ***
110 A0%=INP(4) : GOSUB 440
120 FOR I=22768 TO 22773
130 M$=M$+CHR$(PEEK(I))
140 NEXT I
150 GOSUB 440
160 ; : ; : ; : ; : ; : ; 'Printerutskrift (N) '; : GET A$
170 IF A$='J' OR A$='j' THEN F%=5% ELSE F%=0%
180 OPEN 'KLISTA.DAT' ASFILE 1
190 INPUT #1,A0%
200 DIM K0$(A0%)=10,M0(A0%),B0%(A0%),S0(A0%),M$=10
210 FOR I%=1% TO A0%
220 INPUT #1,K0$(I%),A$,M0(I%),B0%(I%),S0(I%)
230 NEXT I% : CLOSE 1
240 OPEN 'PR:' ASFILE F%
250 GOSUB 440
260 GOSUB 570
270 FOR I%=1% TO A0%
280 IF I%/16%=I%/16 AND F%=0% THEN GOSUB 490 : GOSUB 440 : GOSUB 570
290 ; #F%,K0$(I%);
300 X=B0%(I%) : B0%=B0%+B0%(I%) : GOSUB 510 : ; #F%,TAB(15)A$;
310 X=M0(I%) : M0=M0+M0(I%) : GOSUB 510 : ; #F%,TAB(32)A$;
320 X=S0(I%) : S0=S0+S0(I%) : GOSUB 510 : ; #F%,TAB(49)A$;
330 X=S0(I%)+M0(I%) : GOSUB 510 : ; #F%,TAB(66)A$
340 NEXT I%
350 ; #F%,STRING$(77,95)
360 ; #F%,'TOTAL';
370 X=B0% : GOSUB 510 : ; #F%,TAB(15)A$;
380 X=M0 : GOSUB 510 : ; #F%,TAB(32)A$;
390 X=S0 : GOSUB 510 : ; #F%,TAB(49)A$;
400 X=S0+M0 : GOSUB 510 : ; #F%,TAB(66)A$
410 IF F%=0% GOSUB 490 ELSE ; #F% : ; #F% : ; #F%
420 CLOSE F%
430 CHAIN 'CMWKONTO'
440 IF F%=0% ; CHR$(12);
450 ; #F%,TAB(22)'CMW-Konto Kontoutdrag 'M$
460 ; #F%,TAB(20);
470 IF F%=0% ; CHR$(151)STRING$(30,35) ELSE ; #F%,' 'STRING$(30,232)
480 ; #F% : RETURN 
490 ; CUR(23,0)'Tryck RETURN n{r du l{st f{rdigt';
500 GET A$ : IF A$<>CHR$(13) THEN 500 ELSE RETURN 
510 A$=NUM$(X)
520 IF X=INT(X) THEN A$=A$+'.00' ELSE A$=A$+'00'
530 A$=LEFT$(A$,INSTR(1%,A$,'.')+2)
540 A$=SPACE$(9%-LEN(A$))+A$
550 I9%=0%
560 RETURN 
570 ; #F%,'Konto:';TAB(16)'Budgeterat:';TAB(31)'M}nads-saldo:';TAB(49)'Accumulerat:';TAB(68)'Saldo:'
580 ; #F%,'------';TAB(16)'-----------';TAB(31)'-------------';TAB(49)'------------';TAB(66)'----------'
590 RETURN