1 REM ++++++++++++++++++++++++++++++++
2 REM ! Program ....   ROADRACE.GAM
3 REM ! Utg}va  1.1    1983 ?? ??
4 REM ! av (c) Stig Lindberg   ]land 
5 REM ! screenat av Tom Sj|berg 2401 
7 REM ! Minne 16 Kbytes
8 REM ! Ins{nt av 819 
9 REM ++++++++++++++++++++++++++++++++
10 REM Ett ej grafiskt bilt{vlings-pgm.
11 REM 
100 ; CHR$(12)
110 ; "      DET H[R [R PITTSFIELD-ALBANY"
120 ; "            LANDSV[GSRALLYT"
130 ; : ; 
140 ; "----------------------------------------"
150 ; "V[LJ EN BIL" : ; 
160 ; "(1)  V W 1200"
170 ; "(2)  CHEVROLET 283 NOVA"
180 ; "(3)  CAMARO Z-28 "
190 ; "(4)  FERRARI"
200 ; : ; "V[LJ EN BIL MEN KOM IH]G ATT JU ST\RRE  BIL DESTO MER BENSIN]TG]NG."
210 ; "VILKEN BIL VILL DU HA ? (1-4) ?";
220 INPUT C$
230 ON INSTR(1,'1234',C$)+1 GOTO 240,250,250,250,250
240 GOSUB 1640 : ; CHR$(12) : GOTO 150
250 C1=VAL(C$) : ; CHR$(12) : ; 
260 IF N2=1 THEN 300
270 ; "V[LJ NU VILKEN V[G DU VILL K\RA P].     DEN L[TTASTE OCH RAKASTE [R NR.1 OCH"
280 ; "DEN SV]RASTE OCH KROKIGASTE [R NR.5"
290 ; : ; 
300 ; "VILKEN V[G VILL DU HA (V[LJ 1-5) ?";
310 INPUT C$
320 ON INSTR(1,'12345',C$)+1 GOTO 330,350,350,350,350,350
330 GOSUB 1640 : ; CHR$(12) : GOTO 270
340 FOR W=1 TO 1300 : NEXT W
350 ; CHR$(12)
360 C2=VAL(C$)
370 IF N2=1 THEN 420
380 ; "DU SKALL NU F[RDAS 5 MIL P] 5 LITER     BENSIN."
390 ; "DIN POSITION VISAS VAR 10 SEK.          EFTER VARJE POSITIONSKONTROLL FR]GAS DETEFTER NYTT GASP]DRAG."
400 ; " 10 [R SNABB ACCELERATION               -10 [R H]RD INBROMSNING"
410 ; "VARJE TAL MELLAN  10 OCH -10 [R GILTIGT"
420 FOR I=1 TO C1
430 READ B,M,S
440 B=B/10
450 NEXT I
460 A1=5
470 M1=0
480 C1=C1/2
490 V=0
500 ; 
510 R1=0
520 T=0
530 D=0
540 Q1=0
550 ; "NUVARANDE FART="V" KM/H"
560 ; "BENSIN        ="A1" LITER"
570 ; "V[GSTR[CKA    ="M1" MIL"
580 ; "TID           ="T" SEKUNDER"
590 IF M1>=5 THEN 1340
600 ; "========================================"
610 ; : ; "NYTT GASP]DRAG "
620 ONERRORGOTO 660 : INPUT G
630 IF G<-10 THEN 670
640 IF G>10 THEN 670
650 GOTO 690
660 ONERRORGOTO 0
670 ; "EJ GODK[NT P]DRAG F\RS\K IGEN "
680 GOTO 620
690 IF G<9 THEN 750
700 Z=Z+1
710 IF Z>4 THEN 730
720 GOTO 760
730 ; "DIN MOTOR HAR EXPLODERAT:DU BLEV TR[FFAD AV EN KOLV"
740 GOTO 1160
750 Z=0
760 V=INT(B*G-M*V+V)
770 T=T+10
780 ; : ; "V[GF\RH]LLANDEN F\R TILLF[LLET." : ; 
790 IF V>0 THEN 810
800 V=0
810 M1=M1+V/460
820 IF G<0 THEN 850
830 A1=A1-(G*S)/500
840 IF A1<0 THEN 1270
850 IF R1=1 THEN 1000
860 IF Q1=1 THEN 940
870 Q=INT((C2+1)*RND(X))
880 R=INT((3.75-C2)*RND(X))
890 IF R>0 THEN 1190
900 IF Q>0 THEN 1230
910 ; "RAKT OCH FINT"
920 ; 
930 GOTO 550
940 H=INT(15+35*RND(X))
950 H=H+5*C1
960 IF V>H THEN 1370
970 ; "DU KOM IGENOM KURVAN" : ; 
980 Q1=0
990 GOTO 550
1000 E=E-(V-D)*3
1010 IF E<0 THEN 1040
1020 ; "FORDON";E;" METER FRAMF\R" : ; 
1030 GOTO 550
1040 IF V-D<5 THEN 1100
1050 D=V-D
1060 ; "FORDONETS FART VAR"D" KM/H"
1070 ; : ; 
1080 R1=0
1090 GOTO 550
1100 ; "FORDONET OMK\RS"
1110 D=INT(25+40*RND(X))
1120 ; "MEN DU M\TER EN GREYHOUND BUSS"
1130 ; "BUSSENS HASTGHET VAR"D" KM/H"
1140 D=V+D
1150 ; "KRASCH HASTIGHET"D" KM/H" : ; 
1160 ; "F\RRESTEN VAR H]LLS DIN BEGRAVNING ?" : ; : ; 
1170 FOR ]=0 TO 4000 : NEXT ]
1180 GOTO 1490
1190 ; "FORDON FRAMF\R P] 300 M AVST]ND" : ; 
1200 D=INT(25+35*RND(X))
1210 R1=1
1220 GOTO 550
1230 ; "VARNING KURVA "
1240 Q1=1
1250 ; 
1260 GOTO 550
1270 ; "UTOMORDENTLIGA" : ; 
1280 ; "MEN V[NTA DU BLEV UTAN BENSIN !!"
1290 GOTO 1470
1300 ; "MEN P] N]GOT VIS GREJADE DU DET"
1310 ; 
1320 R1=0
1330 GOTO 550
1340 ; : ; 
1350 ; "DU KLARADE DET ( TUR ) !!!!!!!!"
1360 GOTO 1490
1370 ; "DE VAR HEMSKA"
1380 H=H-5*C1
1390 OUT 6,139 : FOR \=1 TO 1000 : NEXT \
1400 ; 
1410 ; H;"  KM/H  VAR DEN TILL]TNA HASTGHETEN"
1420 ; "           GENOM KURVAN!"
1430 ; 
1440 ; V;" KM/H VAR DIN HASTIGHET. "
1450 ; 
1460 GOTO 1160
1470 ; "DIN J[VLA BLYFOT*#?*#?*#?"
1480 ; 
1490 ; "VILL DU F\RS\KA IGEN ? OK!!!!" : ; 
1500 ; "1=JA ,2=NEJ"
1510 INPUT V
1520 IF V=2 THEN 1550
1530 N2=1
1540 GOTO 1570
1550 ; : ; "J  \  S  S  E"
1560 GOTO 1630
1570 RESTORE 
1580 GOTO 100
1590 DATA 45,.53,10
1600 DATA 60,.05,13
1610 DATA 70,.41,15
1620 DATA 80,.39,18
1630 END 
1640 REM ** ERROR-HANDLER **
1650 ; CUR(23,3)" FEL TAL !  F\RS\K IGEN."; : ; CHR$(7);
1660 FOR T1=0 TO 1500 : NEXT T1 : RETURN