1 REM Ins{nt av 417
1 REM Ins{nt av 417
10 REM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
11 REM < KEYWORD ACESS SYSTEM       <
12 REM < 'LIST' SUBSYSTEM           <
13 REM <      -----------           <
14 REM < K$=KEYWORDS,A$=ARTICLE     <
15 REM < NAME,M$=MAGAZINE,D$=DATE,  <
16 REM < P%=PAGE,W$()=AUTHORS,Z$=   <
17 REM < DATA FILE, N%=ITEMS        <
18 REM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
19 ; CHR$(12%); : ; "========= LISTNING AV ARTIKLAR ========="
20 ; CUR(1%,2%)"PROGRAMMET LISTAR ETT ANTAL ARTIKLAR" : ; CUR(2%,2%)"I FILEN, I DEN ORDNING DE [R INL[STA"
21 DIM K$(10%)=20%,W$(2%)=25%
22 REM *MENU
23 FOR I%=1% TO 21% : ; CUR(I%,0%);"=" : ; CUR(I%,39%);"=" : NEXT I%
24 FOR J%=0% TO 39% : ; CUR(3%,J%)"=" : ; CUR(21%,J%);"=" : NEXT J%
25 ; CUR(5%,2%);"AKTUELL" : ; CUR(6%,3%)"FIL (EXT)  >"
26 ; CUR(8%,2%)"PRINTER J/N >"
27 ; CUR(10%,2%)"F\RSTA POST-" : ; CUR(11%,3%)"NUMMER     >"
28 ; CUR(13%,2%)"SISTA POST-" : ; CUR(14%,3%)"NUMMER     >"
29 REM *OPEN FILE AND PRINTER
30 ; CUR(6%,16%)""; : INPUTLINE Z$ : Z$=LEFT$(Z$,LEN(Z$)-2%) : ONERRORGOTO 65
31 OPEN "DR1:"+Z$ ASFILE 1% : ONERRORGOTO 0
32 ; CUR(8%,16%)""; : INPUTLINE P$ : P$=LEFT$(P$,1%) : IF P$="J" OR P$="j" P1%=2%
33 OPEN "PR:" ASFILE P1%
34 REM *HEAD OF LIST
35 IF P1% ; #P1%'LISTNING AV TIDSKRIFTSARTIKLAR' : ; #P1%
36 IF P1% ; #P1%'AKTUELL FIL: ';Z$
37 ; CUR(11%,16%)""; : INPUTLINE S$ : S$=LEFT$(S$,LEN(S$)-2%) : S%=VAL(S$)
38 ; CUR(14%,16%)""; : INPUTLINE E$ : E$=LEFT$(E$,LEN(E$)-2%) : E%=VAL(E$)
39 IF P1% ; #P1%"SKRIVER UT POSTERNA";S%;"  - ";E%
40 ; CUR(22%,0%)""
41 REM *PRINT THE FILE
42 N%=N%+1%
43 ONERRORGOTO 64
44 FOR I%=1% TO 10% : INPUT #1,K$(I%) : NEXT I%
45 INPUTLINE #1,A$ : A$=LEFT$(A$,LEN(A$)-2%)
46 INPUTLINE #1,M$ : M$=LEFT$(M$,LEN(M$)-2%)
47 INPUTLINE #1,D$ : D$=LEFT$(D$,LEN(D$)-2%)
48 INPUT #1,P%
49 FOR I%=1% TO 2% : INPUTLINE #1,W$(I%) : W$(I%)=LEFT$(W$(I%),LEN(W$(I%))-2%) : NEXT I%
50 IF N%<S% GOTO 41
51 IF N%>E% GOTO 64
52 REM *PRINT ENTRY
53 ; #P1% : ; #P1%'...',N%,'...'
54 ; #P1%A$
55 ; #P1%'BY ';W$(1%);' ';W$(2%)
56 ; #P1%'  ';M$,D$ : ; #P1%'SIDA ';P%
57 FOR I%=1% TO 10%
58 IF K$(I%)="" GOTO 61
59 ; #P1%K$(I%);'    ';
60 NEXT I%
61 ; #P1%
62 IF P1% GOTO 41 ELSE GET ]$ : GOTO 41
63 REM *CLEAN UP
64 CLOSE 1% : IF P1% ; #P1% : ; #P1%'*KLAR' : ; CUR(16%,2%)"*KLAR" ELSE ; : ; "*KLAR" : GET ]$
65 CHAIN "KASMENU"