1 REM +++++++++++++++++++++++++++++++++
2 REM ! Program ....   INUTFIL
3 REM ! Utg}va  1.1    81-03-17
4 REM ! av (c) JAN K[RRB[CK  765
5 REM ! TEL. 08/38 62 85 , 89 19 10
6 REM ! Minne 16 Kbytes f|r flexskiva
7 REM ! screenat av Tom Sj|berg 2401
8 REM ! Ins{nt av 765
9 REM +++++++++++++++++++++++++++++++++
10 REM ETT PROGRAM SOM L[SER OCH
11 REM SKRIVER TEXT FILER.ANV[NDBART!!
12 REM 
100 DIM A$=119%
101 A%=0% : T%=0% : ; CHR$(12%)'* ABC80 INFIL/UTFIL Vers 1.1 *' : ; : ; 'Skriva/l{sa'
102 ; ' Infil/utfil (I/U) '; : INPUT T$ : IF LEN(T$)>1% GOTO 100 ELSE I%=20%
103 DEFFNA%(X$,Y$)=INSTR(1%,T$,X$)+INSTR(1%,T$,Y$)
104 IF FNA%('U','u') T$='tfil' : GOSUB 127 : GOTO 115 ELSE IF FNA%('I','i') T$='nfil' : GOSUB 127 ELSE GOTO 131
105 GOSUB 125
106 ONERRORGOTO 107 : OPEN T$ ASFILE 2% : GOTO 130
107 PREPARE T$ ASFILE 2%
108 ; 'Avsluta din text med * p} ny rad'
109 ; '>'; : INPUTLINE A$
110 A$=LEFT$(A$,LEN(A$)-2%)
111 IF LEN(A$)>38% ; CHR$(7%)'F|r l}ng text skriv om raden !!!' : GOTO 109
112 IF A$='*' ; : GOTO 123
113 ; #2%,A$ : ; 
114 A%=A%+1% : GOTO 109
115 GOSUB 125 : ; 'Printer (nej) '; : INPUT F$ : ; 
116 F%=-(F$='J')-(F$='j') : OPEN 'PR:' ASFILE F%
117 IF F% ONERRORGOTO 118 : ; 'Tabantal (0) '; : INPUT T%
118 ONERRORGOTO 129 : OPEN T$ ASFILE 2%
119 ONERRORGOTO 123 : INPUTLINE #2%,A$
120 A$=LEFT$(A$,LEN(A$)-2%)
121 IF PEEK(65011%)=23% GET T$
122 IF ASC(T$)<>4% ; #F%,TAB(T%)A$ : A%=A%+1% : GOTO 119
123 CLOSE 2% : ; : ; 'Antal rader:'A%'  <Tryck p} return!>';
124 GET T$ : IF ASC(T$)=13% GOTO 101 ELSE 124
125 I%=9% : ; : ; 'Filnamn '; : INPUT T$ : IF T$='' GOTO 131
126 IF INSTR(1%,T$,'.') ; : GOTO 128 ELSE T$=T$+'.TXT'
127 POKE 65011%,PEEK(65011%)-1%,I% : ; T$ : IF I%<20% ; 
128 RETURN 
129 ; CHR$(7%)'Hittar ej filen !!!'; : GET T$ : GOTO 100
130 ; CHR$(7%)'Filen 'T$' finns redan !!!'; : GET T$ : GOTO 100
131 END