1 REM Ins{nt av 774
10 REM 
20 REM  Program ....   ARKEN
30 REM  Utg}va  1.3    840404
40 REM  av (c) OK[ND
50 REM  {ndrat av Per larsen
60 REM  Minne 16 Kbytes f|r flexskiva
70 REM  Ins{nt av Per larsen
80 REM 
90 REM 
100 DIM F$(500%)
110 DIM J$(500%)
120 DIM N$(500%)
130 REM 
140 S$=CHR$(12%)
150 L$='DR1:'
160 REM 
170 REM  INSTRUKTIONER 
180 REM 
190 PRINT S$
200 PRINT STRING$(79%,61%)
210 PRINT TAB(17%);'*****';TAB(36%);'ARKEN';TAB(55%);'*****'
220 PRINT STRING$(79%,61%)
230 PRINT : PRINT : PRINT : PRINT 
240 PRINT 'Du skall t{nka p} ett djur, som datorn skall f|rs|ka leta sig fram till med '
250 PRINT 'hj{lp av dina svar...' : PRINT 
260 PRINT 'Om datorn inte kan djuret, s} kommer den att l{ra sig det med din hj{lp..' : PRINT 
270 PRINT 'Hur intelligent datorn blir beror p} DINA svar. ( skit in = skit ut )....' : PRINT 
280 PRINT 'Du m}ste ha en disk med filen DJUR.DAT.' : PRINT 
290 PRINT 'Om disken tar slut s} s{tter du i en ny och trycker p} RETURN.'
300 PRINT 'Programmet g|r d} en ny fil med alla djur p}........'
310 PRINT CUR(20,5)'HAR DU FILEN DJUR.DAT (J/N) ';
320 GET V$
330 IF V$<>'J' AND V$<>'N' THEN 310
340 IF V$='J' THEN 520
350 REM 
360 REM  SKALL NY FIL SKAPAS 
370 REM 
380 PRINT S$;'Om den finns kommer den att raderas....' : PRINT 
390 PRINT 'Skall jag tillverka filen DJUR.DAT ? :';
400 GET V$
410 IF V$<>'J' THEN END 
420 REM 
430 REM  SKAPA FIL 
440 REM 
450 PREPARE L$+'DJUR.DAT' ASFILE 1%
460 OPEN L$+'INIT.DAT' ASFILE 2%
470 FOR I%=1% TO 19%
480 INPUTLINE #2%,T$
490 PRINT #1%,LEFT$(T$,LEN(T$)-2%)
500 NEXT I%
510 CLOSE 1% : CLOSE 2%
520 REM 
530 REM  FILEN FINNS 
540 REM 
550 OPEN L$+'DJUR.DAT' ASFILE 1%
560 INPUT #1%,A%
570 FOR I%=1% TO A%
580 INPUTLINE #1%,F$(I%)
590 INPUTLINE #1%,J$(I%)
600 INPUTLINE #1%,N$(I%)
610 F$(I%)=LEFT$(F$(I%),LEN(F$(I%))-2%)
620 J$(I%)=LEFT$(J$(I%),LEN(J$(I%))-2%)
630 N$(I%)=LEFT$(N$(I%),LEN(N$(I%))-2%)
640 NEXT I%
650 CLOSE 1%
660 REM 
670 REM  HUVUD-PROGRAM 
680 REM 
690 X%=1%
700 PRINT S$
710 PRINT 'VAD KAN DET VARA F\R DJUR DU T[NKER P] ?' : PRINT 
720 PRINT F$(X%);' ? :';
730 GET V$ : PRINT V$
740 IF ASC(V$)=3% THEN 1220
750 IF V$='J' THEN 790
760 IF V$='N' THEN 820
770 PRINT CHR$(7%)
780 GOTO 720
790 ONERRORGOTO 850
800 IF VAL(J$(X%))>1% THEN X%=VAL(J$(X%)) ELSE 850
810 GOTO 720
820 ONERRORGOTO 870
830 IF VAL(N$(X%))>1% THEN X%=VAL(N$(X%)) ELSE 870
840 GOTO 720
850 ONERRORGOTO 0 : A$=J$(X%) : J%=1% : N%=0%
860 GOTO 880
870 ONERRORGOTO 0 : A$=N$(X%) : J%=0% : N%=1%
880 PRINT 'T[NKER DU P] ';A$;' ? :';
890 GET V$ : PRINT 
900 PRINT 
910 IF V$='J' THEN PRINT 'HURRA! JAG KLARADE DET.' : S%=1% : GOTO 1430
920 IF V$<>'N' THEN PRINT 'SVARA (J/N)' : GOTO 880
930 PRINT 'D] KAN JAG INTE, DU F]R L[RA MIG.' : PRINT 
940 PRINT 'VAD VAR DET F\R DJUR '; : INPUTLINE D$
950 D$=LEFT$(D$,LEN(D$)-2%)
960 PRINT 
970 REM 
980 REM  KOLLA OM OBEST[MD ARTIKEL FINNS 
990 REM 
1000 IF MID$(D$,1%,2%)='EN' THEN 1080
1010 IF MID$(D$,1%,2%)='ET' THEN 1080
1020 PRINT 'ANGE OBEST[MD ARTIKEL '
1030 PRINT 'EN ELLER ETT ';
1040 INPUT V$
1050 PRINT 
1060 IF V$='EN' OR V$='ETT' THEN 1070 ELSE 1020
1070 D$=V$+' '+D$
1080 PRINT 'ST[LL EN FR]GA SOM SKILJER ';D$
1090 PRINT 'FR]N ';A$;' '; : PRINT 
1100 PRINT '>>>'; : INPUTLINE F$(A%+1%) : PRINT 
1110 F$(A%+1%)=LEFT$(F$(A%+1%),LEN(F$(A%+1%))-2%)
1120 PRINT 'OM DET [R ';D$;', VAD [R D] SVARET ';
1130 GET V$ : PRINT 
1140 IF V$='J' THEN J$(A%+1%)=D$ : N$(A%+1%)=A$
1150 IF V$='N' THEN N$(A%+1%)=D$ : J$(A%+1%)=A$
1160 IF V$<>'J' AND V$<>'N' THEN PRINT 'SVARA (J/N)' : GOTO 1120
1170 A%=A%+1%
1180 IF J%=1% THEN J$(X%)=NUM$(A%)
1190 IF N%=1% THEN N$(X%)=NUM$(A%)
1200 GOTO 1430
1210 REM 
1220 REM  SPARA DATA 
1230 REM 
1240 ONERRORGOTO 1350
1250 PREPARE L$+'DJUR.DAT' ASFILE 1%
1260 PRINT #1%,A%
1270 REM 
1280 FOR I%=1% TO A%
1290 PRINT #1%,F$(I%)
1300 PRINT #1%,J$(I%)
1310 PRINT #1%,N$(I%)
1320 NEXT I%
1330 CLOSE 1%
1340 END 
1350 REM 
1360 REM  SKRIVERROR 
1370 REM 
1380 CLOSE 1%
1390 PRINT 'DET G]R INTE ATT F] IN DATA P] DISKEN'
1400 PRINT ']TG[RDA FELET OCH TRYCK P] RETURN.';
1410 INPUTLINE V$
1420 GOTO 1220
1430 REM 
1440 REM  NYTT F\RS\K 
1450 REM 
1460 PRINT : PRINT 'VILL DU PROVA IGEN (J/N) ?';
1470 GET V$
1480 IF V$='J' THEN 670 ELSE 1220