1 REM Av: David Andersson <5201>    1985-10-13 21.43.03
10 REM .  SAVE EPEDEMI
20 REM 
30 REM DAVID ANDERSSON <5201>
40 REM 
100 REM ------------------------------
110 REM SIMULERAR ETT SAMH[LLE D[R
120 REM EPEDEMIER BRYTER UT.
130 REM INDIVIDER F\DS SLUMPVIS (FAST
140 REM MEST I MITTEN) OCH D\R N[R
150 REM EN GRANNE D\R.
160 REM EPEDEMIER STARTAR D[R DET BLIR
170 REM TR]NGT (DVS EN INDIVID SOM F\DS
180 REM F]R 4 GRANNAR).
190 REM 
200 REM PROGRAMMET HAR EN REKURSION SOM
210 REM INTE KR[VER N]N DATA-STACK.
220 REM ------------------------------
230 REM INIT
240 Z%=INP(3%) : REM 40-TKN
250 ; CHR$(12%);
260 ; CUR(0%,8%)' EPEDEMI '
270 FOR Z%=1% TO 22% : ; CUR(Z%,0%)CHR$(23%); : NEXT Z%
280 FOR Z%=5%-2% TO 64%+2%
290 SETDOT Z%,5%-2%
300 SETDOT Z%,64%+2%
310 SETDOT 5%-2%,Z%
320 SETDOT 64%+2%,Z%
330 NEXT Z%
340 RANDOMIZE 
350 Y%=RND*30+RND*30 : Y%=Y%+5%
360 REM MAIN LOOP
370 X%=Y%
380 Y%=RND*30+RND*30 : Y%=Y%+5%
390 SETDOT X%,Y%
400 C%=-DOT(X%-1%,Y%)-DOT(X%+1%,Y%)-DOT(X%,Y%-1%)-DOT(X%,Y%+1%)
410 IF C%>3% GOSUB 440
420 IF INP(56%)>128% GOSUB 530
430 GOTO 360
440 REM EPEDEMI
450 IF NOT DOT(X%,Y%) RETURN 
460 CLRDOT X%,Y%
470 X%=X%-1% : GOSUB 440
480 X%=X%+2% : GOSUB 440
490 X%=X%-1% : Y%=Y%-1% : GOSUB 440
500 Y%=Y%+2% : GOSUB 440
510 Y%=Y%-1%
520 RETURN 
530 REM TANGENT
540 I$=CHR$(INP(56%) AND 127%)
550 IF I$='X' OR I$='x' GOTO 640
560 IF I$='+' GOTO 580
570 RETURN 
580 REM 
590 FOR Z%=5% TO 64%
600 SETDOT Z%,35%
610 SETDOT 35%,Z%
620 NEXT Z%
630 RETURN 
640 REM 
650 FOR Z%=5% TO 63%
660 SETDOT Z%,Z%
670 SETDOT Z%,Z%+1%
680 SETDOT 69%-Z%,Z%
690 SETDOT 69%-Z%,Z%+1%
700 NEXT Z%
710 RETURN