1 DIM A$(37)=40,A1$(18)=42,A2$(37)=40,R%(36),K%(36),A1(22),T%(36%),D(40%) : RANDOMIZE 
2 REM ****************************
3 REM * MEMORY V 1.0   900407    *
4 REM * till ABC80 med 16/32k    *
5 REM * eller 40                 *
6 REM * Skulle kr}ngel uppsto    *
7 REM * skriv i MSG eller till   *
8 REM * Christofer Landgren<7471>*
9 REM * Till alla ABC-klubbs     * 
10 REM * Medlemmar. Go p}sk!      *
11 REM ****************************
12 REM 
13 ; CHR$(12)
14 ; CUR(1,0);"======================================="
15 FOR I%=2% TO 22% : ; CUR(I%,0%)"I";CUR(I%,38%)"I"; : NEXT I%
16 ; CUR(23,0);"======================================="
17 ; CUR(2,15);"Memory"
18 ; CUR(3,15);"======"
19 ; CUR(5,3);"Hej h{r {r ett nytt amazing spel"
20 ; CUR(6,3);"till ABC80. Spelet {r  klassiskt"
21 ; CUR(7,3);"och g}r ut p} att man har  olika"
22 ; CUR(8,3);"kort som passar  ihop  i  par s}"
23 ; CUR(9,3);"att det  g{ller  att  hitta  dom"
24 ; CUR(10,3);"paren f|re datorn g|r det."
25 ; CUR(11,3);"  P} grund av datorn har man ett"
26 ; CUR(12,3);"hj{lpmedel som kallas f|r  Wild-"
27 ; CUR(13,3);"card och hittar du det s} hittar"
28 ; CUR(14,3);"automatiskt det andra kortet."
29 ; CUR(16,13);"Enkelt va!!!"
30 D%=0% : ; CUR(20,5);"Vill du b|rja "; : GET A$(0)
31 ; CHR$(12%);
32 ; CUR(0%,0%)'                                       ';
33 ; CUR(1%,0%)'   j####k####k####k####k####k####k####k';
34 ; CUR(2%,0%)'   j  n j f$ j "9 j jz j j3 j js j #; j';
35 ; CUR(3%,0%)'   j  * j -$ j (& j  * j (& j *. j &  j';
36 ; CUR(4%,0%)'   j,,,,n,,,,n,,,,n,,,,n,,,,n,,,,n,,,,n';
37 ; CUR(5%,0%)'   j `,0j <4 j`4<4j`4x j`480j`4,0j`444j';
38 ; CUR(6%,0%)'   j (s$j #5 j 5u5j 5j j 5v0j 5r$j 5#5j';
39 ; CUR(7%,0%)'   jppppzppppzppppzppppzppppzppppzppppz';
40 ; CUR(8%,0%)'   j ``pj 0p0j 0p0j 0`0j 0p0j 0`pj 0 0j';
41 ; CUR(9%,0%)'   j k*dj"5=4j"58!j"59fj"5-5jb&jjjb&"5j';
42 ; CUR(10%,0%)'   j ""!j !#!j !! j !"!j ! !j"#"#j"# !j';
43 ; CUR(11%,0%)'   j####k####k####k####k####k####k####k';
44 ; CUR(12%,0%)'   j(9(9j(9"9j(9jzj(9j3j(9jsj(9";j(9(9j';
45 ; CUR(13%,0%)'   j*,*,j*,(&j*, *j*,(&j*,*.j*,* j*,"&j';
46 ; CUR(14%,0%)'   j,,,,n,,,,n,,,,n,,,,n,,,,n,,,,n,,,,n';
47 ; CUR(15%,0%)'   j`dhlj(dhlj(d`4j(d`dj(d(dj(dhhj(dh,j';
48 ; CUR(16%,0%)'   jhq"kj`9jzj`9 5j`9hqj`9`9j`9"kj`9b{j';
49 ; CUR(17%,0%)'   jppppzppppzppppzppppzppppzppppzppppz';
50 REM 
51 ; CUR(19%,0%)'                                       ';
52 ; CUR(20%,0%)'                                       ';
53 ; CUR(21%,0%)'                                       ';
54 ON INT(RND*2+1) RESTORE 56,59
55 RESTORE 56 : FOR I%=1% TO 18% : READ A$(I%) : NEXT I% : RESTORE 56 : FOR I%=19% TO 35% : READ A$(I%) : NEXT I%
56 DATA "Raspberry","Chimney","Green stuff","Free day","Computer","Dust","Strawberry","Caramel custard"
57 DATA "Mustard","Rock blaster","Bastard","Blue berry","Black berry","Shutney","Bluff","Bashfulness"
58 DATA "Shyness","WILD"
59 DATA "Smog,"Smoke","Snaffle","Snake","Mosque","Pharos","Pick","Pie"
60 DATA "Graph","Grasp","Grate","Griddle","Grotto","Slug","Sloyd","Modd"
61 DATA "Verger","WILD"
62 ; CUR(1,0)"S=";CHR$(151);CUR(5,0);"D=";CHR$(151);
63 FOR I%=1% TO 35%
64 R%=INT(RND*35%+1%) : IF R%(R%)=1% THEN 64
65 R%(R%)=1% : A2$(I%)=A$(R%) : NEXT I%
66 RESTORE 67 : FOR I%=1% TO 35% : READ R%(I%),K%(I%) : NEXT I%
67 DATA 4,10,4,20,4,30,4,40,4,50,4,60,4,70
68 DATA 14,10,14,20,14,30,14,40,14,50,14,60,14,70
69 DATA 24,10,24,20,24,30,24,40,24,50,24,60,24,70
70 DATA 34,10,34,20,34,30,34,40,34,50,34,60,34,70
71 DATA 44,10,44,20,44,30,44,40,44,50,44,60,44,70
72 RESTORE 73 : FOR I%=0 TO 22 : READ A1(I%) : NEXT I%
73 DATA 31744,31872,32000,32128,32256,32384,32512,32640
74 DATA 31784,31912,32040,32168,32296,32424,32552,32680
75 DATA 31824,31952,32080,32208,32336,32464,32592,32720
76 IF A$(0)="n" OR A$(0)="N" 104
77 GOSUB 138
78 FOR I%=1% TO 35% : IF T%(I%)=0% 85 ELSE NEXT I% : ; CHR$(12);"GAME OVER!!!!"
79 ; "DU FICK ";P%;" OCH JAG FICK ";P1%
80 IF P1%>P% GOTO 83
81 ; "ALLTS] VANN DU.  FUSK!!!!!!" : ; "Jag har aldrig f|r m|tt en s}dan motst}ndare"
82 END 
83 ; "ALLTS] VANN JAG. JIPIE HIPIE            Nu skall jag g} och k|pa mig en coca."
84 END 
85 GOSUB 140
86 ONERRORGOTO 86 : ; CUR(19,2);CHR$(135);"LUCKA NR    ";CHR$(151);CUR(19,11); : INPUT A : IF A>35 OR A<1 THEN 86
87 IF T%(A)=1% OR T%(A)=2% 86
88 ; CUR(19,15)A2$(A) : IF NOT A2$(A)="WILD" GOTO 93
89 ; CHR$(7); : T%(A)=1% : GOSUB 135 : FOR I%=1% TO 35% : IF T%(I%)=1% OR T%(I%)=2% 92
90 ONERRORGOTO 90 : A=I% : ; CUR(19,15)A2$(A);CUR(20,2);CHR$(135);"LUCKA NR?  "
91 GOSUB 135 : GOTO 101
92 NEXT I%
93 GOSUB 135
94 ; CUR(20,2);CHR$(135);"LUCKA NR    ";CHR$(151);CUR(20,11); : INPUT B
95 IF B>35 OR B<1 THEN 94 ELSE IF A=B OR B=A THEN 94 ELSE IF T%(B)=1% OR T%(B)=2% 94
96 GOSUB 136
97 ; CUR(20,11)B;CUR(20,11);"?";CUR(20,15)A2$(B) : IF A2$(B)="WILD" ; CHR$(7); : GOTO 101
98 IF A2$(A)=A2$(B) T%(A)=1% : T%(B)=1% : P%=P%+1% : GOTO 77
99 FOR I%=1% TO 2500% : NEXT I%
100 FOR I%=2% TO 17% : ; CUR(I%,2%);A1$(I%); : NEXT I% : GOTO 104
101 FOR I%=1% TO 35% : IF I%=A THEN 103
102 IF A2$(I%)=A2$(A) THEN T%(A)=1% : T%(B)=1% : T%(I%)=1% : P%=P%+1% : B=I% : GOTO 96
103 NEXT I% : GOTO 98
104 REM ****************************
105 REM ** DATOR SPELARE          **
106 REM ****************************
107 D1%=0% : D2%=0% : IF D%=0% THEN 112
108 FOR I%=1% TO D% : FOR K%=I%+1% TO D% : IF A2$(D(I%))=A2$(D(K%)) THEN 110 ELSE 109
109 NEXT K% : NEXT I% : GOTO 112
110 IF T%(D(I%))=1% OR T%(D(K%))=1% THEN 109
111 D1%=D(I%) : D2%=D(K%) : D(I%)=0% : D(K%)=0% : GOTO 122
112 D1%=INT(RND*35+1) : D2%=INT(RND*35+1)
113 D(0)=0 : FOR I%=1% TO 35% : IF T%(I%)=0% THEN D(0)=D(0)+1%
114 NEXT I% : IF D(0)=2 OR D(0)=3 THEN 77
115 IF A2$(D1%)="WILD" OR A2$(D2%)="WILD" THEN 112 ELSE IF D1%=D2% THEN 112
116 FOR I%=1% TO D% : IF D1%=D(I%) OR D2%=D(I%) THEN 112 ELSE NEXT I%
117 IF T%(D1%)=1% OR T%(D2%)=1% THEN 112 ELSE IF D1%=0% OR D2%=0% 112
118 IF A2$(D1%)=A2$(D2%) THEN 122
119 D%=D%+1% : D(D%)=D1% : D%=D%+1% : D(D%)=D2%
120 GOSUB 142
121 GOSUB 140 : ; CUR(19,2)CHR$(135)D1%" "A2$(D1%)CUR(20,2)CHR$(135)D2%" "A2$(D2%) : GOTO 77
122 A=D1% : B=D2% : GOSUB 135 : GOSUB 136 : GOSUB 140
123 ; CUR(19,2);CHR$(135);"JAG TAR LUCKA NR:"D1%;" ";A2$(D1%)
124 ; CUR(20,2);CHR$(135);"OCH LUCKA NR:"D2%;" ";A2$(D2%)
125 GOSUB 138 : GOSUB 142 : T%(D1%)=1% : T%(D2%)=1% : P1%=P1%+1% : GOTO 107
126 REM 
127 REM 
128 REM 
129 REM 
130 REM 
131 REM 
132 REM ****************************
133 REM ** SLUT COMPUTER          **
134 REM ****************************
135 I%=A : GOSUB 137 : RETURN 
136 I%=B : GOSUB 137 : RETURN 
137 FOR R%=R%(I%) TO R%(I%)+8 : FOR K%=K%(I%) TO K%(I%)+8 : CLRDOT R%,K% : NEXT K% : NEXT R% : RETURN 
138 FOR I%=2% TO 17% : A1$(I%)="" : FOR K%=2% TO 39% : A1$(I%)=A1$(I%)+CHR$(PEEK(A1(I%)+K%)) : NEXT K% : NEXT I%
139 RETURN 
140 ; CUR(19,2)SPACE$(37)CUR(20,2)SPACE$(37)
141 ; CUR(2,0);P%;CHR$(151);CUR(6,0);P1%;CHR$(151); : RETURN 
142 FOR I%=1% TO D% : IF D(I%)=0% THEN 143 ELSE 144
143 FOR K%=I%+1% TO D% : D(K%-1%)=D(K%) : NEXT K% : D%=D%-1% : GOTO 142
144 NEXT I% : RETURN