10 REM ++++++++++++++++++++++++++++++++
20 REM ! Program ....   TIME          !
30 REM ! Utg}va         840715        !
40 REM ! Id` fr}n YOUR COMPUTER       !
50 REM ! \versatt,{ndrat och ut|kat av!
60 REM ! Sten Axtelius tel.0589/13711 !
70 REM ! Minne 16 Kbytes              !
80 REM ! Ins{nt av 3452               !
90 REM ++++++++++++++++++++++++++++++++
100 A$='' : F1%=0% : I1%=0% : S1%=1% : I%=0%
110 DIM L$=250%
120 GOSUB 2010
130 RANDOMIZE 
140 GOSUB 1640
150 N%=0% : V%=N% : \%=N% : S%=N% : U%=N% : D%=N%
160 L$=''
170 ON S1% GOSUB 640,670,700,730,760,800,830,860,890,930,960,990,1020,1030,1060,1090,1120,1160
180 PRINT CHR$(12%) : PRINT CUR(8%,0%)L$
190 GOTO 240
200 F%=0% : FOR N9%=1% TO 12% : IF L%(N9%)<>S1% THEN 230 ELSE 210
210 IF F%=0% PRINT : PRINT 'Jag kan se..'; : F%=1%
220 IF N9%=1% OR N9%=9% OR N9%=11% OR N9%=12% PRINT 'ett ';O$(N9%)' '; ELSE PRINT 'en ';O$(N9%)' ';
230 NEXT N9%
240 PRINT 
250 IF INSTR(1%,A$,'TI')<>0% AND F%=0% PRINT 'Jag ser inget specielt.'
260 B$='' : PRINT : PRINT 'Vad ska jag g|ra '; : INPUTLINE A$ : A$=LEFT$(A$,LEN(A$)-2%) : IF A$='' THEN 260 : PRINT 
270 IF LEN(A$)=1% THEN 610
280 IF A$='' THEN 260 : PRINT 
290 IF LEFT$(A$,2)='G]' PRINT 'SKRIV BARA RIKTNINGEN !' : GOTO 260
300 IF LEN(A$)=1% THEN 350
310 IF INSTR(1%,A$,' ')=0% THEN 350
320 A1$=LEFT$(A$,INSTR(1%,A$,' ')-1%)
330 B$=RIGHT$(A$,INSTR(1%,A$,' ')+1%)
340 A$=A1$
350 IF F1%=1% GOTO 370
360 IF S1%=9% AND RND>.95 PRINT 'Hunden vaknade och }t upp dig !!' : GOTO 2120
370 IF INSTR(1%,A$,'KO')<>0% GOSUB 2010
380 IF INSTR(1%,A$,'NO')<>0% AND N% THEN S1%=N% : GOTO 150
390 IF INSTR(1%,A$,'S\')<>0% AND S% THEN S1%=S% : GOTO 150
400 IF INSTR(1%,A$,'V[')<>0% AND V% THEN S1%=V% : GOTO 150
410 IF INSTR(1%,A$,'\S')<>0% AND \% THEN S1%=\% : GOTO 150
420 IF INSTR(1%,A$,'NE')<>0% AND D%=16% AND L%(3%)<>0% GOTO 2100
430 IF INSTR(1%,A$,'NE')<>0% AND D%=9% AND F1%=0% THEN 1860
440 IF INSTR(1%,A$,'NE')<>0% AND D% THEN S1%=D% : GOTO 150
450 IF INSTR(1%,A$,'IN')<>0% THEN GOSUB 1710 : GOTO 260
460 IF INSTR(1%,A$,'RA')<>0% GOTO 180
470 IF INSTR(1%,A$,'HJ')<>0% PRINT 'Ingen chans !' : GOTO 260
480 IF INSTR(1%,A$,'SI')<>0% THEN 1490
490 IF INSTR(1%,A$,'MA')<>0% THEN 1430
500 IF INSTR(1%,A$,'SL')<>0% THEN 1560
510 IF INSTR(1%,A$,'\P')<>0% THEN 1280
520 IF INSTR(1%,A$,'TI')<>0% THEN 200
530 IF INSTR(1%,A$,'TA')<>0% THEN 1190
540 IF INSTR(1%,A$,'KR')<>0% THEN 1770
550 IF INSTR(1%,A$,'T[')<>0% THEN 1960
560 IF INSTR(1%,A$,'L[')<>0% THEN 1890
570 IF INSTR(1%,A$,'L]')<>0% THEN 1360
580 IF INSTR(1%,A$,'S[')<>0% THEN 1940
590 IF INSTR(1%,A$,'GE')<>0% THEN 2120
600 IF INSTR(1%,A$,'UP')<>0% GOTO 1810
610 IF LEN(A$)=1% PRINT 'Jag vill ha MINST 2 bokst{ver !!' : GOTO 260
620 PRINT 'Jag kan inte 'A$' 'B$' !' : B$='' : F%=1% : GOTO 260
630 RETURN 
640 L$='Du {r i en skog. det g}r stigar }t norr och s|der.'
650 N%=14% : S%=2%
660 RETURN 
670 L$='Du {r i en skog med stigar som g}r }t   norr och |ster och en gl{nta till v{ster'
680 N%=1% : \%=4% : V%=3%
690 RETURN 
700 L$='Du {r p} en gl{nta. I mitten st}r en    tidsmaskin, som saknar kraftk{lla.      Utg}ng till |ster.'
710 \%=2%
720 RETURN 
730 L$='Du {r i en skog.                        Det g}r en stig |st-v{st.'
740 V%=2% : \%=5%
750 RETURN 
760 L$='Du {r i en skog. Genom en |ppning }t    norr kan du se en sj|.'
770 L$=L$+'En stig g}r       |st-v{st och en grotta s|derut.'
780 \%=11% : V%=4% : S%=6%
790 RETURN 
800 L$='Du {r i en liten grotta. Dagsjlus kommerin fr}n norr. Det {r en d|rr }t v{ster  och en |ppning }t s|der.'
810 S%=7% : N%=5%
820 RETURN 
830 L$='Du {r i en stor h}la. D{r st}r en kista i ett h|rn. Endast utg}ng }t norr.'
840 N%=6%
850 RETURN 
860 L$='Jag kan inte se n}got !'
870 U%=6%
880 RETURN 
890 L$='Du {r i en l}ng tunnel med |ppning }t   s|der. Du h|r vatten droppa. ]t norr    finns en trappa.'
900 L$=L$+'En storhund sover p}    golvet.'
910 S%=8%
920 RETURN 
930 L$='Du {r p} en | i mitten p} sj|n. Det {r  en |ppning i marken med en trappa.'
940 D%=9%
950 RETURN 
960 L$='Du st}r vid sj|n. Det {r en | i mitten. ]t v{ster {r skogen och }t norr ett     stenr|s.'
970 N%=12% : V%=5%
980 RETURN 
990 L$='Du st}r i ett stenr|s. Sj|n {r }t v{steroch det {r vass }t norr. V{g bara }t    s|der eller norr.'
1000 N%=13% : S%=11%
1010 RETURN 
1020 PRINT CHR$(12%) : PRINT 'Du sjunker ner i ett k{rr glurp glurp ..' : GOTO 2120
1030 L$='Du {r i en tv{ttstuga. Sj|n {r }t |ster.Skogen {r }t s|der och en {ng }t norr.  P} v{ggen finns en hylla.'
1040 N%=15% : S%=1% : \%=11% : U%=18%
1050 RETURN 
1060 L$='Du st}r p} en {ng. Sj|n finns }t syd|st.Till s|der ser du en tv{ttstuga och }t  |ster ett torn.'
1070 \%=16% : S%=14%
1080 RETURN 
1090 L$='Du st}r vid foten av tornet. Du kan intese n}gon d|rr. Till v{ster {r en {ng och}t |ster {r det vass.'
1100 V%=15% : \%=13% : U%=17%
1110 RETURN 
1120 L$='Du st}r p} toppen av tornet. Du kan se  en sj| med en | }t s|der och skogen p}  andra sidan.'
1130 L$=L$+' I mitten av plattformen {r det en glas-l}da med ett batteri i.'
1140 D%=16%
1150 RETURN 
1160 L$='Du {r p} en hylla i tv{ttstugan'
1170 D%=14%
1180 RETURN 
1190 IF I%>=5% PRINT 'Jag kan inte b{ra mera !.' : GOTO 260
1200 IF B$='' AND F%=1% PRINT 'TA vad ??'; : INPUT B$ : F%=0% : GOTO 1200
1210 IF B$='' PRINT A$' vad d} ????' : GOTO 260
1220 F%=0% : FOR N9%=1% TO 12% : IF O$(N9%)=B$ AND I%<5% AND L%(N9%)=S1% PRINT 'Ok.' : F%=1% : L%(N9%)=0% : I%=I%+1%
1230 NEXT N9%
1240 IF F%=0% THEN 620
1250 B$=''
1260 F%=0%
1270 GOTO 260
1280 IF B$='' PRINT '\ppna vad ??'; : INPUT B$ : GOTO 1280
1290 IF B$='D\RR' AND S1%<>6% PRINT 'Vilken d|rr ??' : GOTO 260
1300 IF B$='D\RR' AND U2%=0% PRINT 'Den {r l}st !!' : GOTO 260
1310 IF B$='D\RR' PRINT 'Det g}r en trappa ned}t.' : D%=8% : GOTO 260
1320 IF B$='KISTA' AND S1%<>7% THEN PRINT 'Jag ser ingen kista !' : GOTO 260
1330 IF B$='KISTA' AND U1%=0% THEN PRINT 'Den {r l}st !' : GOTO 260
1340 IF B$='KISTA' PRINT 'Ok.' : L%(12%)=7% : GOTO 260
1350 A$='\PPNA' : GOTO 620
1360 IF B$='' PRINT 'L}sa upp vad ??'; : INPUT B$ : GOTO 1360
1370 IF B$='D\RR' AND S1%<>6% PRINT 'Vilken d|rr ??' : GOTO 260
1380 A$='L]SA UPP' : IF L%(7%) THEN 620
1390 IF B$='D\RR' U2%=1% : PRINT 'Klick !' : GOTO 260
1400 IF B$='KISTA' AND S1%<>7% PRINT 'Vilken kista ??' : GOTO 260
1410 IF B$='KISTA' U1%=1% : PRINT 'Kluck !' : GOTO 260
1420 A$='L]SA UPP' : GOTO 620
1430 IF B$='' PRINT 'Mata vad d} '; : INPUT B$ : GOTO 1430
1440 IF B$<>'HUND' PRINT 'Var inte larvig !' : A$='MATA' : GOTO 620
1450 IF S1%=9% OR S1%=10% THEN 1460 ELSE PRINT 'Det finns ingen hund h{r !' : GOTO 260
1460 IF L%(12%) PRINT 'Jag har ingen hundmat !' : GOTO 260
1470 I%=I%-1% : F1%=1% : U%=10% : PRINT 'Smask slafs ..' : L%(12%)=20% : GOTO 260
1480 GOTO 620
1490 IF S1%=11% AND L%(10%)=0% THEN 1520
1500 IF S1%=10% AND L%(10%)=0% THEN 1530
1510 IF S1%=10% OR S1%=11% THEN 1540 ELSE 1550
1520 S1%=10% : GOTO 160
1530 S1%=11% : GOTO 160
1540 PRINT 'BRR vattnet {r f|r kallt !' : GOTO 260
1550 PRINT 'Det finns inget vatten h{r !' : GOTO 260
1560 IF B$='' AND I%=0% THEN 1580
1570 IF B$='' PRINT 'Sl{ppa vad ??'; : INPUT B$ : GOTO 1570
1580 IF B$='' THEN PRINT 'Sl{ppa vad d} ??' : GOTO 260
1590 F%=0% : FOR N9%=1% TO 12% : IF O$(N9%)=B$ AND L%(N9%)=0% THEN PRINT 'Ok..' : F%=1% : L%(N9%)=S1% : I%=I%-1%
1600 NEXT N9%
1610 IF F%=0% THEN PRINT 'Jag har ingen 'B$' !  '
1620 B$=''
1630 GOTO 260
1640 U2%=0% : U1%=0%
1650 DIM O$(13%),L%(13%)
1660 RESTORE 1670
1670 DATA REP,16,STEN,12,STEGE,10,GULDRING,5,PISTOL,14,'S[KRING',15 
1680 DATA NYCKEL,5,FACKLA,11,BATTERI,20,SIMDYNA,10,KORT,18,BEN,20
1690 FOR N9%=1% TO 12% : READ O$(N9%),L%(N9%) : NEXT N9%
1700 RETURN 
1710 F%=0% : FOR N9%=1% TO 12% : IF L%(N9%)<>0% THEN 1740
1720 IF F%=0% PRINT 'Jag har f|ljande prylar..' : F%=1%
1730 PRINT O$(N9%)
1740 NEXT N9%
1750 IF F%=0% PRINT 'Jag har ingenting !!'
1760 RETURN 
1770 IF B$='' PRINT 'Vad '; : INPUT B$ : GOTO 1770
1780 IF B$<>'GLAS' OR S1%<>17% A$='KROSSA' : GOTO 620
1790 IF L%(2%) THEN PRINT 'Ingenting att krossa med' : GOTO 260
1800 PRINT 'PANG SKRAMMEL !!' : I%=I%-1% : L%(9%)=S1% : L%(2%)=S1% : GOTO 260
1810 IF S1%=9% THEN 1860
1820 IF L%(3%)<>0% AND U%=17% PRINT 'Det finns ingen v{g upp !' : GOTO 260
1830 IF L%(3%)<>0% AND U%=18% PRINT 'Jag n}r inte upp !' : GOTO 260
1840 IF U% S1%=U% : GOTO 150
1850 PRINT 'Jag kan inte g} upp !' : GOTO 260
1860 IF F1%=0% PRINT 'Det {r en stor hund iv{gen !' : GOTO 260
1870 S1%=10% : GOTO 150
1880 GOTO 620
1890 IF B$='' THEN PRINT 'L{sa vad '; : INPUT B$ : GOTO 1890
1900 IF B$<>'KORT' A$='L[SA' : GOTO 620
1910 IF L%(11%) PRINT 'Jag har inget kort !' : B$='' : GOTO 260
1920 PRINT 'Det st}r: H{lsningar fr}n Bor}s.' : ; '          EMMA & GUSTAV' : B$='' : GOTO 260
1930 GOTO 620
1940 IF L%(9%) OR S1%<>3% A$='S[TTA IN' : GOTO 620
1950 PRINT CHR$(12%) : PRINT 'Du har lyckas fixa det h{r' : GOTO 2120
1960 IF B$='' PRINT 'T{nda vad '; : INPUT B$ : GOTO 1960
1970 IF L%(8%) A$='T[NDA' : GOTO 620
1980 IF S1%=8% AND B$='FACKLA' N%=9% : GOTO 1990 ELSE 2000
1990 L$='Du st}r i ett litet rum. Det {r en      trappa }t |ster och en fuktig g}ng }t   norr.' : GOTO 180
2000 PRINT 'Det d{r gjorde ingen nytta.' : GOTO 260
2010 PRINT CHR$(12%) : PRINT '            TIDSMASKINEN'
2020 PRINT : PRINT : PRINT 'Du har kommit till en annan tids}lder'
2030 PRINT 'Du m}ste hitta en v{g tillbaka till din egen tid med hj{lp av en tidsmaskin.'
2040 PRINT : PRINT 'KOMMANDON {r:';
2050 PRINT 'NORR,S\DER,V[STER,\STER,NER,UPP,RADERA(sk{rm),INVENTERA,KOMMANDON,'
2060 PRINT 'KROSSA,T[NDA,L[SA,L]SA UPP,TA,SL[PPA,   \PPNA,MATA,TITTA,SIMMA,S[TT IN,GER UPP, HJ[LP.'
2070 PRINT : PRINT 'De 2 f|rsta bokst{verna r{cker.' : PRINT 'Anv{nd bara STORA bokst{ver.'
2080 PRINT : PRINT : PRINT 'Tryck n}gon tangent f|r att starta.'
2090 GET A$ : A$='RA' : RETURN 
2100 PRINT CHR$(12%)
2110 PRINT 'Ett fall fr}n ett 73m h|gt torn kan intedu klara.'
2120 PRINT 'Vill du f|rs|ka igen (J/N)'; : GET A$
2130 IF A$='J' THEN 100
2140 END