1 REM Ins{nd av J|rgen Hansen <5844>    1986-09-23 04.38.29 (DUMP)
10 REM Program GOLF av J|rgen Hansen 1986
20 REM
30 GOSUB 90
40 GOSUB 210
50 GOTO 1080
60 REM
70 REM Initierar par (totalt 72)
80 REM
90 DIM P(18),L(18)
100 ; CHR$(12)'Vilken bana |nskas (1-3) ?'; : GET \$ : ONERRORGOTO 100 : \=VAL(\$) : IF \<1 OR \>3 THEN 100
110 Z=\ : RANDOMIZE
120 ON Z RESTORE 150,160,170
130 FOR I=1 TO 18 : READ P(I) : READ L(I) : NEXT I
140 RETURN
150 DATA 5,500,4,362,3,185,4,307,3,145,5,562,3,173,5,479,3,167,4,327,4,412,3,216,5,523,4,232,4,272,3,204,5,482,5,505
160 DATA 3,211,3,127,5,561,3,251,4,415,4,462,5,237,4,181,5,498,3,197,3,217,3,132,5,512,5,606,5,412,4,362,5,527,4,327
170 DATA 4,361,4,381,3,172,5,582,4,386,3,126,4,299,4,348,5,606,3,134,3,202,4,404,5,467,3,127,5,426,5,182,3,167,5,599
180 REM
190 REM Huvudloop
200 REM
210 FOR J=1 TO 18
220 M=L(J) : S=0 : G=0 : B=0
230 IF J>1 THEN 390
240 ; CHR$(12)
250 FOR I=0 TO 10
260 ; CUR(I,0)CHR$(127)
270 ; CUR(I,39)CHR$(127)
280 NEXT I
290 FOR I=0 TO 39
300 ; CUR(0,I)CHR$(127)
310 ; CUR(3,I)CHR$(127)
320 ; CUR(5,I)CHR$(127)
330 ; CUR(7,I)CHR$(127)
340 ; CUR(8,I)CHR$(127)
350 ; CUR(9,I)CHR$(127)
360 ; CUR(11,I)CHR$(127)
370 NEXT I
380 ; CUR(6,0)' ' : ; CUR(6,39)' '
390 ; CUR(1,2)'Hela banan: '
400 ; CUR(2,1)STRING$(14,127)
410 ; CUR(1,16)'Bana:'Z
420 ; CUR(2,16)'Avverkade h}l:'J-1
430 ; CUR(4,2)'Par:'X1
440 ; CUR(4,18)' Dina slag:'X2
450 ; CUR(8,1)' Aktuellt h}l:'J' '
460 ; CUR(8,22)' Par:'P(J)' '
470 ; CUR(10,2)'L{ngd:'L(J)' m'
480 ; CUR(10,20)STRING$(18,32)
490 ; CUR(10,18)' Meter kvar:'M' m'
500 ; CUR(13,0)'Tr{          280-170 m'
510 ; CUR(13,23)' J{rn  210-100 m'
520 ; CUR(14,0)'Winkel+Bunker  10-99 m'
530 ; CUR(14,23)' Putter   0-10 m'
540 FOR R=16 TO 22 : FOR K=0 TO 39 : ; CUR(R,K)CHR$(32); : NEXT K : NEXT R
550 ; CUR(16,0)'Klubba (T/J/W/B/P) ? '; : GET K$
560 IF B THEN IF K$='B' OR K$='b' THEN 590 ELSE 390
570 IF G THEN IF K$='P' OR K$='p' THEN 590 ELSE 390
580 IF K$<>'T' AND K$<>'J' AND K$<>'t' AND K$<>'j' AND K$<>'W' AND K$<>'w' THEN 390
590 IF K$='T' OR K$='t' THEN ; 'Tr{'
600 IF K$='J' OR K$='j' THEN ; 'J{rn'
610 IF K$='P' OR K$='p' THEN ; 'Putter'
620 IF K$='B' OR K$='b' THEN ; 'Bunker'
630 IF K$='W' OR K$='w' THEN ; 'Winkel'
640 ; CUR(17,0);
650 IF K$<>'P' THEN 670
660 ; 'Putt'; : GOTO 680
670 ; 'Swing';
680 ; ' (1-9) ?'; : GET S$ : ; S$
690 ONERRORGOTO 390
700 T=VAL(S$)
710 IF T=0 THEN 390
720 IF K$='T' OR K$='t' OR K$='J' OR K$='j' THEN 730 ELSE 810
730 IF T=1 THEN T=9 : GOTO 810
740 IF T=2 THEN T=8 : GOTO 810
750 IF T=3 THEN T=7 : GOTO 810
760 IF T=4 THEN T=6 : GOTO 810
770 IF T=6 THEN T=4 : GOTO 810
780 IF T=7 THEN T=3 : GOTO 810
790 IF T=8 THEN T=2 : GOTO 810
800 IF T=9 THEN T=1 : GOTO 810
810 IF FIX(RND*15)+1>14 AND S=0 AND P(J)>3 THEN ; : ; 'Tyv{rr hamnade bollen i en bunker.' : B=1
820 IF K$='T' OR K$='t' THEN F=FIX(RND*30)+160+T*10
830 IF K$='J' OR K$='j' THEN F=FIX(RND*20)+90+T*10
840 IF K$='B' OR K$='b' THEN F=FIX(RND*10)+T*10 : B=0
850 IF K$='W' OR K$='w' THEN F=FIX(RND*10)+T*10
860 IF K$='P' OR K$='p' THEN F=FIX(RND*1.2)+T
870 M=M-F : S=S+1
880 IF M=0 THEN ; : ; : ; : GOTO 950
890 ; : ; : ; 'Du slog 'F' meter.'
900 IF M<-10 THEN ; : ; 'Du slog f|r l}ngt!'
910 IF M<0 THEN M=M-M*2
920 IF M<10 AND G=0 THEN G=1 : ; : ; 'Du {r p} green!'
930 GET \$
940 GOTO 390
950 D=P(J)-S
960 IF S=1 THEN ; 'Du gjorde en HOLE-IN-ONE !!!' : GOTO 1040
970 IF D=3 THEN ; 'Du gjorde en ALBATROSS,  OOOTROLIGT !!!'
980 IF D=2 THEN ; 'Du fick en eagle !!'
990 IF D=1 THEN ; 'Du fick en birdie!'
1000 IF D=0 THEN ; 'Du fick par.'
1010 IF D=-1 THEN ; 'Du fick en bogey.'
1020 IF D=-2 THEN ; 'Du fick en dubbel-bogey...'
1030 IF D<-2 THEN ; 'Du fick utsk{llning av din caddy!!'
1040 X1=X1+P(J) : X2=X2+S
1050 GET \$
1060 NEXT J
1070 RETURN
1080 ; CHR$(12)'Du fick totalt'X2' slag!'
1090 END