100 DATA 0,23
110 RESTORE 100 : GOSUB 120 : END 
120 REM ******************************
130 REM * RUTIN SK[RM                *
140 REM * VER 4.0                    *
150 REM * Kodat; 1981-05-14,         *
160 REM * Nils-Gunnar Westermark,    *
170 REM * MBS-N 0047 73243.          *
180 REM * Copyright; F}r kopieras    *
190 REM * helt fritt i kommersiellt  *
200 REM * syfte.                     *
210 REM ******************************
220 REM * Rutinen listar sk{rm-      *
230 REM * inneh}ll samt {r avsedd    *
240 REM * f|r printern Microline 80. *
250 REM * Text och blockgrafik       *
260 REM * listas. Restore till en    *
270 REM * datasats anropas f|rst,    *
280 REM * sedan denna subrutin.      *
290 REM * Datasatsen skall inneh}lla *
300 REM * de radnr mellan vilka      *
310 REM * listning skall ske (0-23). *
320 REM * I detta exempel sker       *
330 REM * listning mellan rad 3 och  *
340 REM * 12.   DATA 3,12            *
350 REM * TEMPOR[RA VARIABLER; I3%   *
360 REM * I4% I5% I6% I7% I8% \$     *
370 REM ******************************
380 POKE 65037,0
390 DATA 31744,31872,32000,32128,32256,32384,32512,32640,31784
400 DATA 31912,32040,32168,32296,32424,32552,32680,31824,31952
410 DATA 32080,32208,32336,32464,32592,32720
420 READ I4% : READ I5%
430 OPEN "PR:" ASFILE 1 : ; #1,CHR$(27,54)CHR$(30,27,65) : RESTORE 390
440 FOR I3%=0% TO 23% : READ I7% : I8%=0% : \$="" : IF I3%>I5% OR I3%<I4% THEN 540
450 FOR I6%=I7% TO I7%+39% : IF PEEK(I6%)=23% OR PEEK(I6%)=22% OR PEEK(I6%)=151% I8%=1% : \$=\$+" " : GOTO 510
460 IF PEEK(I6%)=7% OR PEEK(I6%)=4% THEN I8%=0% : \$=\$+" " : GOTO 510
470 IF PEEK(I6%)=135% THEN I8%=0% : \$=\$+" " : GOTO 510 ELSE IF I8%=0% THEN \$=\$+CHR$(PEEK(I6%))
480 IF I8%=0% AND PEEK(I6%)=127% THEN \$=LEFT$(\$,LEN(\$)-1%) : \$=\$+CHR$(143%)
490 IF I8%=1% IF PEEK(I6%)<96% AND PEEK(I6%)>63% THEN \$=\$+CHR$(PEEK(I6%)) : GOTO 510
500 IF I8%=1% IF PEEK(I6%)<64% AND PEEK(I6%)>31% \$=\$+CHR$(PEEK(I6%)-32%+128%) ELSE \$=\$+CHR$(PEEK(I6%)+128%)
510 NEXT I6% : FOR I8%=40% TO 1% STEP -1% : IF ASC(MID$(\$,I8%,1%))=32% OR ASC(MID$(\$,I8%,1%))=128% NEXT I8%
520 IF I8%<1% ; #1 : GOTO 540
530 ; #1,TAB(19)MID$(\$,1%,I8%)
540 NEXT I3% : CLOSE 1 : RETURN