1 REM +++++++++++++++++++++++++++++++++
2 REM ! Program ....   SOLVALLA
3 REM ! Utg}va  2.0    1981-02-22
4 REM ! av (c) Odd Rolander
5 REM ! {ndrat av Nils H{ggblom
7 REM ! Minne 16 Kbytes
9 REM +++++++++++++++++++++++++++++++++
10 REM 
11 REM Screening av
12 REM Allan Varcoe & G|ran Olsson
13 REM 
14 IF PEEK(590)<>40 THEN ; INP(3)
15 REM +++++++++++++++++++++++++++++++++
80 RANDOMIZE 
90 DIM X$=120%
100 ; CHR$(12)
110 ; "____________________________________"
120 ; "* H [ S T K A P P L \ P N I N I N G*"
130 ; "____________________________________"
140 ; : ; 
150 DIM S(8)
160 ; "V[LKOMMEN TILL SOLVALLA !"
170 ; 
180 ; "VILL DU HA INSTRUKTIONER (J/N) ?";
190 GET A$ : ; A$
200 ; 
210 IF A$="N" OR A$="n" THEN 320
220 ; CHR$(12%)
230 ; "Upp till 10 spelare kan satsa. Du kan   spela mellan 5 och 1.000.000 kr p} en   h{st."
240 ; "Det g}r bara att spela vinnare."
250 ; 
260 ; "Under loppet visas h{starnas placeringargenom att numren anges p} sk{rmen."
270 ; "M}let {r nederst p} bildsk{rmen."
280 ; 
290 ; "Spelet b|rjar med att en tabell visas |-ver vinnarodds."
300 ; "D{refter uppmanas spelarna att satsa i  tur och ordning."
310 ; : ; : ; : ; : ; : ; : ; : ; 
320 ONERRORGOTO 320 : ; "HUR M]NGA VILL SPELA ";
330 INPUT C : ONERRORGOTO 0 : DIM W$(C)=120%,Q(C),P(C),N0(C)
340 FOR X%=1% TO C : N0(X%)=50000 : NEXT X% : ; CHR$(12%)
350 FOR A=1 TO C
360 ; : ; : ; "VAD [R DITT NAMN SPELARE"A' ?'
370 ; 
380 INPUTLINE W$(A) : W$(A)=LEFT$(W$(A),LEN(W$(A))-2%) : ; 
390 NEXT A
400 ; CHR$(12);
410 ; "H[ST","NUMMER","ODDS"
420 ; 
430 FOR I=1 TO 8 : S(I)=0 : NEXT I
440 A=O
450 FOR A=1 TO 8
460 D(A)=INT(10*RND(1)+1)
470 NEXT A
480 FOR A=1 TO 8
490 R=R+D(A)
500 NEXT A
510 V$(1)="NAROLD SCOTCH"
520 V$(2)="MR EGO"
530 V$(3)="JET SWEEP"
540 V$(4)="SONG KEY"
550 V$(5)="AL JOE"
560 V$(6)="RAFAEL"
570 V$(7)="DAWSON KING"
580 V$(8)="EGO FLASH"
590 FOR N=1 TO 8
600 ; V$(N),N,"1:"R/D(N)
610 NEXT N
620 ; "****************************************"
630 ; "Satsa p} h{st nr och belopp" : ; : GOSUB 1490
640 F0%=1% : FOR J=1 TO C : GOSUB 1490 : IF N0(J)=0% 710 ELSE F0%=0%
650 ONERRORGOTO 1510 : GOSUB 1520 : ; W$(J)", Din tur " : ; 
660 INPUT Q(J),P(J) : ONERRORGOTO 0
670 IF P(J)<(5) 680 ELSE IF P(J)>1E+6 ; : ; "H|gsta insatsen {r 1.000.000kr." : GOTO 675 ELSE 700
675 GOSUB 1500 : GOSUB 1490 : GOTO 650
680 ; : ; "Du kan inte satsa mindre {n 5kr." : GOSUB 1500 : GOSUB 1490
690 GOTO 650
700 IF N0(J)<P(J) P(J)=N0(J) : N0(J)=0% : ; : ; 'Du har inga pengar kvar !' : GOSUB 1500 ELSE N0(J)=N0(J)-P(J)
710 NEXT J : IF F0% 1530
720 ; 
730 ; "1 2 3 4 5 6 7 8"
740 ; CHR$(12)"***** START *****";
750 FOR I=1 TO 8
760 M=I
770 M(I)=M
780 Y(M(I))=INT(100*RND(1)+1)
790 IF Y(M(I))<10 THEN 880
800 S=INT(R/D(I)+.5)
810 IF Y(M(I))<S+17 THEN 900
820 IF Y(M(I))<S+37 THEN 920
830 IF Y(M(I))<S+57 THEN 940
840 IF Y(M(I))<77+S THEN 960
850 IF Y(M(I))<S+92 THEN 980
860 Y(M(I))=7
870 GOTO 990
880 Y(M(I))=1
890 GOTO 990
900 Y(M(I))=2
910 GOTO 990
920 Y(M(I))=3
930 GOTO 990
940 Y(M(I))=4
950 GOTO 990
960 Y(M(I))=5
970 GOTO 990
980 Y(M(I))=6
990 NEXT I
1000 M=I
1010 FOR I=1 TO 8
1020 S(M(I))=S(M(I))+Y(M(I))
1030 NEXT I
1040 I=1
1050 FOR L=1 TO 8
1060 FOR I=1 TO 8-L
1070 IF S(M(I))<S(M(I+1)) THEN 1110
1080 H=M(I)
1090 M(I)=M(I+1)
1100 M(I+1)=H
1110 NEXT I
1120 NEXT L
1130 T=S(M(8))
1140 FOR I=1 TO 8
1150 B=S(M(I))-S(M(I-1))
1160 IF B=0 THEN 1210
1170 FOR A=1 TO B
1180 ; 
1190 IF S(M(I))>27 THEN 1260
1200 NEXT A
1210 ; M(I);
1220 NEXT I
1230 FOR A=1 TO 23-T
1240 ; 
1250 NEXT A
1260 FOR X%=1% TO 6000% : NEXT X% : IF T<28 THEN 740
1265 ; CHR$(12%);
1270 ; "RESULTATET AV LOPPET [R:"
1280 Z9=1
1290 FOR I=8 TO 1 STEP -1
1300 F=M(I)
1310 ; 
1320 ; Z9;". PLACERING H[ST ";F;" TILL ";"1:"R/D(F)
1330 Z9=Z9+1
1340 NEXT I
1350 FOR J=1 TO C
1360 IF Q(J)<>M(8) THEN 1430
1370 N=Q(J)
1380 ; 
1390 ; "TRYCK EN TANGENT"
1400 GET X$
1410 ; CHR$(12)
1420 ; W$(J);" VINNER KR "; : N0=INT((R/D(N))*P(J)) : ; N0 : N0(J)=N0(J)+N0 : ; : ; : ; 'Saldo :'N0(J)
1430 Q(J)=0% : NEXT J
1440 ; "________________________________________"
1450 ; "*  VILL DU SATSA P] N[STA LOPP (J/N)  *"
1460 ; "________________________________________"
1470 GET O$ : GET O$
1480 IF O$="J" OR O$="j" OR O$=' ' OR O$=CHR$(13%) 400 ELSE 1530
1490 FOR Q9%=13% TO 21% : ; CUR(Q9%,0%)SPACE$(40%) : NEXT Q9% : ; CUR(14%,0%); : RETURN 
1500 ; CHR$(7%); : FOR Q9%=1% TO 10000% : NEXT Q9% : RETURN 
1510 ; : ; 'Fel v{rden.' : GOSUB 1500 : GOSUB 1490 : GOTO 650
1520 ; CUR(23%,0%)'Saldo :'N0(J)'      'CUR(14%,0%); : RETURN 
1530 ; CHR$(12%)'* * *  R E S U L T A T L I S T A  * * *' : ; : ; 
1540 FOR X%=1% TO C-1% : FOR Y%=X%+1% TO C
1550 IF N0(X%)<N0(Y%) X=N0(X%) : N0(X%)=N0(Y%) : N0(Y%)=X : X$=W$(X%) : W$(X%)=W$(Y%) : W$(Y%)=X$
1560 NEXT Y% : NEXT X% : FOR X%=1% TO C : ; W$(X%),'Saldo :'N0(X%) : NEXT X%