1 REM ++++++++++++++++++++++++++++++++
2 REM ! Program ....   BYR]KRAT.BAS
3 REM ! Utg}va  1.1    1983
4 REM ! av (c)  Ove Oskarsson, 
5 REM !         Tage Magnusson,
6 REM !         Henrik Schi|ld
7 REM ! screenat av Tom Sj|berg 2401
8 REM ! Minne 16 Kbytes
9 REM ! Ins{nt av Bo Lund  849
10 REM ++++++++++++++++++++++++++++++++
11 DIM A$(7,8),B$(8),C$(20),R%(8),U$=40
12 DIM U9$(4)
13 V1=0
14 S$=SPACE$(1)
15 PRINT CHR$(12)
16 ; TAB(8);"HJ[LPREDA F\R BYR]KRATER"
17 ; " Av Ove Oskarsson, Tage Magnusson och               Henrik Schi|ld" : ; : ; 
18 ; 'ANGE OM SKRIVARE FINNS (J/N)';
19 GET X$ : IF X$="J" OR X$="j" THEN ; ' JA' : X$='J' : OPEN "PR:" ASFILE 1 ELSE ; ' NEJ'
20 ; : ; : ; 'VILL DU HA INSTRUKTIONER (J/N)';
21 GET V$ : IF V$="J" OR V$="j" GOSUB 63
22 FOR I=1 TO 8 : FOR J=1 TO 7
23 READ A$(J,I) : NEXT J : NEXT I
24 U9=1
25 FOR K=1 TO 8
26 RANDOMIZE : R%(K)=FIX(RND*7)
27 IF R%(K)=0 THEN 26 ELSE NEXT K
28 FOR N=1 TO 8 : B$(N)=A$(R%(N),N)
29 NEXT N
30 U$=B$(1)+S$
31 FOR I=2 TO 8
32 L=LEN(B$(I))
33 N=LEN(U$)
34 M=39-N
35 IF L>M GOTO 41
36 U$=U$+B$(I)
37 IF L<M THEN U$=U$+S$ : GOTO 51
38 GOSUB 79
39 U$=""
40 GOTO 51
41 J9=0
42 FOR J=2 TO M
43 C$(J)=LEFT$(B$(I),J)
44 D$=RIGHT$(C$(J),J)
45 IF D$=" " THEN J9=J : E$=RIGHT$(B$(I),J+1)
46 NEXT J
47 IF J9=0 THEN GOSUB 79 : U$=B$(I)+S$ : GOTO 51
48 U$=U$+C$(J9)
49 GOSUB 79
50 U$=E$+S$
51 NEXT I
52 U$=U$+"."
53 GOSUB 79
54 GOTO 87
55 DATA "N{r det g{ller","Betr{ffande","Mot bakgrund av","R|rande","I termer av","Under p}verkan av","parallellt med"
56 DATA "konstruktiv","konsekvent","objektiv","seri|s","subjektiv","konventionell","dynamisk"
57 DATA "information","rationalisering","effekt","samordning","instruktion","|kning","kravanalys"
58 DATA "generaliseras","verifieras","utvecklas","f|rordas","komprimeras","modifieras","realiseras"
59 DATA "principiella","reella","fundamentala","latenta","godtyckliga","informella","partiella"
60 DATA "rutiner","strukturer","tendenser","hypoteser","ideologier","konklusioner","restriktioner"
61 DATA "i samband med","med h{nsyn till","inom ramen f|r","avseende","med avseende p}","i vad avser","i fr}ga om"
62 DATA "administrationen","n{ringslivet","myndigheten","personalen","intressenterna","utbudet","utfallet"
63 REM INSTRUKTIONER *****************
64 ; CHR$(12)
65 ; : ; : ; : ; "HJ[LPREDA F\R BYR]KRATER kan med f|r-"
66 ; "del anv{ndas i REMISSVAR, RAPPORTER mm"
67 ; "Datorn konstruerar meningarna helt"
68 ; "automatiskt. Om Du {r n|jd med meningen"
69 ; "och |nskar f} den utskriven p} papper"
70 ; "trycker Du p} P. Vill Du d{remot ha en"
71 ; "ny trycker Du p} mellanslagstangenten"
72 ; "N{r REMISSEN eller RAPPORTEN har berik-"
73 ; "ats med tillr{ckligt antal byr}kratiska"
74 ; "spetsfundigheter trycker Du p} S."
75 ; "H{r {r den f|rsta meningen"
76 ; : ; 
77 V1=1
78 RETURN 
79 REM UTSKRIFTSRUTIN*****************
80 U9$(U9)=U$
81 IF V1=0 THEN PRINT CHR$(12)
82 ; U$
83 V1=1
84 ; 
85 U9=U9+1
86 RETURN 
87 REM SLUTRUTIN ********************
88 GET V$ : IF V$="p" THEN V$='P'
89 V1=0
90 IF V$=" " THEN U9=1 : GOTO 24
91 IF V$="P" AND X$="J" THEN 92 ELSE 97
92 FOR Z=1 TO U9
93 ; : ; #1,U9$(Z)
94 NEXT Z
95 ; #1
96 GOTO 24
97 ; : ; CUR(15,15)"S L U T" : END