1 REM Ins{nt av 4230
2 REM *****************************
3 REM * ENBANDIT.GAM / Minne 16K  *
4 REM * VER 1.0 / 1982-??-??      *
5 REM * (c) Alf Wirdling / <4230> *
6 REM * Tel.   0470-26277 / V[XJ\ *
7 REM *****************************
100 REM  ENARMAD BANDIT 
110 ; CHR$(12);STRING$(39,42)
120 ; "*********** ENARMAD BANDIT ************"
130 ; STRING$(39,42)
140 ; : ; "H{r g{ller det att ha tur n{r du drar"
150 ; "i armen."
160 ; : ; "Det blir vinst vid 3 lika frukter."
170 ; : ; "Om de 2 sista frukterna {r lika,"
180 ; "spelar man fritt den g}ngen."
190 ; STRING$(39,45)
200 ONERRORGOTO 200
210 ; "Hur m}nga olika frukter (3-9) "; : INPUT N%
220 IF N%<3% OR N%>9% THEN 210
230 ; : ; "AUTOMATIK - 'ARMEN DRAR' SJ[LV (J/N) ";
240 GET R$ : ; R$ : IF R$="J" OR R$="j" THEN W%=2% ELSE W%=1%
250 ; STRING$(39,45)
260 V1%=N%^2%-N% : V2%=1%
270 S%=V1%*2% : REM  SPEL-AUTOMATEN 
280 K%=V1% : REM  LYCKO-S\KAREN 
290 ; : ; "DU HAR";K%;" KRONOR ATT SPELA MED !!!"
300 ; : ; "TRE LIKA FRUKTER GER";V1%;" G]NGER PENGARNA"
310 ; "TV] LIKA FRUKTER GER";V2%;" G]NGER PENGARNA"
320 ; : ; STRING$(39,45)
330 ; "TRYCK RETURN F\R ATT SPELA ";
340 POKE 65013,0 : GET R$
350 ; CHR$(12)
360 FOR I%=0% TO 6% : ; CUR(I%,0%);CHR$(151%); : NEXT I%
370 V%=38% : H%=40% : SETDOT 0%,39%
380 FOR I%=1% TO 20%
390 SETDOT I%,V% : SETDOT I%,H%
400 V%=V%-1% : H%=H%+1% : NEXT I%
410 ; CUR(6%,1%);"######################################";
420 ; CUR(2%,2%);"V[LKOMMEN";
430 ; CUR(2%,32%);"ATT";
440 ; CUR(3%,17%);"PR\VA";
450 ; CUR(5%,17%);"LYCKAN";
460 REM  INITIERING 
470 RANDOMIZE : GOSUB 1260
480 L%(1%)=1% : L%(2%)=1% : L%(3%)=1%
490 GOTO 870 : REM  KAPITALET 
500 REM  DRA I ARMEN 
510 IF K%>0% THEN 550
520 ; CUR(19%,1%);"BEKLAGAR, DU [R PANK - OSIS !!!!!!!!!!!"
530 ; CUR(22%,0%);SPACE$(39%)
540 OUT 6,25 : FOR F=1 TO 5000 : NEXT F : OUT 6,0 : END 
550 IF V1%<=S% THEN 570 ELSE OUT 6,43
560 ; CUR(19%,1%);"TRE LIKA NU - SPR[NGER AUTOMATEN !!!";
570 ; CUR(22%,1%);"VARS]GOD OCH DRA I ARMEN (RETURN) ";
580 ON W% GOTO 590,600
590 POKE 65013,0 : GET R$
600 K%=K%-1% : S%=S%+1% : REM  SATS 
610 REM  SNURRA FULL OMG]NG 
620 ; CUR(7%,0%);SPACE$(39%);
630 A%(1%)=RND*11+50
640 A%(2%)=RND*11+125
650 A%(3%)=RND*11+275
660 REM  3 BILDER 
670 FOR B%=1% TO 3%
680 IF A%(B%)=0% THEN GOSUB 950 : GOTO 720
690 IF L%(B%)=N% THEN L%(B%)=1% ELSE L%(B%)=L%(B%)+1%
700 A%(B%)=A%(B%)-1% : F%=L%(B%)
710 GOSUB 1330 : NEXT B% : GOTO 660
720 REM  2 BILDER 
730 FOR B%=2% TO 3%
740 IF A%(B%)=0% THEN GOSUB 950 : GOTO 780
750 IF L%(B%)=N% THEN L%(B%)=1% ELSE L%(B%)=L%(B%)+1%
760 A%(B%)=A%(B%)-1% : F%=L%(B%)
770 GOSUB 1330 : NEXT B% : GOTO 720
780 REM  1 BILD KVAR 
790 FOR B%=3% TO 3%
800 IF A%(B%)=0% THEN GOSUB 950 : GOTO 840
810 IF L%(B%)=N% THEN L%(B%)=1% ELSE L%(B%)=L%(B%)+1%
820 A%(B%)=A%(B%)-1% : F%=L%(B%)
830 GOSUB 1330 : NEXT B% : GOTO 780
840 REM  VINST ELLER EJ ??? 
850 IF L%(1%)=L%(2%) AND L%(3%)=L%(2%) THEN M%=V1% : GOSUB 1100 : GOTO 870
860 IF L%(2%)=L%(3%) THEN M%=V2% : GOSUB 1100
870 GOSUB 1200 : REM  SPACE 
880 ; CUR(17%,1%);"DITT KAPITAL [R NU:";K%;" KRONOR";
890 IF S%>0% THEN 500
900 ; CUR(19%,1%);"DU SPR[NGDE SPEL-AUTOMATEN !!!!!!!!!!!"
910 IF S%=0% THEN ; CUR(22%,0%);SPACE$(39%) : GOTO 940
920 ; CUR(22%,1%);"MEN DE";ABS(S%);" KRONORNA JAG [R SKYLDIG,"
930 ; " F]R DU ALDRIG SE IGEN - HA HA"
940 OUT 6,5 : FOR F=1 TO 5000 : NEXT F : OUT 6,0 : END 
950 REM  NAMN P] AVSTANNAD BILD 
960 ON L%(B%) GOTO 970,980,990,1000,1010,1020,1030,1040,1050
970 F$="   PEAR   " : GOTO 1060
980 F$="  APPLE   " : GOTO 1060
990 F$="  BANANA  " : GOTO 1060
1000 F$="  CHERRY  " : GOTO 1060
1010 F$="  ORANGE  " : GOTO 1060
1020 F$=" CURRANTS " : GOTO 1060
1030 F$="  TOMATO  " : GOTO 1060
1040 F$="RASPBERRY " : GOTO 1060
1050 F$="STRAWBERRY"
1060 ; CHR$(7); : ON B% GOTO 1070,1080,1090
1070 ; CUR(7%,1%);F$; : RETURN 
1080 ; CUR(7%,15%);F$; : RETURN 
1090 ; CUR(7%,29%);F$; : RETURN 
1100 REM  VINST MED KLINGANDE MYNT 
1110 GOSUB 1200 : REM  SPACE 
1120 C%=0% : ; CUR(17%,1%);
1130 FOR D%=1% TO M%
1140 IF C%>18% THEN ; : ; " "; : C%=0%
1150 ; " "; : OUT 6,131 : FOR F=1 TO 100 : NEXT F : C%=C%+1%
1160 OUT 6,0 : NEXT D%
1170 FOR F=1 TO 3000 : NEXT F
1180 IF M%>S% THEN K%=K%+S% : S%=S%-M% : RETURN 
1190 K%=K%+M% : S%=S%-M% : RETURN 
1200 REM  UTBLANKNING KOMMENTARER 
1210 ; CUR(17%,0%);SPACE$(39%);
1220 ; CUR(18%,0%);SPACE$(39%);
1230 ; CUR(19%,0%);SPACE$(39%);
1240 ; CUR(20%,0%);SPACE$(39%);
1250 RETURN 
1260 REM  UPPL[GGNING RAM 
1270 ; CUR(8%,0%);CHR$(151%);"7########k    7########k    7########k"
1280 FOR U%=1% TO 6%
1290 ; CUR(8%+U%,0%);CHR$(151%);"5        j    5        j    5        j"
1300 NEXT U%
1310 ; CUR(15%,0%);CHR$(151%);"uppppppppz    uppppppppz    uppppppppz"
1320 RETURN 
1330 REM  BILDRUTA ??? 
1340 ON B% GOTO 1350,1360,1370
1350 P%=2% : GOTO 1380
1360 P%=16% : GOTO 1380
1370 P%=30%
1380 REM  FRUKT 
1390 ON F% GOTO 1400,1480,1560,1640,1720,1800,1880,1960,2040
1400 REM  P[RON 
1410 ; CUR(9%,P%);"   j5   ";
1420 ; CUR(10%,P%);"  xt  ";
1430 ; CUR(11%,P%);"`~}0";
1440 ; CUR(12%,P%);"j5";
1450 ; CUR(13%,P%);"j5";
1460 ; CUR(14%,P%);'"o?o?!';
1470 RETURN 
1480 REM  [PPLE 
1490 ; CUR(9%,P%);"   j5   ";
1500 ; CUR(10%,P%);" `~}0 ";
1510 ; CUR(11%,P%);" ~} ";
1520 ; CUR(12%,P%);"j5";
1530 ; CUR(13%,P%);" o? ";
1540 ; CUR(14%,P%);' "o?! ';
1550 RETURN 
1560 REM  BANAN 
1570 ; CUR(9%,P%);"   `~   ";
1580 ; CUR(10%,P%);"  x'   ";
1590 ; CUR(11%,P%);"      ";
1600 ; CUR(12%,P%);"      ";
1610 ; CUR(13%,P%);"  *    ";
1620 ; CUR(14%,P%);"   +}   ";
1630 RETURN 
1640 REM  K\RSB[R 
1650 ; CUR(9%,P%);"      8!";
1660 ; CUR(10%,P%);"    `n  ";
1670 ; CUR(11%,P%);"   8!j  ";
1680 ; CUR(12%,P%);" `6  j0 ";
1690 ; CUR(13%,P%);"`~}0`~}0";
1700 ; CUR(14%,P%);'"o?!"o?!';
1710 RETURN 
1720 REM  APELSIN 
1730 ; CUR(9%,P%);"   }0   ";
1740 ; CUR(10%,P%);"   t  ";
1750 ; CUR(11%,P%);"     ";
1760 ; CUR(12%,P%);"     ";
1770 ; CUR(13%,P%);"   '  ";
1780 ; CUR(14%,P%);"   ?!   ";
1790 RETURN 
1800 REM  VINB[R 
1810 ; CUR(9%,P%);'"k###k#!';
1820 ; CUR(10%,P%);"h~/ *o| ";
1830 ; CUR(11%,P%);"h~/ *o| ";
1840 ; CUR(12%,P%);"h~/ *o| ";
1850 ; CUR(13%,P%);"h~/ *o| ";
1860 ; CUR(14%,P%);"h~/ *o| ";
1870 RETURN 
1880 REM  TOMAT 
1890 ; CUR(9%,P%);"        ";
1900 ; CUR(10%,P%);"  `||0  ";
1910 ; CUR(11%,P%);" h4 ";
1920 ; CUR(12%,P%);" *% ";
1930 ; CUR(13%,P%);'  "//!  ';
1940 ; CUR(14%,P%);"        ";
1950 RETURN 
1960 REM  HALLON 
1970 ; CUR(9%,P%);"(l,,,<,$";
1980 ; CUR(10%,P%);"h~| |}4 ";
1990 ; CUR(11%,P%);" +! ""'  ";
2000 ; CUR(12%,P%);"(,,l,,,$";
2010 ; CUR(13%,P%);"  h~|   ";
2020 ; CUR(14%,P%);"   +!   ";
2030 RETURN 
2040 REM  JORDGUBBAR 
2050 ; CUR(9%,P%);"   j5   ";
2060 ; CUR(10%,P%);" xt ";
2070 ; CUR(11%,P%);'"o?!';
2080 ; CUR(12%,P%);"  #k##  ";
2090 ; CUR(13%,P%);"  5  ";
2100 ; CUR(14%,P%);"  ""o'   ";
2110 RETURN