100 REM *\VERF\R*
110 REM G BENEDICKS 82-06-11
120 ; CHR$(12)"DENNA RUTIN \VERF\R SEKTOR 1-564 FR]N  MASTER I DRIVE 1 TILL SKIVA I DRIVE 0";
130 ; "   I STEG OM 100 SEKTORER" : ; : ; 
140 ; "STARTSEKTOR"; : INPUT S1%
150 ; "SLUTSEKTOR"; : INPUT S2%
160 IF S1%>S2% OR S2%>564% THEN 100
170 ; : ; "KONTROLLERA ATT:" : ; "MASTERN SITTER I DRIVE 1"
180 ; "S[KERHETSKOPIAN SITTER I DRIVE 0"
190 ; : ; "KORREKT (J/N)"; : GET C$ : IF C$="J" THEN 200 ELSE 100
200 DIM A$(100)=255,Q0$=255
210 ; CHR$(12)
240 ONERRORGOTO 470
250 OPEN "DR1:DD1.DAT" ASFILE 1%
260 OPEN "DR0:DD1.DAT" ASFILE 2%
270 FOR I%=S1% TO S2% STEP 100%
280 FOR J%=0% TO 99%
290 IF (I%+J%)>S2% THEN 330
300 ; CUR(5%,10%)I%+J%
310 GOSUB 430 : REM L[S SEKTOR
320 NEXT J%
330 FOR N%=0% TO 99%
340 IF (N%+I%)>S2% THEN 390
350 ; CUR(6%,10%)I%+N%
360 GOSUB 450 : REM SKRIV SEKTOR
370 NEXT N%
380 NEXT I%
390 CLOSE 1% : CLOSE 2%
400 ; : ; "KLART"
410 ; "S[TT PROGRAMSKIVAN I DRIVE 0" : ; "TRYCK RETURN" : GET C$
420 STOP : REM CHAIN "START"
430 Z%=CALL(28666%,1%)+CALL(28668%,I%+J%) : A$(J%)=Q0$
440 RETURN 
450 Z%=CALL(28666%,2%) : Q0$=A$(N%) : Z%=CALL(28670%,I%+N%)
460 RETURN 
470 CLOSE 1% : CLOSE 2% : ; "SKIVFEL ! ! !"
480 FOR J=1 TO 1000 : NEXT J
490 GOTO 100