1 REM Ins{nt av 417
1 REM Ins{nt av 417
10 REM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
11 REM < KEYWORD ACESS SYSTEM       <
12 REM < 'REPORT' SUBSYSTEM         <
13 REM <     ------------           <
14 REM < K$=KEYWORDS,A$=ARTICLE     <
15 REM < NAME,M$=MAGAZINE,D$=DATE,  <
16 REM < P%=PAGE,W$()=AUTHORS,Z$=   <
17 REM < FILE NAME,Z6%=READ RECORD  <
18 REM < COUNT,Z7%=OUTPUT FILE #,   <
19 REM < Z8%=INPUT FILE #,V$=ALL    <
20 REM < KEYWORDS,Y$=NAME OF WORK   <
21 REM < FILES,S$=CUBTITLE,T$=CUR-  <
22 REM < RENT TITLE,Z$=CURRENT FILE <
23 REM < V%=NUMBER OF KEYWORDS,F6%= <
24 REM < NUMBER OF UNPRINTED ITEMS, <
25 REM < F9%=NUMBER OF WORK FILES,  <
26 REM < L5%=SCRATCH,L6%=MIN SPACE/ <
27 REM < ENTRY,L7%=CURRENT LINE,L8%=<
28 REM < CURRENT PAGE,L9%=LINES/PAGE<
29 REM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
30 DIM K$(10%),W$(2%),V$(255%)
31 ; CHR$(12%)'====== SAMTLIGA TIDNINGSARTIKLAR ======' : ; '====== SORTERADE EFTER S\KORD    ======'
32 P1%=1% : ; STRING$(39%,61%) : ; '=';TAB(38%)'='
33 FOR I%=4% TO 20% : ; CUR(I%,0%)"=" : ; CUR(I%,38%)'=' : NEXT I% : ; STRING$(39%,61%)
34 ; CUR(4%,2%)'AKTUELL' : ; CUR(5%,3%)'ARTIKELFIL' : ; CUR(6%,3%);'(MED EXT) >'
35 ; CUR(6%,15%)""; : INPUTLINE Z$ : Z$=LEFT$(Z$,LEN(Z$)-2%)
36 OPEN "PR:" ASFILE P1%
37 GOTO 59
38 REM 
39 REM I/O BLOCK **
40 REM ** READ RECORD (GOSUB)
41 ONERRORGOTO 177
42 FOR I%=1% TO 10% : INPUT #Z8%,K$(I%) : NEXT I%
43 Z6%=Z6%+1%
44 INPUTLINE #Z8%,A$ : A$=LEFT$(A$,LEN(A$)-2%)
45 INPUTLINE #Z8%,M$ : M$=LEVT$(M$,LEN(M$)-2%)
46 INPUTLINE #Z8%,D$ : D$=LEFT$(D$,LEN(D$)-2%)
47 INPUT #Z8%,P%
48 FOR I%=1% TO 2% : INPUTLINE #Z8%,W$(I%) : W$(I%)=LEFT$(W$(I%),LEN(W$(I%))-2%) : NEXT I%
49 RETURN 
50 REM ** WRITE RECORD (GOSUB)
51 FOR I%=1% TO 10% : ; #Z7%,K$(I%) : NEXT I%
52 ; #Z7%,A$
53 ; #Z7%,M$
54 ; #Z7%,D$
55 ; #Z7%,P%
56 FOR I%=1% TO 2% : ; #Z7%,W$(I%) : NEXT I%
57 RETURN 
58 REM END OF I/O BLOCK **
59 REM *CONT. OF MAIN PROGRAM
60 F9%=6%
61 REM *KEYWORD LIST
62 Z8%=2%
63 REM GET ALL KEYWORDS IN V$
64 ONERRORGOTO 130 : OPEN "DR1:"+Z$ ASFILE Z8% : \%=1% : ONERRORGOTO 0
65 GOSUB 40 : REM READ RECORD
66 FOR I%=1% TO 10%
67 IF K$(I%)="" GOTO 65
68 FOR J%=1% TO V%
69 IF K$(I%)=V$(J%) GOTO 74
70 NEXT J%
71 V%=V%+1%
72 IF V%>255% STOP : REM TO MANY UNIQUE KEYWORDS
73 V$(V%)=K$(I%)
74 NEXT I%
75 GOTO 65
76 CLOSE Z8%
77 ; CUR(8%,2%)V%;' OLIKA S\KORD INL[ST' : ; CUR(9%,2%)Z6%;' POSTER L[STA'
78 REM *SORT KEYWORDS
79 IF V%<2% GOTO 89
80 C%=0% : REM CHANGE FLAG
81 FOR I%=1% TO V%-1%
82 IF V$(I%)<V$(I%+1%) GOTO 85
83 C%=1%
84 T$=V$(I%) : V$(I%)=V$(I%+1%) : V$(I%+1%)=T$
85 NEXT I%
86 IF C%=1% GOTO 80
87 REM *BUILD A REPORT FILE FOR EACH KEYWORD
88 REM IF WE HAVE MORE KEYWORDS THAN FILES GO DO IT AGAIN
89 F6%=V%
90 T$="ARTIKELINDEX MED S\KORD" : GOSUB 148
91 F7%=1%
92 F8%=F9%
93 IF F6%<F8% THEN F8%=F6%
94 Z8%=2%
95 OPEN "DR1:"+Z$ ASFILE Z8%
96 REM *OPEN WORK FILES (A.KAS,B.KAS,..)
97 FOR I%=3% TO F8%+2%
98 Y$=CHR$(ASC("A")+I%-3%)+".KAS"
99 PREPARE "DR1:"+Y$ ASFILE I%
100 ; #I%,SPACE$(10%) : CLOSE I% : OPEN "DR1:"+Y$ ASFILE I%
101 NEXT I%
102 REM *READ RECORD
103 \%=2% : GOSUB 40
104 FOR J%=F7% TO F7%+F8%-1%
105 FOR L%=1% TO 10%
106 IF K$(L%)="" GOTO 112
107 IF V$(J%)<>K$(L%) GOTO 111
108 REM *WRITE RECORD TO CORRECT FILE
109 Z7%=J%+3%-F7%
110 GOSUB 50
111 NEXT L%
112 NEXT J%
113 GOTO 103
114 CLOSE Z8%
115 REM *REWIND FILES
116 FOR I%=3% TO F8%+2% : CLOSE I% : NEXT I%
117 FOR I%=3% TO F8%+2% : Y$=CHR$(ASC("A")+I%-3%)+".KAS" : OPEN "DR1:"+Y$ ASFILE I% : NEXT I%
118 GOSUB 133 : REM PRINT REPORTS
119 REM *DELETE WORK FILES
120 FOR I%=1% TO F8%
121 Y$=CHR$(ASC("A")+I%-1%)+".KAS"
122 CLOSE I%+2% : KILL Y$
123 NEXT I%
124 F7%=F7%+F9%
125 F6%=F6%-F8%
126 IF F6%>0% GOTO 93
127 ; #P1% : ; #P1%
128 ; #P1%" *KLAR"
129 REM 
130 CHAIN "KASMENU"
131 REM END OF MAIN PROGRAM **
132 REM 
133 REM ** PRINT KEYWORD REPORT (GOSUB)
134 L6%=3% : L9%=66%
135 FOR K%=1% TO F8%
136 Z8%=K%+2%
137 REM PRINT SUBTITLE
138 S$=V$(K%+F7%-1%) : GOSUB 159
139 \%=3% : GOSUB 40 : REM READ RECORD
140 GOSUB 168
141 ; #P1%TAB(5%);A$;"  AV ";W$(1%),W$(2%)
142 GOSUB 168
143 ; #P1%TAB(8%);M$,D$;TAB(50%);"SIDA ";P%
144 GOTO 139
145 NEXT K%
146 RETURN 
147 REM ** REPORT PAGE HANDLER (GOSUB)
148 REM INITALIZE ENTRY
149 L8%=0%
150 ; : ; 'PRINTERN KLAR ? <RETURN> '; : GET S$
151 GOTO 154
152 REM NEW PAGE AND THEN TITLE
153 FOR L5%=L7%0TO L9%+3% : ; #P1% : NEXT L5%-
154 L8%=L8%+1%
155 ; #P1%T$;TAB(70%);"- ";L8%;"-"
156 ; #P1% : ; #P1%
157 L7%=4%
158 RETURN 
159 REM SET SUBTITLE
160 ; #P1% : L7%=L7%+1%
161 REM IF NO ROOM FOR 1 ENTRY THEN PAGE EJECT
162 IF L7%<L9%-5%-L6% GOTO 165
163 REM NEW PAGE & PRINT TITLEk
164 GOSUB 153
165 ; #P1%S$ : REM SUBTITLE
166 L7%=L7%+1%
167 RETURN 
168 REM - LINE COUNT
169 IF L7%<L9%-5% GOTO 174
170 REM NEW PAGE & PRINT TITLE
171 GOSUB 153
172 ; #P1%S$;" (FORTS )"
173 L7%=L7%+1%
174 L7%=L7%+1%
175 RETURN 
176 REM END OF REPORT PAGE HANDLER**
177 ON \% GOTO 76,114,178
178 IF K%=F8% GOTO 119 ELSE GOTO 145