1 REM ++++++++++++++++++++++++++++++++
2 REM ! Program    WORLDPO.WER
3 REM ! VER 1.2      1.31.1981
4 REM ! av    (C) Odd Rolander 
5 REM ! Mod. av Nils H{ggblom
6 REM ! Minne 16 Kbytes
7 REM ! Ins{nt av ????
8 REM ! Screening Tom Sj|berg 2401
9 REM ++++++++++++++++++++++++++++++++
100 ; CHR$(12%) : RANDOMIZE 
101 W=3 : S$="KUSTEN"
102 DIM A(10,10),C(10,10),N$(10),D$(5),L$(5)
103 DATA N. AMERIKA,AUSTRALIEN,S. AMERIKA,SOVJET,JAPAN,AFRIKA
104 DATA KOREA,KINA,SVERIGE,ENGLAND,TRUPPER,FLYG,ARTILLERI
105 DATA TANKS,RAKETER,NORD,SYD,\ST,V[ST
106 FOR X=1 TO 10 : READ N$(X) : NEXT X
107 FOR X=1 TO 5 : READ D$(X) : NEXT X
108 FOR X=1 TO 4 : READ L$(X) : NEXT X
109 FOR X=1 TO 10 : C(X,1)=INT((5000*RND)+5000)*10 : NEXT X
110 FOR X=1 TO 10 : FOR J=2 TO 5 : C(X,J)=INT(50*RND)+25 : NEXT J : NEXT X
111 FOR X=1 TO 10 : FOR J=6 TO 10 : C(X,J)=INT(4*RND)+1 : NEXT J : NEXT X
112 FOR X=1 TO 5 : FOR J=1 TO 10 : A(X,J)=C(X,J) : C(X,J)=0 : NEXT J : NEXT X
113 ; "     ------------------------------"
114 ; "     *** W O R L D    P O W E R ***"
115 ; "     ------------------------------"
116 ; : ; ;'V{rlden {r delad i tv} maktblock och tredje v{rldskriget har brutit ut.' : ; 
117 ; 'Du har nu den |vergripande makten |ver  det ena blocket.Du skall genom strate-  giska "man|vrer"';
118 ; ' f|ra det EGna blocket                 till seger.' : ; 
119 Y6=Y6+1 : GOSUB 249
120 ONERRORGOTO 120 : ; : ; "MAN\VER "; : INPUT M : ONERRORGOTO 0
121 IF M>5 OR M<(1) 119
122 ON M GOTO 148,123,131,156,171
123 GOSUB 246
124 ONERRORGOTO 123 : ; : ; "LAND "; : INPUT R : ONERRORGOTO 0
125 IF R>10 OR R<1 THEN 124
126 ; CHR$(12%)"STATUSRAPPORT: "N$(R)
127 ; "F\RSVAR","ANTAL","BEL[GENHET" : ; : FOR X=1 TO 5
128 ; D$(X)TAB(13%)A(R,X);TAB(28%);
129 IF C(R,X+5)<>0 ; L$(C(R,X+5)) ELSE ; '----'
130 NEXT X : GOTO 119
131 GOSUB 246
132 ONERRORGOTO 132 : ; : ; "ANGE L[NDER:(FR]N,TILL)" : INPUT F,T : ONERRORGOTO 0
133 IF F>10 OR F<1 OR T>10 OR T<(1) 132 ELSE GOSUB 247
134 ONERRORGOTO 134 : ; : ; "VILKA STYRKOR "; : INPUT D : ONERRORGOTO 0
135 IF D<1 OR D>(5) 134
136 ONERRORGOTO 136 : ; : ; "VILKET ANTAL "; : INPUT Q : ONERRORGOTO 0
137 IF A(F,D)>=(Q) 139
138 ; "DU HAR BARA"A(F,D)" "D$(D)" I "N$(F) : GOTO 119
139 IF 20000%>A(F,D) 140 ELSE IF Q<20000 ; 'DU M]STE FLYTTA MINST 20000 TRUPPER.' : GOTO 119 ELSE 141
140 IF A(F,D)<>(Q) ; "DU M]STE FLYTTA ALLA "D$(D) : GOTO 119
141 A(T,D)=A(T,D)+Q : A(F,D)=A(F,D)-Q : GOSUB 248
142 ONERRORGOTO 142 : ; : ; "ANGE GR[NS/KUST "; : INPUT L : ONERRORGOTO 0
143 IF L<1 OR L>(4) 142
144 A(T,D+5)=L
145 IF INT(RND*100)>(25) 147
146 GOSUB 223
147 GOTO 119
148 ; CHR$(12%)TAB(12%)"--- GLOBAL RAPPORT ---"
149 ; : ; "LAND"TAB(12%)"EG.TR."TAB(20%)"FI.TR."TAB(27%)"EG.LAND ?" : ; 
150 FOR X=1 TO 10 : ; N$(X)TAB(11%)A(X,1);TAB(19%)C(X,1);TAB(27%);
151 K2=0 : FOR F2=1 TO 5 : IF C(X,F2)<>0 K2=K2+1
152 NEXT F2
153 IF K2>0 ; "NEJ" ELSE ; "JA"
154 NEXT X
155 GOTO 119
156 GOSUB 246
157 ONERRORGOTO 157 : ; : ; "ANGE L[NDER:(FR]N,TILL) "; : INPUT F,T : ONERRORGOTO 0
158 IF F>10 OR F<1 OR T>10 OR T<(1) 157
159 IF A(F,2)>=(10) 161
160 ; "DU HAR INTE TILLR[CKLIGT FLYG I ";N$(F) : GOTO 119
161 A(F,2)=A(F,2)-10
162 ; : ; : ; : ; "SPIONRAPPORT: "N$(T)
163 IF INT(RND*100)>20 THEN 166
164 IF INT(50*RND)<26 ; "ALLA PLAN F\RLORADE \VER HAVET" : GOTO 119
165 ; "PLANEN NEDSKJUTNA \VER ";N$(T) : GOTO 119
166 ; : ; "F\RSVAR"TAB(13%)"ANTAL"TAB(20)"BEL[GENHET" : ; : FOR X=1 TO 5
167 ; D$(X)TAB(12%)C(T,X);TAB(20%);
168 IF C(T,X+5)<>0 ; L$(C(T,X+5)) : GOTO 170
169 ; 
170 NEXT X : GOTO 119
171 K=0 : FOR X=1 TO 10 : FOR J=1 TO 5
172 IF A(X,J)<>(0) 180
173 NEXT J : NEXT X : IF K>(0) 171
174 K=0 : H=0 : FOR X=1 TO 10 : FOR J=1 TO 5
175 IF C(X,J)<>0 K=K+1
176 IF A(X,J)<>0 H=H+1
177 NEXT J : NEXT X : IF K=(0) 241
178 IF H=(0) 239
179 GOTO 119
180 C=1
181 IF C(X,C)<>(0) 184
182 C=C+1 : IF C=(6) 173
183 GOTO 181
184 IF A(X,J+5)<>C(X,C+5) 182
185 K=K+1 : ; : ; : ; : ; CHR$(7)"STRID I "N$(X);
186 ; " P] "L$(A(X,J+5))S$"!"
187 ; "FIENDE "D$(C)TAB(18%)"EGNA "D$(J)
188 O=C(X,C) : O1=A(X,J) : E=O : E1=O1
189 IF J=1 IF C<>(1) 209
190 IF C=1 IF J<>(1) 216
191 ; E;TAB(18%)E1
192 GOSUB 233
193 IF E1=(0) E8=1 : GOTO 198
194 IF E=(0) E8=0 : GOTO 198
195 IF E1>(E*1.7) E8=0 : GOTO 198
196 IF E1>(E*1.5) E8=1 : GOTO 198
197 GOTO 191
198 ; E;TAB(18%)E1 : ; : ; "***** SEGER F\R ";
199 IF E8=1 ; "FIENDEN I "; : GOTO 201
200 ; "EGNA TRUPPER I ";
201 ; N$(X) : ; "P] "L$(A(X,J+5))S$
202 ; "TOTALA F\RLUSTER: "
203 ; "FIENDE "D$(C)" :  "O-E
204 ; "EGNA   "D$(J)" :  "O1-E1
205 IF E8=1 C(X,J)=C(X,J)+A(X,J) : A(X,J)=0 : GOTO 208
206 A(X,C)=A(X,C)+C(X,C) : C(X,C)=0 : A(X,C+5)=C(X,C+5)
207 ; E;" "D$(C)" BLEV TILLF]NGATAGNA." : ; "TRYCK EN TANGENT "; : GET H$ : GOTO 173
208 C(X,J+5)=A(X,J+5) : ; "TRYCK EN TANGENT "; : GET H$ : GOTO 173
209 ; E;TAB(18%)E1
210 GOSUB 233
211 IF E=(0) E8=0 : GOTO 198
212 IF E1=(0) E8=1 : GOTO 198
213 IF E1/1000>E E8=0 : GOTO 198
214 IF E>(E1*1000) E8=1 : GOTO 198
215 GOTO 209
216 ; E;TAB(18%)E1
217 GOSUB 233
218 IF E=(0) E8=0 : GOTO 198
219 IF E1=(0) E8=1 : GOTO 198
220 IF E1/1000>E E8=1 : GOTO 198
221 IF E1>(E*1000) E8=1 : GOTO 198
222 GOTO 216
223 R=INT(100*RND)+1 : X2=INT(10*RND)+2 : IF D=1 X2=INT(100*RND)+2
224 IF A(T,D)<=X2 X2=A(T,D)
225 A(T,D)=A(T,D)-X2
226 IF R<(33) 231
227 IF R<(66) 232
228 ; "BAKH]LL UNDER TRANSPORT"
229 ; "DU F\RLORADE JUST"X2" "D$(D)
230 ; "TOTALT ANL[NDA I "N$(T);"= "A(T,D) : RETURN 
231 ; "GERILLA P] "L$(A(T,D+5))+S$ : GOTO 229
232 ; "STORM S[NKER ETT FARTYG" : GOTO 229
233 E=E-INT((E/3)*RND)-2
234 IF E<=0 E=0
235 E1=E1-INT((E1/3)*RND)-2
236 IF E1<=(0) E1=0
237 A(X,J)=E1 : C(X,C)=E
238 RETURN 
239 ; : ; : ; "SORRY, DU MISSLYCKADES."
240 ; "ALLA DINA STYRKOR [R SLAGNA" : ; : END 
241 ; CHR$(12%)"---------------------"
242 ; "G R A T U L E R A R !"
243 ; "---------------------"
244 ; : ; "DU HAR ER\VRAT V[RLDEN MED"Y6" MAN\VRAR."
245 ; : ; "TRYCK EN TANGENT "; : GET H$ : GOTO 148
246 ; : FOR X=1 TO 10 : ; X') 'N$(X) : NEXT X : RETURN 
247 ; : FOR X=1 TO 5 : ; X') 'D$(X) : NEXT X : RETURN 
248 ; : FOR X=1 TO 4 : ; X') 'L$(X) : NEXT X : RETURN 
249 ; STRING$(39%,45%) : ; '1) GLOBAL RAPPORT'
250 ; '2) STATUSRAPPORT F\R VALFRITT LAND'
251 ; '3) FLYTTA STYRKOR'
252 ; '4) FLYGOPERATION'
253 ; '5) STRID (med styrkorna i nuv.l{ge)'
254 RETURN