1 REM Ins{nt av 3374
10 REM +-------------------------------
12 REM !
14 REM ! / SIZE.BAS /
16 REM ! / ver 2.02 / 2180 bytes /
18 REM !
20 REM ! Ett program gjort 830401 av
22 REM ! B. Gustavsson, Osby
24 REM ! Osby Mikrodator Service
26 REM ! tel. 0479-10620
28 REM !
30 REM ! Medlemsnr. 3374
32 REM !
34 REM ! 16kB och flexskiva
36 REM !
38 REM +-------------------------------
40 REM !
42 REM !  SIZE.BAC skriver in storlek
44 REM !  p} en fil i LIB-sp}ret, men
46 REM !  inte i back up-sp}ret.
48 REM !
50 REM !  Passar att g|ra snabba
52 REM !  LIB-program till. Man m}ste
54 REM !  f|rst}s uppdatera n{r man
56 REM !  {ndrat en fil.
58 REM !
60 REM !  ABC's UFD-dos anv{nder sig
62 REM !  av denna plats i LIB-sp}ret.
64 REM !
66 REM !  Har man dessutom tillg}ng
68 REM !  till SUPERBASIC fr}n
70 REM !  NYFORS DATA tel. 0760/38025
72 REM !  s} har denna mycket geniala
74 REM !  produkt ett kommando LIB
76 REM !  som l{ser av filstorlekarna
78 REM !  just d{r detta program l{gger
80 REM !  upp dem.
82 REM !
84 REM +-------------------------------
86 REM 
88 REM 
90 GOSUB 158 : REM - |verskrift
92 GOSUB 146 : REM - superbasic ?
94 GOSUB 156 : REM - forts{tt !
96 GOSUB 158 : REM - |verskrift
98 FOR D%=0% TO 6%
100 POKE -767%,D%
102 ; CUR(3%,8%)'Drive nr:'D%
104 FOR I%=0% TO 7%
106 Z%=CALL(24678%,(16%+I%)*32%)
108 ; CUR(3%,20%)'sp}r:'; : IF PEEK(-747%) ; '    ' ELSE ; 16%+I%
110 ; CUR(8%+D%,5%)'DR';D%;': ';
112 FOR B=62720 TO 62960 STEP 16
114 IF PEEK(B)=255% 132
116 R=PEEK(B)*256%+PEEK(B+1)
118 POKE 64512%,6%,112%,195%,15%,96%
120 Z%=CALL(64512,R) : IF PEEK(-747%) 136
122 Y%=0% : FOR J=0 TO 254 STEP 2
124 IF PEEK(J-1020)=255% 130
126 V%=PEEK(J-1019)
128 Y%=Y%+(V% AND 31)+1 : NEXT J
130 POKE B+2,Y%
132 NEXT B
134 Z%=CALL(24675%,(16%+I%)*32%)
136 NEXT I%
138 IF PEEK(-747%) ; CUR(8%+D%,11%)'-' ELSE ; CUR(8%+D%,11%)'ok'
140 NEXT D%
142 GOSUB 146 : REM - superbasic ?
144 END 
146 IF PEEK(16388%)=175% A$='LIB' : GOSUB 150 : REM - CMD 'LIB'
148 RETURN 
150 ; CUR(21%,0%)'Vill du se LIB-listan ? (J/N) '; : GET L$ : ; L$
152 IF L$='j' OR L$='J' ; CHR$(12%) : CMD A$
154 RETURN 
156 ; CUR(22%,0%)'Tryck RETURN n{r du vill forts{tta.'; : GET \4$ : IF \4$<>CHR$(13%) 156 ELSE RETURN 
158 ; CHR$(12%)CUR(0%,0%)'***** Ger filstorlek i LIB-sp}ret *****'
160 RETURN