100 REM *EDITERA*
110 REM L[S - R[TTA - SKRIV I DATABASEN*
120 REM COPYRIGHT G BENEDICKS 82-06-11
130 DIM U$=3000%,A$=1500%,Q0$=255%,A$(2%)=1500%,B$=3000
140 ; CHR$(12);
150 ; : ; "L[S - R[TTA - SKRIV I DATABAS"
160 ; "*****************************"
170 ; "(VER 82-06-11)"
180 ; CUR(22,0)"VILKEN STARTSEKTOR "; : INPUT C$
190 IF C$="" CHAIN "START" ELSE A%=VAL(C$)
200 IF A%>549% OR A%<1% 140
220 P%=0%
230 ONERRORGOTO 730
250 OPEN "DR1:DD1.DAT" ASFILE 1%
260 A$(0%)="" : A$(1%)="" : A$(2%)="" : S%=0%
270 FOR I%=0% TO 2%
280 FOR R%=(A%+I%*3%) TO (A%+2%+I%*3%)
290 REM 
300 GOSUB 710 : REM L[S
310 S%=S%+1% : A$=A$+SPACE$(255%)
320 IF MID$(A$,251,1)<>"F" THEN A$(I%)=A$(I%)+LEFT$(A$,250) : GOTO 360
330 A$(I%)=A$(I%)+LEFT$(A$,250)
340 NEXT R%
350 NEXT I%
360 ; CHR$(12); : CLOSE 1%
370 H%=1%
380 Q%=0%
390 IF S%>3% THEN Q%=1%
400 IF S%>6% THEN Q%=2%
410 REM 
420 REM 
430 REM 
440 U$=""
450 FOR I%=0% TO Q%
460 A$=A$(I%) : GOSUB 750 : REM BEASRBETA
470 U$=U$+A$
480 NEXT I%
490 U%=LEN(U$)
500 ; CUR(22,0)"L= LAGRA    M-SLAG= SEKTOR"A%+P%+S%;"      " : ; "P= PRINTER  RETURN= NY SEKTOR   "; : GET C$
510 ; CHR$(12)
520 IF C$="P" AND H%=1% V%=61% : L%=2% : GOTO 1000
530 IF C$="L" AND H%=1% THEN 560
540 IF C$=" " THEN A%=A%+P%+S% : GOTO 200
550 GOTO 140
560 IF S%<(((U%-1%)/250%)+1%) THEN ; "TEXTEN RYMMS INTE P]";S%;" SEKTORER G\R OM" : GOTO 430
570 ; : ; "SKALL VI L[GGA IN TEXTEN P] SKIVAN (J/N)"; : GET C$ : IF C$="J" OR C$="j" THEN 580 ELSE 680
580 IF P%=0% THEN OPEN "DR1:DD1.DAT" ASFILE 1% ELSE OPEN "DR0:DD1.DAT" ASFILE 1%
590 U$=U$+SPACE$(252)
600 FOR I%=0% TO S%-1%
610 R%=A%+I%
620 A$=MID$(U$,1%+(I%*250%),250%)
630 IF I%<(S%-1%) THEN A$=A$+"F"+RIGHT$(NUM$(I%+1%),2%)+RIGHT$(NUM$(S%),2%) : GOTO 650
640 A$=A$+SPACE$(251%-LEN(A$))+RIGHT$(NUM$(I%+1%),2%)+RIGHT$(NUM$(S%),2%)
650 GOSUB 690 : REM SKRIV
660 NEXT I%
670 CLOSE 1% : ; CHR$(12)"KLART"
680 ; : ; "FORTS[TTA (J/N)"; : GET C$ : IF C$="J" OR C$="j" THEN 140 ELSE CHAIN "START"
690 Z%=CALL(28666%,1%) : Q0$=A$ : Z%=CALL(28670%,R%)
700 RETURN 
710 Z%=CALL(28666%,1%)+CALL(28668%,R%) : A$=Q0$
720 RETURN 
730 CLOSE 1% : ; "DU HAR SKRIVIT FEL AVSNITT ELLER" : ; "SATT I FEL SKIVA (RETURN)";
740 GET C$ : GOTO 140
750 REM EDITERA A$
760 REM **********
770 DEFFNR%=(N%-1%)/40%
780 DEFFNK%=N%-1%-FNR%*40%
790 C%=INSTR(1%,A$,"    ")
800 IF C%>0% THEN A$=LEFT$(A$,C%)
810 ; CHR$(12); : N%=LEN(A$)/2% : ; A$;
820 ; CUR(22,20)"SEKTOR"A%+P%;" SID";I%+1%;
830 ; CUR(22,0)"[NDRA TEXT (J/-M-)"; : GET C$ : IF C$="J" OR C$="j" THEN 840 ELSE 990
840 ; CUR(22,0)"FLYTTA *pil v{*pil h|*ctrl |*ctrl {*"
850 ; "RADERING = RETURN  *  KLART = <";
860 ; CUR(FNR%,FNK%); : GET C$
870 IF C$=CHR$(9) THEN N%=N%+1% : IF N%>(LEN(A$)+1%) THEN N%=LEN(A$)+1%
880 IF C$=CHR$(8) THEN N%=N%-1% : IF N%<1% THEN N%=1%
890 IF C$=CHR$(13) THEN 950
900 IF C$=CHR$(28) THEN IF N%>41% THEN N%=N%-40%
910 IF C$=CHR$(27) THEN N%=N%+40% : IF N%>(LEN(A$)+1%) THEN N%=N%-40%
920 IF ASC(C$)<32 THEN 860
930 IF C$="<" THEN 970
940 A$=LEFT$(A$,N%-1%)+C$+RIGHT$(A$,N%) : ; CUR(0,0)A$ : N%=N%+1% : GOTO 860
950 IF (LEN(A$))<N% THEN A$=LEFT$(A$,N%-1%) ELSE A$=LEFT$(A$,N%-1%)+RIGHT$(A$,N%+1%)
960 ; CUR(0,0)A$+" " : GOTO 860
970 ; CHR$(12)
980 ; A$
990 RETURN 
1000 REM **SKRIV************************
1010 H%=0%
1020 U$=LEFT$(U$,INSTR(1%,U$,"%")-2%)+" "
1030 IF L%=2% THEN OPEN "PR:" ASFILE 2%
1040 ; #L%TAB(2)"SEKTOR"A%+P%;
1050 B$="" : C$="" : E%=0% : X%=0%
1060 IF U$="" OR U$=" " GOTO 500
1070 IF (A%+P%)>293% THEN E%=INSTR(8%,U$,"=") ELSE E%=0%
1080 IF E%=0% E%=LEN(U$) : U$=U$+" "
1090 B$=LEFT$(U$,E%) : U$=RIGHT$(U$,E%+1%)
1100 IF LEN(B$)>V% THEN 1120
1110 C$=B$ : GOSUB 1180 : GOTO 1050
1120 G%=0% : IF LEFT$(B$,1%)="=" THEN G%=2%
1130 FOR I%=V%+G% TO 1% STEP -1%
1140 IF MID$(B$,I%,1%)<>" " THEN NEXT I% ELSE 1160
1150 ; "FEL" : STOP 
1160 C$=LEFT$(B$,I%) : B$=RIGHT$(B$,I%+1%)
1170 GOSUB 1180 : GOTO 1100
1180 IF C$="" THEN 1230 ELSE IF LEFT$(C$,1%)=" " C$=RIGHT$(C$,2%) : GOTO 1180
1190 IF RIGHT$(C$,LEN(C$))=" " C$=LEFT$(C$,LEN(C$)-1%) : GOTO 1190
1200 F%=0%
1210 IF LEFT$(C$,1%)="=" ; #L% : F%=-2% : GOTO 1230
1220 X%=INSTR(1%,C$," DE ") : IF X%>2% AND X%<5% ; #L%
1230 ; #L%TAB(15%+F%)C$
1240 RETURN 
1250 REM ****************************