100 REM *SKRIV*
110 REM SKRIV NY TEXT I DATABASEN*
120 REM ********************************ED100
130 REM G BENEDICKS 82-06-11 VER 3
140 DIM U$=3000%,A$=1500%,Q0$=255%
150 ; CHR$(12) : ; 
160 ; "INSKRIVNING OCH EDITERING NY TEXT" : ; STRING$(33,42)
180 ; : ; "Du kan skriva in ett avsnitt med totalt 3000 tecken och editera texten."
190 ; "Eftersom sk{rmen bara rymmer totalt 3   sektorer eller 750 tecken, f}r du ta en sida i taget vid l{ngre text."
200 ; : ; : ; "VILKEN STARTSEKTOR F\R NY TEXT "; : INPUT C$
210 C%=VAL(C$) : R1%=0%
220 IF C%<1% OR C%>549% THEN 150
230 OPEN "DR1:DD1.DAT" ASFILE 1%
260 R%=C%-R1% : GOSUB 660 : CLOSE 1% : REM L[S
270 ONERRORGOTO 680
280 IF LEFT$(A$,5%)="     " THEN 320
290 ; "DET FINNS GAMMAL TEXT P] SEKTOR";C%
300 ; "SKALL DEN RADERAS (J/N) "; : GET C$
310 IF C$="J" OR C$="j" THEN 320 ELSE 150
320 U$=""
330 FOR I%=0% TO 2%
340 A$=""
350 GOSUB 700 : REM SKRIV TEXT
360 U$=U$+LEFT$(A$,INSTR(1%,A$,"<")-1%)
370 ; CUR(22,0)"MER TEXT (J/N)"; : GET C$
380 IF C$="J" OR C$="j" THEN 400
390 ; CUR(22,0);"[R DU S[KER (J/N)"; : GET C$ : IF C$="J" OR C$="j" THEN 410 ELSE 370
400 NEXT I%
410 REM 
420 U%=LEN(U$)+2% : U$=U$+" %"+SPACE$(255)
430 S%=(U%-1%)/250%
440 IF (S%+C%-R1%)<550% THEN 470
450 ; "TEXTEN KOMMER EJ ATT RYMMAS P] KVARVARANDE SEKTORER (TRYCK RETURN"; : GET C$
460 GOTO 630
470 ; CHR$(12)"TEXTEN KOMMER ATT L[GGAS UPP P] SEKTOR";C%;" TILL";C%+S%
480 ; "[R DETTA OK (J/N) "; : GET C$
490 IF C$="J" OR C$="j" THEN 540
500 ; "VILKEN SEKTOR D] D]"; : INPUT C$
510 C%=VAL(C$)
520 R1%=0%
530 GOTO 440
540 OPEN "DR1:DD1.DAT" ASFILE 1%
550 FOR I%=0% TO S%
560 R%=C%-R1%+I%
570 A$=MID$(U$,1%+(I%*250%),250%)
580 IF I%<S% THEN A$=A$+"F"+RIGHT$(NUM$(1%+I%),2%)+RIGHT$(NUM$(S%+1%),2%) : GOTO 600
590 A$=A$+SPACE$(251%-LEN(A$))+RIGHT$(NUM$(1%+I%),2%)+RIGHT$(NUM$(S%+1%),2%)
600 GOSUB 640 : REM SKRIV
610 NEXT I%
620 CLOSE 1% : ; CHR$(12)"KLART"
630 ; : ; 'FORTS[TTA (J/N)'; : GET C$ : IF C$='J' OR C$='j' 150 ELSE CHAIN 'START'
640 Z%=CALL(28666%,1%) : Q0$=A$ : Z%=CALL(28670%,R%)
650 RETURN 
660 Z%=CALL(28666%,1%)+CALL(28668%,R%) : A$=Q0$
670 RETURN 
680 CLOSE 1% : ; "DU HAR SKRIVIT FEL AVSNITT ELLER" : ; "SATT I FEL SKIVA (RETURN)";
690 GET C$ : GOTO 150
700 REM EDITERA A$
710 REM **********
720 DEFFNR%=(N%-1%)/40%
730 DEFFNK%=N%-1%-FNR%*40%
740 ; CHR$(12); : N%=1% : ; A$;
750 ; CUR(21,0)STRING$(39%,127%);
760 ; CUR(22,0)"FLYTTA *pil v{*pil h|*ctrl |*ctrl {*"
770 ; "RADERING = RETURN  *  KLART = <";
780 ; CUR(21,10)"SIDA";I%+1%; : ; CUR(21,14)"";
790 IF C$="<" THEN 900
800 ; CUR(FNR%,FNK%); : GET C$
810 IF C$=CHR$(9) THEN N%=N%+1% : IF N%>(LEN(A$)+1%) THEN N%=LEN(A$)+1%
820 IF C$=CHR$(8) THEN N%=N%-1% : IF N%<1% THEN N%=1%
830 IF C$=CHR$(13) THEN 880
840 IF C$=CHR$(28) THEN IF N%>41% THEN N%=N%-40%
850 IF C$=CHR$(27) THEN N%=N%+40% : IF N%>(LEN(A$)+1%) THEN N%=N%-40%
860 IF ASC(C$)<32 THEN 790
870 A$=LEFT$(A$,N%-1%)+C$+RIGHT$(A$,N%) : ; CUR(0,0)A$ : N%=N%+1% : GOTO 790
880 IF (LEN(A$))<N% THEN A$=LEFT$(A$,N%-1%) ELSE A$=LEFT$(A$,N%-1%)+RIGHT$(A$,N%+1%)
890 ; CUR(0,0)A$+" " : GOTO 790
900 ; CHR$(12)
910 ; A$
920 RETURN