10 REM 
20 REM LIST TYPO32K.BAS
30 REM *****************************
40 REM * TRYCKERIFAKTOR            *
42 REM * PROGRAM F\R ABC-80        *
44 REM * 32K, KASSETT, 40-TECKEN   *
50 REM * AV FERDINAND MICAN        *
60 REM * TEL. 0510-62336           *
70 REM * REV. 821227               *
80 REM *****************************
90 REM 
100 REM S%=VAL AV SUBPROGRAM
110 REM 
120 REM +++++++KONVERTERING++++++++++++
130 REM C=CICERO
140 REM P=PUNKTER
150 REM R=RESULTAT
160 REM V=V[RDE
170 DIM K(14) : REM dimensionera antalet konverteringar
180 FOR N%=1 TO 14 : READ K(N%) : NEXT N% : REM N%=ANTALET KONVERTERINGAR
190 DATA 4.513,2.659,.934,1.07,4.216,.237,25.4
192 DATA .0394,3.785,.264,.621,1.609,.454,2.205
200 REM K=KONVERTERINGSFAKTOR
210 REM 
220 REM +++++++TC-TAL++++++++++++++++++
230 FOR S1%=1% TO 5% : READ X(S1%) : NEXT S1% : REM S1%=ANTALET STILAR
240 DATA 5.59,4.58,5.19,5.19,5.59
250 REM G1=GRAD
260 REM T=TC-TAL
270 REM [$=AVSLUTNING
280 REM 
290 REM +++++++MANUSKRIPTBER[KNING+++++
292 REM T% T$=TECKEN/manusrad
294 REM R1% R1$=RADER (manus)
296 REM S1 S1$=SIDOR (manus)
298 REM B$=ANTAL (manustecken/sida)
302 REM A A$=ANTAL (manustecken total)
304 REM S1%=STIL
306 REM G1=GRAD
308 REM S2=TC-TAL
312 REM B=BREDD (s{ttningens)
314 REM R2%=RADER (s{ttning)
316 REM S=SIDOR (tryck)
412 REM I=BLINK (bildadress)
430 REM X=F\RDR\JNING
440 REM N%=[NDRINGSVAL
450 REM +++++++PAPPERSVIKT+++++++++++++
460 REM PAPPERSYTA A-SERIE
470 FOR Y=0 TO 6 : READ A(Y) : NEXT Y
480 DATA 9999.49,4995.54,2494.8,1247.4,623.7,310.8,155.4
490 RESTORE 
500 REM A=ANTAL ARK
510 REM V=VIKT I KG
520 REM P1 P1$=PAPPERSFORMAT (h|jd)
530 REM P2=PAPPERSBREDD
540 REM P3=ARKYTA
550 REM P1$=PAPPERSFORMAT (h|jd)
560 REM [$=AVSLUTNING
570 REM 
580 REM +++++++REPRODUKTIONSPROCENT++++
590 REM M=M]TT (bredd)
600 REM O=ORIGINALSTORLEK
610 REM \=\NSKAD STORLEK
620 REM R=REPRODUKTIONSPROCENT
630 REM F$=AVSLUTNING
640 REM 
650 REM +++++++BILDPROPORTIONER++++++++
660 REM O=ORIGINALL[NGD
665 REM B=BREDD (efter storleks{ndring)
667 REM P=PRESENTATION VID STOR BILD
670 REM P1-P7=GRAFIKPUNKTER
680 REM X-X3 =GRAFIKPUNKTER
690 REM Y=GRAFIKPUNKTER
700 REM I%=GRAFISK MODE
710 REM A$=AVSLUTNING
720 REM 
730 REM +++++++INSTRUKTIONER+++++++++++
740 REM S$=BL[DDRA
750 REM 
760 REM *******************************
770 ; CHR$(12)
780 ; "Detta {r programmet"
810 ; "TRYCKERIFAKTOR                HUVUDMENY"
820 ; "========================================"
830 ; "F|ljande subprogram finns:"
840 ; 
850 ; TAB(10)"1 Konvertering"
860 ; TAB(10)"2 tc-tal"
870 ; TAB(10)"3 Manuskriptber{kning"
880 ; TAB(10)"4 Pappersvikt"
890 ; TAB(10)"5 Reproduktionsprocent"
900 ; TAB(10)"6 Bildproportioner"
910 ; TAB(10)"7 Instruktioner"
920 ; 
930 ; 
940 ; "Vilket program v{ljer Du";
950 REM 
960 REM VAL AV SUBPROGRAM
970 ; : ; : ; : ; 
980 ONERRORGOTO 450
990 ; "_____________________________________"
1000 ; "Skriv siffran och tryck p} RETURN."
1010 ; CUR(16%,24%); : INPUT S%
1020 ONERRORGOTO 450
1030 IF S%<1 OR S%>7 GOTO 220
1050 ON S% GOTO 1070,2010,2270,3340,3830,4190,4810
1060 REM 
1070 REM KONVERTERING*******************
1080 REM 
1090 ; CHR$(12)
1100 ; "Detta {r programmet          Subprogram"
1110 ; "TRYCKERIFAKTOR             KONVERTERING"
1120 ; "========================================"
1130 ; "Du kan omvandla f|ljande enheter"
1140 ; 
1150 ; " 1 cicero till mm";TAB(20)"2 mm till cicero"
1160 ; " 3 pica till cicero"TAB(20)"4 cicero till pica"
1170 ; " 5 pica till mm";TAB(20)"6 mm till pica"
1180 ; " 7 tum till mm";TAB(20)"8 mm till tum"
1190 ; " 9 gallon till l";TAB(19)"10 liter till gallon"
1200 ; "11 Fahrenheit";TAB(19)"12 Celsius till"
1210 ; "   till Celsius";TAB(22)"Fahrenheit"
1220 ; "13 pounds till kg";TAB(19)"14 kg till pounds"
1230 ; 
1240 ; 
1250 ; 
1260 REM Bildsk{rmsunderstycke KONVERTERING
1270 ; 
1280 ; "_______________________________________"
1290 ; "Skriv siffran f|r |nskad omvandling och"
1300 ; "tryck p} RETURN"
1310 ; "Vill Du tillbaks till huvudmenyn s}"
1320 ; "tryck endast p} RETURN"
1330 REM Loop f|r tilldelning av konverteringsfaktor
1340 ; CUR(16%,0%);"Vilken omvandling beh|ver Du"
1350 ; CUR(16%,28%); : INPUT N%
1360 IF N%<1 OR N%>14 GOTO 1070
1370 ; CHR$(12)
1380 ; "Detta {r programmet          Subprogram"
1390 ; "TRYCKERIFAKTOR          KONVERTERING";N%
1400 ; "========================================"
1410 GOSUB 1920
1420 ; CUR(5,1)"Vilket v{rde vill Du omvandla       ";
1430 ; CUR(5%,30%); : INPUT V
1440 IF V=0 GOTO 1070
1450 ONERRORGOTO 450
1460 R=V*K(N%) : REM Formel f|r omvandling
1470 R=INT(100*R+.5)/100 : REM Avrundar till tv} decimaler
1480 REM Skicka programmet till r{tt utskriftsrad
1488 IF N%>7 GOTO 1492 : REM DELA TILLDELNING I 2 RADER
1490 ON N% GOTO 1500,1520,1560,1600,1640,1660,1700
1491 GOTO 1500
1492 L%=N%-7%
1494 ON L% GOTO 1720,1740,1760,1780,1810,1840,1860
1500 ; V;" cicero=";R;" mm            "
1510 GOTO 1420
1520 C=INT(R/12) : P=INT(R-(C*12))
1530 ; V;" mm=";C;" cicero     ";
1540 GOSUB 1880
1550 GOTO 1420
1560 C=INT(R) : P=12*(R-INT(R)) : P=INT(P+.5)
1570 ; V;" pica=";C;" cicero     ";
1580 GOSUB 1880
1590 GOTO 1420
1600 C=INT(R) : P=12*(R-INT(R)) : P=INT(P+.5)
1610 ; V;" cicero=";C;" pica      ";
1620 GOSUB 1880
1630 GOTO 1420
1640 ; V;" pica=";R;" mm      "
1650 GOTO 1420
1660 C=INT(R) : P=12*(R-INT(R)) : P=INT(P+.5)
1670 ; V;" mm=";C;" pica      ";
1680 GOSUB 1880
1690 GOTO 1420
1700 ; V;" tum=";R;" mm        "
1710 GOTO 1420
1720 ; V;" mm=";R;" tum       "
1730 GOTO 1420
1740 ; V;" gallon=";R;" liter     "
1750 GOTO 1420
1760 ; V;" liter=";R;" gallon      "
1770 GOTO 1420
1780 R=(V-32)*5/9
1790 ; V;" Fahrenheit=";R;" Celsius    "
1800 GOTO 1420
1810 R=(V*9/5)+32
1820 ; V;" Celsius=";R;" Fahrenheit    "
1830 GOTO 1420
1840 ; V;" pounds=";R;" kg    "
1850 GOTO 1420
1860 ; V;" kg=";R;" pounds    "
1870 GOTO 1420
1880 IF P>1 THEN PRINT P;" punkter              "
1890 IF P=1 THEN PRINT " 1 punkt                   "
1900 IF P=0 ; "           "
1910 RETURN 
1920 REM Bildsk{rmsunderstycke KONVERTERING 1-14
1930 ; CUR(18%,0%)"_______________________________________"
1940 ; CUR(19%,0%)"Skriv talet och tryck p} RETURN s} f}r"
1950 ; CUR(20%,0%)"Du svaret omedelbart. Skriver Du 0 som"
1960 ; CUR(21%,0%)"v{rde s} kan Du v{lja en annan konver-"
1970 ; CUR(22%,0%)"tering. Vill Du byta till huvudmenyn"
1980 ; CUR(23%,0%)"igen s} tryck endast p} RETURN."
1990 RETURN 
2000 REM 
2010 REM TC-TAL************************
2020 ; CHR$(12%)
2030 ; CUR(0%,0%)"Detta {r programmet          Subprogram"
2040 ; CUR(1%,0%)"TRYCKERIFAKTOR                   TC-TAL"
2050 ; CUR(2%,0%)"======================================="
2060 REM Bildsk{rmsunderstycke TC-TAL
2070 ; CUR(20%,0%)"_______________________________________"
2080 ; CUR(21%,0%)"Skriv stilnumret och graden s} f}r Du"
2090 ; CUR(22%,0%)"veta tc-talet."
2100 ; CUR(8%,0%)"Vilken stil   " : S1%=0
2110 ; CUR(9%,0%)"Vilken grad    " : G1=0
2120 ; CUR(8%,11%); : INPUT S1%
2130 IF S1%>5 GOTO 2120 : REM MAX ANT STILAR
2140 ; CUR(9%,11%); : INPUT G1
2150 IF G1<4.5 OR G1>72 GOTO 2140 : REM Gradomf}nget
2160 T=5/G1*(X(S1%)) : REM Formel f|r ber{kning av tc-tal
2170 T=INT(100*T+.5)/100 : REM Avrundning
2180 ; CUR(10%,23%);"    "; : ; CUR(10%,23%);T
2190 ; CUR(9%,20%);"tc-talet"
2200 ; CUR(10%,20%);""; : ; CUR(10%,31%);""
2210 ; CUR(11%,20%);""
2220 ; CUR(14%,0%);"Vill Du veta flera tc-tal (J/N)"; : INPUT [$
2230 IF [$="J" OR [$="j" THEN GOTO 2010
2240 IF [$="N" OR [$="n" GOTO 2270
2250 GOTO 20
2260 REM 
2270 REM MANUSKRIPTBER[KNING***********
2280 ; CHR$(12%)
2290 ; CUR(0%,0%)"Detta {r programmet          Subprogram"
2300 ; CUR(1%,0%)"TRYCKERIFAKTOR      MANUSKRIPTBER[KNING"
2310 ; CUR(2%,0%)"======================================="
2320 ; CUR(4%,0%)"Tecken/rad      " : T%=0
2330 ; CUR(5%,0%)"Antal rader     " : R1%=0
2340 ; CUR(6%,0%)"Manussidor      " : S1=0
2350 ; CUR(4%,20%);"Manuskriptets" : A=0
2360 ; CUR(5%,20%);"antal nedslag"
2370 ; CUR(8%,0%)"Stil               "
2380 ; CUR(9%,0%)"Grad               " : G1=0
2390 ; CUR(8%,20%)"tc-tal"
2400 ; CUR(9%,19%)'     ' : S2=0
2410 ; CUR(10%,0%)"Satsbredd      " : ; CUR(11%,0%)"(i cicero)" : B=0
2420 ; CUR(12%,0%)"Antal rader      " : R2%=0
2430 ; CUR(13%,0%)"Sidantal        " : S=0
2440 ; CUR(12%,21%)'               '
2450 REM Bildsk{rmsunderstycke
2460 ; CUR(20%,0%)"_______________________________________"
2470 ; CUR(21%,0%)"Fyll i siffrorna och skriv 0 (noll) f|r"
2480 ; CUR(22%,0%)"det Du s|ker. RETURN visar huvudmenyn."
2490 ; CUR(4%,11%); : INPUT T$ : T%=VAL(T$)
2500 ; CUR(5%,11%); : INPUT R1$ : R1%=VAL(R1$)
2510 ; CUR(6%,11%); : INPUT S1$ : S1=VAL(S1$)
2520 A=T%*R1%*S1 : ; CUR(6%,19%)"           "
2530 REM STR[NGAR F\R UTSKRIFT UTAN E+
2540 B$=MUL$(T$,R1$,0)
2550 A$=MUL$(B$,S1$,0)
2560 ; CUR(6%,20%)A$ : REM ANTALET TECKEN
2570 ; CUR(8%,11%); : INPUT S1%
2580 IF S1%>5 GOTO 2570 : REM MAX ANT STIL
2590 ; CUR(9%,11%); : INPUT G1
2600 IF G1=0 GOTO 2640
2610 IF G1<4.5 OR G1>72 GOTO 2590
2620 S2=5/G1*(X(S1%)) : S2=INT(100*S2+.5)/100 : REM Formel tc-tal + avrundning
2630 ; CUR(9%,19%);"       "; : ; CUR(9%,19%);S2
2640 ; CUR(10%,11%); : INPUT B
2650 ; CUR(12%,11%); : INPUT R2%
2660 ; CUR(13%,11%); : INPUT S
2670 REM [NDRINGSINPUT
2680 GOTO 2830
2690 ; CUR(8%,11%)"    " : ; CUR(8%,11%); : INPUT S1%
2700 S2=5/G1*(X(S1%)) : S2=INT(100*S2+.5)/100 : REM Formel tc-tal + avrundning
2710 ; CUR(9%,19%);"    "; : ; CUR(9%,19%);S2
2720 GOTO 2830
2730 ; CUR(9%,11%)"    " : ; CUR(9%,11%); : INPUT G1
2740 IF G1=0 GOTO 3120
2750 S2=5/G1*(X(S1%)) : S2=INT(100*S2+.5)/100 : REM Formel tc-tal + avrundning
2760 ; CUR(9%,19%);"    "; : ; CUR(9%,19%);S2
2770 GOTO 2830
2780 ; CUR(10%,11%);"     " : ; CUR(10%,11%); : INPUT B
2790 GOTO 2830
2800 ; CUR(12%,11%);"     " : ; CUR(12%,11%); : INPUT R2%
2810 GOTO 2830
2820 ; CUR(13%,11%);"     " : ; CUR(13%,11%); : INPUT S
2830 REM V[LJ FORMEL
2840 IF G1=0 GOTO 3120
2850 IF B=0 GOTO 3170
2860 IF R2%=0 GOTO 3190
2870 IF S=0 GOTO 3220
2880 REM BLINK OM EJ 0+++++++++++++++++
2890 ; CHR$(7)
2900 FOR I=32485 TO 32503
2910 POKE I,PEEK(I) OR 128
2920 NEXT I
2930 FOR I=32592 TO 32604
2940 POKE I,PEEK(I) OR 128
2950 NEXT I
2960 ; CUR(19%,15%)"                 "
2970 ; CUR(17%,0%)"Du har gl|mt att fylla i en nolla f|r"
2980 ; CUR(18%,0%)"det Du s|ker - Du f}r en chans till   "
2990 ; CUR(19%,0%)"om 10 sekunder.                        "
3000 FOR X=1 TO 10000 : NEXT X
3010 FOR I=32485 TO 32503
3020 POKE I,PEEK(I) AND 127 : NEXT I
3030 FOR I=32592 TO 32604
3040 POKE I,PEEK(I) AND 127 : NEXT I
3050 POKE I,PEEK(I) AND 127
3060 OUT 6,17
3070 FOR I=1 TO 600 : NEXT I
3080 OUT 6,0
3090 GOTO 3270
3100 REM 
3110 REM SLUT P] BLINK+++++++++++++++++
3120 REM 
3130 S2=A/(S*B*R2%) : ; CUR(9%,20%);'    '; : ; CUR(9%,20%); : ; S2
3140 G1=100*(S2/(X(S1%))/5) : ; CUR(12%,22%);"    "
3150 G1=INT(10*G1+.5)/10 : ; CUR(12%,22%); : ; G1; : ; " punkter"
3160 S2=0 : GOTO 3240
3170 B=A/(S*S2*R2%) : ; CUR(12%,22%);"        "; : ; CUR(12%,22%);B; : ; "=cic"
3180 B=0 : GOTO 3240
3190 R2%=A/(S2*B*S) : ; CUR(12%,22%);"         "
3200 ; CUR(12%,22%);R2%; : ; " rader"
3210 R2%=0 : GOTO 3270
3220 S=A/(S2*B*R2%) : S=INT(10*S+.5)/10 : ; CUR(12%,22%);"               "
3230 ; CUR(12%,22%);S; : ; " sidor" : S=0
3240 ; CUR(11%,20%);""
3250 ; CUR(12%,20%);""; : ; CUR(12%,36%);""
3260 ; CUR(13%,20%);""
3270 ; CUR(17%,0%)"Vill Du {ndra uppgiften om stil (1), "
3280 ; CUR(18%,0%)"grad (2), bredd (3), radantal (4), sid-"
3290 ; CUR(19%,0%)"antal (5) e. samtliga uppgifter (6)    "
3300 ; CUR(19%,35%); : INPUT N%
3310 ON N% GOTO 2690,2730,2780,2800,2820,2320
3320 GOTO 2270 : REM ]TER SUBSTART
3330 REM 
3340 REM PAPPERSVIKT*******************
3350 ; CHR$(12)
3360 ; "Detta {r programmet          Subprogram"
3370 ; "TRYCKERIFAKTOR              PAPPERSVIKT"
3380 ; "========================================"
3390 ; CUR(7%,0%)"Papprets h|jd"
3400 ; CUR(7%,25%)"(Skriv A0...A6)"
3410 ; CUR(8%,0%)"         bredd"
3420 ; CUR(8%,25%)"(eller cm)"
3430 ; CUR(9%,0%)"Gramvikt       " : G=0
3440 ; CUR(10%,0%)"Antal ark         " : A=0
3450 ; CUR(11%,0%)"Vikt i kg        " : V=0
3460 REM Bildsk{rmsunderstycke PAPPERSVIKT
3470 ; CUR(20%,0%)"_______________________________________"
3480 ; CUR(21%,0%)"Fyll i siffrorna och skriv 0 (noll) f|r"
3490 ; CUR(22%,0%)"det Du s|ker."
3500 ; CUR(7%,14%); : INPUT P1$
3520 IF LEFT$(P1$,1)='A' THEN GOTO 3560
3525 ONERRORGOTO 3340
3530 ; CUR(8%,14%); : INPUT P2
3540 P3=VAL(P1$)*P2
3550 GOTO 3640
3560 REM 
3562 Y$=RIGHT$(P1$,2)
3565 Y=VAL(Y$)
3570 P3=A(Y)
3630 IF P3=0 PRINT CUR(19%,0%)'Endast A0 t.o.m. A6 finns inmatade' : GOTO 3490
3640 ; CUR(9%,14%); : INPUT G
3660 ; CUR(10%,14%); : INPUT A
3670 ; CUR(11%,14%); : INPUT V
3672 ; CUR(12%,25%);"**************"
3673 ; CUR(13%,25%);"*"; : ; CUR(13%,38%);"*"
3674 ; CUR(14%,25%);"*"; : ; CUR(14%,38%);"*"
3675 ; CUR(15%,25%);"*"; : ; CUR(15%,38%);"*"
3676 ; CUR(16%,25%);"**************"
3680 IF G=0 GOTO 3720
3690 IF A=0 GOTO 3740
3700 IF V=0 GOTO 3760
3710 GOTO 20
3720 G=1E+7*(V/(P3))/A : ; CUR(14%,26%);G; : ; ' g' : REM GRAMVIKT
3730 GOTO 3770
3740 A=V/(P3*G)*1E+7 : ; CUR(14%,26%);A; : ; ' ark' : REM ARK
3750 GOTO 3770
3760 V=(P3*G*A)/1E+7 : ; CUR(14%,26%);V; : ; ' kg' : REM VIKT
3770 ; CUR(19%,0%);"Vill Du r{kna ut flera upplagor (J/N)"; : INPUT [$
3780 IF [$="J" OR [$="j" THEN GOTO 3340
3790 IF [$="N" OR [$="n" GOTO 20
3800 GOTO 20
3810 ONERRORGOTO 20
3820 REM 
3830 REM REPRODUKTIONSPROCENT**********
3840 ; CHR$(12)
3850 ; "Detta {r programmet          Subprogram"
3860 ; "TRYCKERIFAKTOR     REPRODUKTIONSPROCENT"
3870 ; "======================================="
3880 ; CUR(5%,0%)"\nskat m}tt"
3890 ; CUR(6%,0%)"Originalets m}tt"
3900 REM Bildsk{rmsunderstycke REPRODUKTIONSPROCENT
3910 ; CUR(14%,0%)"_______________________________________"
3920 ; CUR(16%,0%)"Skriv m}tten (valfri enhet) + RETURN"
3930 ; CUR(5%,16%)"        "
3940 ; CUR(5%,16%); : INPUT \
3950 ; CUR(6%,16%)"       ";
3960 ; CUR(6%,16%)"    ";CUR(6%,16%); : INPUT O
3970 R=(\/O)*100
3980 ; CUR(6%,24%)"            " : ; CUR(6%,24%)R; : ; " %"
3990 ; CUR(17%,0%)"TANGENTEN K trycker du p} om Du vill"
4000 ; CUR(18%,0%)"            kolla bildens bredd"
4010 ; CUR(19%,0%)'  "       N ber{kna en ny bild'
4020 ; CUR(20%,0%)'  "       S ha samma m}tt p} bilden'
4030 ; CUR(21%,0%)'  "  RETURN f|r }terg}ng till menyn'
4040 ; CUR(22%,0%)'  "       P se bildens proportioner'
4050 ; CUR(8%,0%)"Vad vill Du g|ra nu";
4060 INPUT F$
4070 IF F$="K" OR F$="k" THEN GOTO 4130
4080 IF F$="N" OR F$="n" THEN GOTO 3830
4090 IF F$="S" OR F$="s" THEN GOTO 3950
4100 REM NY BER[KNING MED SAMMA \
4110 IF F$="P" OR F$="p" THEN GOTO 4190
4120 GOTO 20
4130 ; CUR(10%,0%)"M}ttet          ";
4140 INPUT M
4150 B=(M*R)/100
4160 ; CUR(10%,24%);B
4170 GOTO 4050
4180 REM 
4190 REM BILDPROPORTIONER**************
4200 ; CHR$(12)
4210 FOR I%=0% TO 23%
4220 ; CUR(I%,10%);CHR$(151);
4230 NEXT I%
4240 ; CUR(0%,0%)"BILD-"
4250 ; CUR(1%,0%)"PROPOR-"
4260 ; CUR(2%,0%)"TIONER"
4270 ; CUR(3%,0%)"========="
4280 ; CUR(4%,0%)"L[NGD"
4290 ; CUR(5%,0%); : INPUT O
4300 P1=22
4310 P5=P1
4320 P2=INT((O/2.78)+22)
4330 IF P2<80 THEN GOTO 4380
4340 ; CUR(10%,0)"L[NGDEN"
4342 ; CUR(11%,0%)"ST\RRE [N" : ; CUR(12%,0%)"BILD-" : ; CUR(13%,0%)"SK[RMEN"
4350 P=INT((79/P2)*100)
4360 ; CUR(15%,0%)"BILDEN" : ; CUR(16%,0%)"VISAS I" : ; CUR(17%,0%)P; : ; " %"
4370 P2=79
4380 FOR Y=P1 TO P2 : REM HOR LINJE
4390 SETDOT 0,Y
4400 NEXT Y
4410 ; CUR(6%,0%)"H\JD"
4420 ; CUR(7%,0%); : INPUT M
4430 P3=INT(M/2.29)
4440 IF P3<72 THEN GOTO 4450
4442 ; CUR(10%,0)"H\JDEN "
4444 ; CUR(11%,0%)"ST\RRE [N" : ; CUR(12%,0%)"BILD-" : ; CUR(13%,0%)"SK[RMEN"
4446 P=INT((71/P3)*100) : P3=71
4448 ; CUR(15%,0%)"BILDEN" : ; CUR(16%,0%)"VISAS I" : ; CUR(17%,0%)P; : ; " %"
4450 FOR Y2=P1 TO P2 : REM 2A HORIZ
4460 SETDOT P3,Y2
4470 NEXT Y2
4480 ; CUR(8%,0%)"PROCENT"
4490 ; CUR(9%,0%); : INPUT R
4500 P7=INT(M*R/2.29/100)
4510 IF P7<80 THEN GOTO 4520
4512 P=INT((79/P7)*100) : P7=79
4514 ; CUR(15%,0%)"BILDEN" : ; CUR(16%,0%)"VISAS I" : ; CUR(17%,0%)P; : ; " %"
4516 P3=71
4520 P6=INT((R*O/2.78/100)+22)
4530 IF P6<72 THEN GOTO 4540
4532 ; CUR(10%,0)"BILDEN "
4534 ; CUR(11%,0%)"ST\RRE [N" : ; CUR(12%,0%)"BILD-" : ; CUR(13%,0%)"SK[RMEN"
4536 P=INT((71/P6)*100) : P6=71
4538 ; CUR(15%,0%)"BILDEN" : ; CUR(16%,0%)"VISAS I" : ; CUR(17%,0%)P; : ; " %"
4540 FOR Y3=P1 TO P6 STEP 2 : REM 3e punktlinje hor
4550 SETDOT P7,Y3
4560 NEXT Y3
4570 P4=INT(O/2.9)
4580 FOR X=0 TO P3 : REM VERT LINJE
4590 SETDOT X,P1
4600 NEXT X
4610 FOR X2=0 TO P3 : REM 2a vertlinje
4620 SETDOT X2,P2
4630 NEXT X2
4640 FOR X3=0 TO P7 STEP 2 : REM 3e punktlinje vert
4650 SETDOT X3,P6
4660 NEXT X3
4670 ; CUR(20%,0%);"Fler"
4672 ; CUR(21%,0%);"bilder"
4674 ; CUR(22%,0%);'(J/N)' : INPUT A$
4676 IF A$="J" OR A$="j" THEN GOTO 4190
4678 IF A$="N" OR A$="n" GOTO 20
4800 REM 
4810 REM INSTRUKTIONER*****************
4820 REM 
4830 ; CHR$(12)
4840 ; "Detta {r programmet          Subprogram"
4850 ; "TRYCKERIFAKTOR         INSTRUKTIONER(1)"
4860 ; "======================================="
4870 ; "Med hj{lp av programmet kan Du"
4880 ; 
4890 ; "* omvandla m}tt, t.ex. cicero till mm"
4895 ; '* "sl} upp" tc-tal f|r Dina stilar'
4900 ; "* ber{kna antalet rader vid s{ttning"
4910 ; "* r{kna ut pappersvikten"
4920 ; "* r{kna ut bildstorleken"
4930 ; "* se p} bildproportioner"
4950 ; 
4960 ; "I huvudet p} varje sk{rm st}r i vilket"
4970 ; "subrogram Du befinner Dig."
4980 ; 
4990 ; "I botten, under strecklinjen, finns"
5000 ; "anvisningar f|r svarandet p} fr}gorna."
5010 ; 
5025 ; 
5030 REM Bildsk{rmsunderstycke
5032 ; "_____________________________________"
5034 ; "Tryck p} mellanslag n{r Du vill l{sa"
5036 ; "vidare eller p} RETURN om Du vill" : ; "tillbaks till huvudmenyn"
5040 ; CUR(17%,40%) : GET S$
5050 IF S$="" GOTO 450
5060 IF S$=" " GOTO 5070 ELSE 450
5070 ; CHR$(12)
5080 ; "Detta {r programmet          Subprogram"
5090 ; "TRYCKERIFAKTOR         INSTRUKTIONER(2)"
5100 ; "======================================="
5102 ; 
5110 ; "Varje svar avslutas med RETURN. Trycker"
5111 ; "Du p} RETURN utan annan inmatning samt"
5115 ; "vid felaktiga inmatningar s} g}r datorn"
5117 ; "till huvudmenyn."
5119 ; 
5120 ; "Det {r meningen att man skall anpassa"
5130 ; "programmet till sina egna behov."
5132 ; 
5140 ; "Mera ing}ende anvisningar hur detta"
5150 ; "g|rs l{mnas i den bifogade listningen."
5152 ; "D{r l{mnas ocks} exempel p} hur"
5154 ; "programmet kan anv{ndas."
5156 ; 
5158 ; "Lycka till!"
5180 REM Bildsk{rmsunderstycke
5190 ; "_____________________________________"
5200 ; "Tryck p} RETURN om Du vill tillbaka"
5210 ; "till huvudmenyn."
5215 GET A$
5220 GOTO 20