1 REM Ins{nt av 417
10 REM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
11 REM < KEYWORD ACESS SYSTEM       <
12 REM < 'ADD ITEM' SUBSYSTEM       <
13 REM <      -----------           <
14 REM < K$=KEYWORDS,A$=ARTICLE     <
15 REM < NAME,M$=MAGAZINE,D$=DATE,  <
16 REM < P%=PAGE,W$()=AUTHORS,Z$=   <
17 REM < DATA FILE, R%='OLD' ITEMS  <
18 REM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
19 ; CHR$(12%); : ; "====== L[GGA IN TIDSKRIFTSARTIKLAR ====="
20 DIM K$(10%)=20%,W$(2%)=25%
21 REM MENU
22 FOR I%=1% TO 21% : ; CUR(I%,0%);"=" : ; CUR(I%,39%);"=" : NEXT I%
23 FOR J%=0% TO 39% : ; CUR(1%,J%);"=" : ; CUR(21%,J%)"=" : NEXT J%
24 ; CUR(2%,2%);"AKTUELL" : ; CUR(3%,3%)"FIL (EXT) >"
25 ; CUR(4%,2%)"ARTIKELNS"
26 ; CUR(5%,3%)"TITEL     >" : ; CUR(6%,2%)"TIDSKRIFT  >" : ; CUR(7%,2%)"DATUM/NR   >"
27 ; CUR(8%,2%)"SIDNUMMER  >" : ; CUR(9%,2%)"F\RFATTARE >" : ; CUR(10%,2)"EV.MEDF\R-"
28 ; CUR(11%,3%)"FATTARE   >" : ; CUR(12%,15%)"- S\KORD -"
29 FOR I%=14% TO 18% : ; CUR(I%,2%)">" : ; CUR(I%,20%)">" : NEXT I%
30 IF C% GOTO 38
31 REM 
32 ; CUR(3%,15%)""; : INPUTLINE Z$ : Z$=LEFT$(Z$,LEN(Z$)-2%) : ONERRORGOTO 57
33 OPEN "DR1:"+Z$ ASFILE 1% : ONERRORGOTO 0
34 PREPARE "DR1:"+"WORK.KAS" ASFILE 2% : GOSUB 58
35 C%=1%
36 ; CUR(20%,2%)"DET FANNS";R%;" TIDSKRIFTER I FILEN"
37 REM INPUT
38 ; CUR(5%,15%)""; : INPUTLINE A$ : A$=LEFT$(A$,LEN(A$)-2%) : IF A$="" GOTO 55
39 ; CUR(6%,15%)""; : INPUTLINE M$ : M$=LEFT$(M$,LEN(M$)-2%)
40 ; CUR(7%,15%)""; : INPUTLINE D$ : D$=LEFT$(D$,LEN(D$)-2%)
41 ; CUR(8%,15%)""; : INPUTLINE P$ : P$=LEFT$(P$,LEN(P$)-2%) : P%=VAL(P$)
42 ; CUR(9%,15%)""; : INPUTLINE W$(1%) : W$(1%)=LEFT$(W$(1%),LEN(W$(1%))-2%)
43 ; CUR(11%,15%)""; : INPUTLINE W$(2%) : W$(2%)=LEFT$(W$(2%),LEN(W$(2%))-2%)
44 FOR I%=1% TO 10% : K$(I%)="" : NEXT I%
45 FOR I%=14% TO 18% : L%=I%-13% : ; CUR(I%,4%)""; : INPUTLINE K$(L%)
46 K$(L%)=LEFT$(K$(L%),LEN(K$(L%))-2%) : IF K$(L%)="" GOTO 51
47 NEXT I%
48 FOR I%=14% TO 18% : L%=I%-8% : ; CUR(I%,22%)""; : INPUTLINE K$(L%)
49 K$(L%)=LEFT$(K$(L%),LEN(K$(L%))-2%) : IF K$(L%)="" GOTO 51
50 NEXT I%
51 GOSUB 67 : REM WRITE A NEW RECORD
52 ; CUR(20%,2%)SPACE$(35%) : ; CUR(20%,2%)"FLER ARTIKLAR (J/N) ? "; : GET B$
53 IF B$="N" OR B$="n" THEN GOTO 55
54 FOR I%=2% TO 20% : FOR J%=2% TO 38% : ; CUR(I%,J%)" " : NEXT J% : NEXT I% : GOTO 25
55 REM CLEAN UP FILES
56 CLOSE 1% : CLOSE 2% : KILL Z$ : NAME "WORK.KAS" AS Z$
57 CHAIN "KASMENU"
58 REM ** READ FILE (SUB)
59 ONERRORGOTO 72
60 FOR N%=1% TO 10% : INPUT #1%,K$(N%) : NEXT N%
61 INPUTLINE #1%,A$ : A$=LEFT$(A$,LEN(A$)-2%)
62 INPUTLINE #1%,M$ : M$=LEFT$(M$,LEN(M$)-2%)
63 INPUTLINE #1%,D$ : D$=LEFT$(D$,LEN(D$)-2%)
64 INPUT #1%,P%
65 FOR N%=1% TO 2% : INPUTLINE #1%,W$(N%) : W$(N%)=LEFT$(W$(N%),LEN(W$(N%))-2%) : NEXT N%
66 IF K$(1%)="***" RETURN 
67 REM ** WRITE FILE (SUB)
68 ONERRORGOTO 68
69 FOR N%=1% TO 10% : ; #2%,K$(N%) : NEXT N%
70 ; #2%,A$ : ; #2%,M$ : ; #2%,D$ : ; #2%,P%
71 FOR N%=1% TO 2% : ; #2%,W$(N%) : NEXT N% : R%=R%+1% : IF C% 72 ELSE GOTO 58
72 RETURN