10 REM +++++++++++++++++++++++++++++++++
11 REM ! Program ....   MX80PR
12 REM ! Utg}va  1.0    1982-02-07
13 REM ! av (c) Carl K|vamees
14 REM ! Minne 16 Kbytes
15 REM ! Ins{nt av 767
16 REM +++++++++++++++++++++++++++++++++
17 REM 
18 REM Screened by +TCP+
19 REM 
20 REM +-------------------------------
21 REM !
22 REM !   Subrutin som dumpar sk{rmen
23 REM !   p} printer s} som MX80 eller
24 REM !   liknande som har grafiken 
25 REM !   mellan CHR$(160-223).
26 REM !
27 REM !   Det {r ganska l{tt att {ndra
28 REM !   pgm'et s} man kan ange tex 
29 REM !   filnr, dumpning mellan rader
30 REM !   dumpning mellan kolumner.
31 REM !
32 REM !      VARIABELER
33 REM !      ==========
34 REM !  In- 
35 REM !     I%=TAB till PR
36 REM ! Pgm-
37 REM !     I9%=Rad
38 REM !     I8%=Kolumn
39 REM !     I7%=IF Grafik
40 REM !     I6%=I9%,I8% Tecken
41 REM !     I$=Rad tecken
42 REM !
43 REM +-------------------------------
44 I%=20% : REM TAB(20)
45 GOSUB 46 : END 
46 DEFFNA%(I9%,I8%)=PEEK(884%+2%*I9%)+SWAP%(PEEK(885%+2%*I9%))+I8%
47 OPEN 'PR:' ASFILE 1%
48 FOR I9%=0% TO 23%
49 I7%=0% : I$=''
50 FOR I8%=0% TO 39%
51 I6%=PEEK(FNA%(I9%,I8%))
52 IF I6%=23% I7%=1% : I6%=32% : GOTO 58
53 IF I6%=7% I7%=0% : I6%=32% : GOTO 58
54 IF I6%<96% IF I6%>63% 58
55 IF I7% THEN 56 ELSE 58
56 IF I6%<64% IF I6%>31% I6%=I6%+128%
57 IF I6%<128% IF I6%>95% I6%=I6%+96%
58 I$=I$+CHR$(I6%)
59 NEXT I8%
60 ; #1%,TAB(I%)I$
61 NEXT I9%
62 CLOSE 1%
63 I$=''
64 RETURN