1 REM +++++++++++++++++++++++++++++++++
2 REM ! Program ....   LABYRINT.GRF
3 REM ! Utg}va  1.1    1984 05 21
4 REM ! av (c) TOM SJ\BERG
7 REM ! Minne 16 Kbytes
8 REM ! Ins{nt av 2401
9 REM +++++++++++++++++++++++++++++++++
10 REM Ritar olika (RND) labyrinter varje g}ng.
11 REM Kan anv{ndas f|r egna spel.
12 REM Fungerar p} b}de 40 o 80 tkn.
13 REM F\RS\K KLURA UT ALGOTITMEN !!
14 REM DEN [R OTROLIG !!
15 REM S{tt REM framf|r rad 229 f|r tidtagning.
100 REM ---- init tidtag ----
101 DEFFNK=((PEEK(65010) XOR 255%)*256%+(PEEK(65009) XOR 255%))*5.12+(PEEK(65008) XOR 255%)/50
102 ; CHR$(12%)
104 ; CHR$(7%) : S1=FNK
200 REM ---- start labyrint ----
201 DEFFNA%=CALL(65408%,A%) : DEFFNB%=CALL(65408%,B%)
202 DEFFNB%=CALL(65408%,B%)
203 ; CHR$(7%) : S1=FNK
204 RANDOMIZE 
205 POKE 65408,235,124,38,0,41,17,116,3,25,134,35,102,111,201
206 DIM A%(3%)
207 A%(0%)=2% : A%(1%)=-2%*256% : A%(2%)=-2% : A%(3%)=2%*256%
208 W%=127% : H%=32% : A%=3%+3*256%
209 ; CHR$(12%) : FOR I%=0% TO 22% : ; CUR(I%,1%)CHR$(151%)STRING$(PEEK(529%)-3%,W%); : NEXT I%
210 REM -----------
211 POKE FNA%,4% OR 64%
212 J%=RND*4% : X%=J%
213 B%=A%+A%(J%)
214 IF PEEK(FNB%)<>W% GOTO 217
215 POKE FNB%,J% OR 64% : A%=A%+A%(J%)/2%
216 POKE FNA%,H% : A%=B% : GOTO 212
217 J%=(J%+1%)*(-(J%<3%)) : IF J%<>X% 213
218 J%=PEEK(FNA%) AND 191% : POKE FNA%,H%
219 IF J%<4% THEN A%=A%-A%(J%) : GOTO 212
220 REM 
221 REM -----------------------------
222 POKE FNA%,127% : J%=3%
223 B%=A%+A%(J%)/2%
224 IF PEEK(FNB%)<>H% GOTO 227
225 POKE FNB%,127% : POKE FNA%,H%
226 A%=B% : J%=(J%+2%)+4%*(J%>1%)
227 J%=(J%-1%)-4%*(J%=0%)
228 REM FOR I=0 TO 50 :   NEXT I ev f|rdr|jning 
229 GOTO 223
230 REM  s{tt REM framf|r 229 s} f}r du tidtagning p} utf|randet
1000 S2=FNK : ; CHR$(7%)
1010 S3=S2-S1 : ; CUR(23,0)'>>> TID ='S3' sek <<<  RETURN';
1020 GET G$ : GOTO 104