1 REM Ins{nt av 2839
100 REM ******************************
110 REM **  GOBLIN.GAM    Vers 5.1  **
120 REM **  ======================  **
130 REM ** Nedhackat och modifierat **
140 REM ** 1983-12-18               **
150 REM **                          **
160 REM ** Lars B|rje Cid           **
170 REM ** Stens{ttersg 41 a        **
180 REM ** 641 46  KATRINEHOLM      **
190 REM ** Tel. 0150 - 539 43       **
200 REM **                          **
210 REM ** PS Ekonomer beh|vs!!     **
220 REM **                          **
230 REM ******************************
240 REM ****************************
250 REM **                        **
260 REM **   L[GG UPP MASKINKOD   **
270 REM **                        **
280 REM ****************************
290 REM ** 62720 - RITA \n        **
300 REM ** 62739 - RITA On        **
310 REM ** 62762 - TA BORT On     **
320 REM ** 62785 - POLLA KEYBOARD **
330 REM ****************************
340 FOR I%=0% TO 92% : READ A%
350 POKE 62720%+I%,A%
360 NEXT I%
370 ; CHR$(12%) : ; TAB(16%)'GOBLIN'
380 ; TAB(15%)CHR$(23%)STRING$(6%,35%)
390 ONERRORGOTO 400 : READ A$ : ; CUR(5%+L,5%)A$; : L=L+1 : GOTO 390
400 ; CUR(22%,10%)'TRYCK RETURN!'CHR$(8%);
410 POKE 65013%,0% : GET Z$
420 REM ****************************
430 REM **                        **
440 REM **   INITIERA SPELET      **
450 REM **                        **
460 REM ****************************
470 DEFFNA%(I%,J%)=PEEK(884%+I%*2%)+256%*PEEK(885%+I%*2%)+J%
480 Z%=INP(3%)
490 ; CHR$(12%)TAB(15%) : FOR I%=1% TO 23% : ; : ; CHR$(23%); : NEXT I%
500 RANDOMIZE 
510 P%=0% : P8%=30% : P9%=0%
520 ; CUR(2%,15%)CHR$(1%)'HI: 'P1%
530 ; CUR(22,0)'0 - V{nster                    P - H|ger';
540 OUT 6,0
550 REM ****************************
560 REM **                        **
570 REM **   L[GG UT HINDER       **
580 REM **                        **
590 REM ****************************
600 FOR I%=1% TO 70% : OUT 6,0 : OUT 6,57
610 Y%=INT(RND*15%)+4% : X%=INT(RND*38%)+1%
620 IF PEEK(FNA%(Y%,X%))<>32% THEN 610
630 POKE FNA%(Y%,X%),ASC("f") : NEXT I%
640 REM ******************************
650 REM **                          **
660 REM **   L[GG UT [TBARA SAKER   **
670 REM **   OCH KONTROLLERA ATT    **
680 REM **   DE KAN N]S.            **
690 REM **                          **
700 REM ******************************
710 P7%=0% : FOR I%=1% TO P8%
720 Y%=INT(RND*17%)+4% : X%=INT(RND*38%)+1%
730 IF PEEK(FNA%(Y%,X%))<>32% THEN 720
740 Z1%=PEEK(FNA%(Y%+1%,X%-1%)) : Z2%=PEEK(FNA%(Y%+1%,X%)) : Z3%=PEEK(FNA%(Y%+1%,X%+1%))
750 IF Z1%=102 AND Z2%=102% AND Z3%=102% O0%=ASC("\") : P7%=P7%+1% ELSE O0%=27%
760 POKE FNA%(Y%,X%),O0% : NEXT I%
770 Z%=CALL(62739%) : P8%=P8%-P7%
780 R%=22% : K%=20%
790 R1%=R% : K1%=K%
800 REM ****************************
810 REM **                        **
820 REM **   Styr spelare         **
830 REM **                        **
840 REM ****************************
850 POKE FNA%(R1%,K1%),32%
860 POKE FNA%(R%,K%),127%
870 R1%=R% : K1%=K%
880 R%=R%-1% : IF R%<4% THEN R%=21%
890 OUT 6,0 : FOR P=1 TO 190 : NEXT P : OUT 6,57
900 Z%=CALL(62785%) : IF Z%>2% OR Z%<0% STOP 
910 ON Z%+1% GOTO 960,920,930
920 K%=K%-1% : GOTO 940
930 K%=K%+1%
940 IF K%<1% THEN K%=39%
950 IF K%>39% THEN K%=1%
960 Z%=PEEK(FNA%(R%,K%))
970 IF Z%=102% THEN 1140
980 IF Z%<>ASC("O") THEN 850
990 OUT 6%,0% : OUT 6%,135%
1000 P%=P%+25% : ; CUR(2%,0%)P%
1010 P9%=P9%+1% : IF P9%=P8% P8%=P8%+10% : P9%=0% : POKE FNA%(R1%,K1%),32% : POKE FNA%(R%,K%),32% ELSE 850
1020 REM ****************************
1030 REM **                        **
1040 REM **   Spelare klarar allt  **
1050 REM **                        **
1060 REM ****************************
1070 ; CUR(23%,13%)CHR$(1%)'G O O D ! !';
1080 OUT 6%,0% : FOR P=1 TO 1000 : OUT 6%,255% : NEXT P : ; CUR(23%,0%)SPACE$(38%); : GOTO 520
1090 REM ****************************
1100 REM **                        **
1110 REM **   Spelare missar       **
1120 REM **                        **
1130 REM ****************************
1140 POKE FNA%(R1%,K1%),32%
1150 FOR I%=1% TO 10% : POKE FNA%(R%,K%),32%
1160 FOR P=1 TO 40 : OUT 6%,9% : NEXT P
1170 POKE FNA%(R%,K%),ASC("f")
1180 FOR P=1 TO 40 : OUT 6%,0% : NEXT P : NEXT I%
1190 FOR I%=1 TO 19 : OUT 6,0 : FOR P=1 TO 13 : NEXT P : Z%=CALL(62762%)
1200 FOR P=1 TO 13 : NEXT P : OUT 6,0 : Z%=CALL(62739%) : NEXT I%
1210 Z%=CALL(62720%)
1220 ; CUR(22%,0%)SPACE$(40%)CUR(22%,0%)'Spela igen (J/N) '; : POKE 65013%,0% : GET Z$
1230 IF P1%<P% THEN P1%=P%
1240 IF Z$<>"N" THEN 490
1250 ; CHR$(12%)TAB(11%)'P} }terseende.'
1260 REM ****************************
1270 REM **                        **
1280 REM **   DATA F\R MASKINKOD   **
1290 REM **                        **
1300 REM ****************************
1310 DATA 1,192,3,33,0,124,126,254,79
1320 DATA 32,3,62,92,119,237,161,224,24
1330 DATA 243,62,135,211,6,1,192,3,33,0
1340 DATA 124,126,254,27,32,3,62,79,119
1350 DATA 237,161,224,24,243,62,135,211
1360 DATA 6,1,111,3,33,0,124,126,254,79
1370 DATA 32,3,62,27,119,237,161,224,24
1380 DATA 243,219,56,245,175,50,245,253
1390 DATA 241,254,207,40,8,254,208,40,8
1400 DATA 33,0,0,201,33,1,0,201,33,2,0
1410 DATA 201
1420 REM ****************************
1430 REM **                        **
1440 REM **  DATA F\R INFORMATION  **
1450 REM **                        **
1460 REM ****************************
1470 DATA 'GOBLIN g}r ut p} att {ta upp
1480 DATA 'O :  na men se upp f|r hindren.',
1490 DATA 'N{r det  {r om|jligt att  ta
1500 DATA 'ett  O  f|rvandlas  det till
1510 DATA 'ett \.',,
1520 DATA 'Du styr med f|ljande :  ',
1530 DATA ,'       O - V{nster'
1540 DATA '       P - H|ger'