10 REM .  SAVE LINDA
100 REM ===============================
110 REM Program....     LINDA.BAC
120 REM Datum......     85-03-13
130 REM F|rfattare.     David Andersson
140 REM Medlem nr..     5201
150 REM 
160 REM Detta {r progr. LINDAPIC.800
170 REM fr}n kasset #12 konverterat
180 REM till ABC80-basic och -grafik.
190 REM Bl.a f|r att f} plats i 16K RAM
200 REM ligger data-satserna i en
210 REM separat fil; LINDA.DAT
220 REM 
230 REM Ursprunglig f|rfattare {r
240 REM Jan Gustafsson (medlem 4443).
250 REM 
260 REM P} sk{rmen ritas en l{cker tjej
270 REM med namnet Linda.
280 REM 
290 REM L]T DITT \GA FR\JDAS
300 REM ===============================
310 REM 
1000 REM C$() MAPPAS P] BILDMINNET, M]STE LIGGA F\RST I VARIABELLISTAN.
1010 DIM C$(23%)=80%
1020 C0%=PEEK(65065%)+SWAP%(PEEK(65066%))
1030 C1%=PEEK(C0%+4%)+SWAP%(PEEK(C0%+5%))
1040 L%=PEEK(590%) : REM 40 ELLER 80 TECKENS SK[RM
1050 FOR C2%=0% TO 23%
1060 POKE C1%+C2%*6%+2%,PEEK(884%+C2%*2%),PEEK(885%+C2%*2%)
1070 NEXT C2%
1080 A9%=96% : REM rader i scroll minnet
1090 DIM A$(A9%)=L%*.9
1100 FOR A%=0% TO A9% : A$(A%)=CHR$(23%)+SPACE$(L%*.9-1%) : NEXT A%
1110 A0%=0% : ; CHR$(12%) : GOSUB 3200
2000 REM 
2010 X8%=-7% : X9%=82% : Y8%=-60% : Y9%=225%
2020 OPEN 'LINDA.DAT' ASFILE 1%
2030 REM big loop
2040 INPUT #1%,M$,X%,Y%
2050 IF M$='L' GOSUB 5000 : GOTO 2030
2060 IF M$='D' GOSUB 4000 : GOTO 2030
2070 IF M$='C' C%=X% : GOTO 2030
2080 GOSUB 3300
2090 REM end loop
2100 CLOSE 1%
2110 ; CUR(10%,L%/2%-10%)'7###################k'
2120 ; CUR(11%,L%/2%-10%)'5                   j'
2130 ; CUR(12%,L%/2%-10%)'5   SCROLLA BILDEN  j'
2140 ; CUR(13%,L%/2%-10%)'5        MED        j'
2150 ; CUR(14%,L%/2%-10%)'5   PILTANGENTERNA  j'
2160 ; CUR(15%,L%/2%-10%)'5                   j'
2170 ; CUR(16%,L%/2%-10%)'upppppppppppppppppppz'
2200 REM 
2210 ; CUR(21%,0%); : GET A$
2220 IF A$=CHR$(8%) IF A0%>0% A0%=A0%-1% : GOSUB 3200
2230 IF A$=CHR$(9%) IF A0%+23%<A9% A0%=A0%+1% : GOSUB 3200
2240 GOTO 2200
2250 END 
3000 REM  SCALE X%,Y%
3010 X%=(X%-X8%)*(L%*2%-2%)/240*2+2
3020 Y%=(Y9%-Y%)
3030 RETURN 
3100 REM  SET DOT X3%,Y3%
3110 IF Y3%>=A0%*3% AND Y3%<A0%*3%+72% GOTO 3160
3120 GOSUB 3300
3130 IF Y3%<A0%*3% LET A%=A0%-1% ELSE IF Y3%>=A0%*3%+72% LET A%=A0%+1% ELSE 3160
3140 A0%=A% : IF A0%<0% A0%=0% ELSE IF A0%+23%>A9% A0%=A9%-23%
3150 GOSUB 3200 : GOTO 3130
3160 SETDOT Y3%-A0%*3%,X3%
3170 RETURN 
3200 REM  SKRIV A$() TILL SK[RM
3210 FOR Z%=0% TO 23% : C$(Z%)=A$(Z%+A0%) : NEXT Z%
3220 RETURN 
3300 REM  SPARA SK[RM I A$()
3310 FOR Z%=0% TO 23% : A$(Z%+A0%)=C$(Z%) : NEXT Z%
3320 RETURN 
4000 REM  SET DOT X%,Y%
4010 GOSUB 3000
4020 X3%=X% : Y3%=Y% : GOSUB 3100
4030 X0%=X% : Y0%=Y%
4040 RETURN 
5000 REM  LINE TO X%,Y%
5010 GOSUB 3000
5020 IF X%=X0% AND Y%=Y0% THEN X3%=X% : Y3%=Y% : X0%=X% : Y0%=Y% : GOTO 3100
5030 IF ABS(X%-X0%)<ABS(Y%-Y0%) THEN 5100
5040 IF X%<X0% X1%=X% : X2%=X0% : Y1%=Y% : Y2%=Y0% ELSE X1%=X0% : X2%=X% : Y1%=Y0% : Y2%=Y%
5050 FOR X3%=X1% TO X2%
5060 Y3%=.5+Y1%+(Y2%-Y1%)*(X3%-X1%)/(X2%-X1%) : GOSUB 3100
5070 NEXT X3%
5080 GOTO 5200
5100 REM 
5110 IF Y%<Y0% X1%=X% : X2%=X0% : Y1%=Y% : Y2%=Y0% ELSE X1%=X0% : X2%=X% : Y1%=Y0% : Y2%=Y%
5120 FOR Y3%=Y1% TO Y2%
5130 X3%=.5+X1%+(X2%-X1%)*(Y3%-Y1%)/(Y2%-Y1%) : GOSUB 3100
5140 NEXT Y3%
5200 REM 
5210 X0%=X% : Y0%=Y%
5220 RETURN