10 REM +++++++++++++++++++++++++++++++++
20 REM ! Program ....   MEMORERA
30 REM ! Utg}va         1980-01-11
40 REM ! av (c) Kaj S Arn|
50 REM ! Minne 16 Kbytes
60 REM +++++++++++++++++++++++++++++++++
70 REM 
80 REM Screening av
90 REM Allan Varcoe & G|ran Olsson
100 REM 
110 IF PEEK(590)<>40 THEN ; INP(3)
120 REM +++++++++++++++++++++++++++++++++
130 ; CHR$(12%)TAB(15%)"MEMORERA" : ; 
140 ; "Med MEMORERA kan du testa ditt minne en-ligt vetenskapligt erk{nda metoder."
150 ; : ; "Jag visar i tur och ordning 1-20 siffrorefter varandra p} rutan, och din uppgift";
160 ; "{r att memorera dem och n{r alla siffrorvisats upprepa dem."
170 RANDOMIZE 
180 DIM S%(20%)
190 ; : ; "HUR M]NGA SIFFROR \NSKAS? (1-20),0=Slut"
200 ONERRORGOTO 190
210 INPUT H%
220 IF H%=0% END 
230 IF H%<0% OR H%>20% 190
240 T%=0%
250 ; CHR$(12%)TAB(15%)"MEMORERA" : ; 
260 ; "SIFFRORNA VISAS NEDAN I TUR OCH ORDNING" : ; 
270 FOR I%=1% TO H%
280 S%=RND*9%+1%
290 S%(I%)=S%
300 ; CHR$(13%)"  "; : FOR I=1 TO 500 : NEXT I : ; CHR$(7%,13%)S%;
310 FOR I=1 TO 1000 : NEXT I
320 NEXT I%
330 ; CHR$(13%)"UPPREPA NU SIFFRORNA!" : ; 
340 FOR I%=1% TO H% : POKE 65013%,0% : GET A$ : ONERRORGOTO 390 : S%=VAL(A$)
350 IF S%<>S%(I%) T%=T%+1% : IF T%=2% ; : GOTO 390 ELSE I%=I%-1% : ; CHR$(7%); ELSE ; S%;
360 NEXT I%
370 ; : ; : ; "DU MINDES"H%" SIFFROR EFTER VARANDRA!" : ; "GRATULERAR!"
380 GOTO 190
390 ; : ; "DU KOM I H]G"I%-1%" SIFFROR AV"H%"!"
400 FOR I=1 TO 2000 : OUT 6%,5% : NEXT I
410 ; : ; "DEN R[TTA KOMBINATIONEN LYDER:"
420 FOR I%=1% TO H%
430 ; S%(I%)CHR$(7%); : FOR I=1 TO 1000 : NEXT I
440 NEXT I%
450 ; : ; : ; "B[TTRE LYCKA N[STA G]NG!"
460 GOTO 190