1 REM Ins{nd av Bo Wernfeldt <4584>    1988-01-23 17.43.16 (KERMIT)
10 REM ***********ABC*80***************
15 REM *                              *
20 REM *     * *   BIORYTM   * *      *
25 REM *                              *
30 REM *      fr}n  Mikrodatorn       *
35 REM *                              *
40 REM ****bo*******************84*****
45 REM 
50 REM >  D1%  D2%  D3  D4%  D%  F%  I%
55 REM >  J%  K%  M1%  M4%  M%  P
60 REM >  P$()  T%()  ]1  ]3  ]4  ]
65 REM 
100 DIM T%(13%),P$(40%)=1%
105 ; CHR$(12%)'Mata in f|delsedatum!'
110 ; 'Format XX,YY,ZZ (]R,M]NAD,DAG)'
115 INPUT ],M%,D% : ; 
120 ; 'N{r vill du starta BIORYTMEN?'
125 ; 'Samma format som ovan.'
130 INPUT ]1,M1%,D1% : ; 
135 ; 'Hur m}nga dagars BIORYTM?'
140 INPUT D2% : ; : D3=0% : IF M%>2% 150
145 IF INT(]/4%)-]/4%=0% D3=1%
150 FOR I%=1% TO 12% : READ T%(I%) : NEXT I%
155 D3=T%(M%)-D%+D3 : FOR I%=M%+1% TO 12%
160 D3=T%(I%)+D3 : NEXT I% : ]3=]
165 ]3=]3+1% : IF ]3>=]1 THEN 185
170 IF INT(]3/4%)-]3/4%=0% 180
175 D3=D3+365% : GOTO 165
180 D3=D3+366% : GOTO 165
185 IF M1%<=2% 195
190 IF INT(]1/4%)-]1/4%=0% D3=D3+1%
195 FOR I%=1% TO M1%-1%
200 D3=T%(I%)+D3 : NEXT I% : D3=D1%+D3
205 ; 'Fysiska cykel markeras med F' : ; 
210 ; 'K{nslocykeln markeras med K' : ; 
215 ; 'Intellektulla cykeln markeras med I'
220 ; : ; 'Tryck p} RETURN f|r utmatning';
225 ; ' av BIORYTM-kurvorna' : GET P$(0%)
230 ; CHR$(12%)' Datum'TAB(11%)'ner'TAB(23%);
235 ; 'noll'TAB(37%)'upp' : ; STRING$(40%,45%)
240 M4%=M1% : D4%=D1% : ]4=]1 : P=6.28318
245 F%=(SIN((D3/23-INT(D3/23))*P)+1%)*14%+11%
250 K%=(SIN((D3/28-INT(D3/28))*P)+1%)*14%+11%
255 I%=(SIN((D3/33-INT(D3/33))*P)+1%)*14%+11%
260 FOR J%=0% TO 39% : P$(J%)=' ' : NEXT J%
265 P$(F%)='F' : P$(K%)='K' : P$(I%)='I'
270 ; NUM$(]4)+NUM$(M4%)+NUM$(D4%);
275 ; TAB(9%); : FOR J%=9% TO 39% : ; P$(J%);
280 NEXT J% : ; : IF D2%=1% 325
285 D2%=D2%-1% : D3=D3+1% : D4%=D4%+1%
290 IF M4%=2% IF D4%=29% IF INT(]4/4%)-]4/4=0% 245
300 IF D4%<=T%(M4%) 245
305 M4%=M4%+1% : D4%=1% : IF M4%<=12% 245
310 M4%=1% : ]4=]4+1% : GOTO 245
315 DATA 31,28,31,30,31,30,31,31
320 DATA 30,31,30,31
325 END 
330 REM 2327 byte + 505 var