10 REM +++++++++++++++++++++++++++++++++
11 REM ! Program ....   KATTR]TT
12 REM ! Utg}va         1981-02-18
13 REM ! av (c) Isak Engquist
14 REM ! Minne 16 Kbytes
15 REM ! Ins{nt av 325
16 REM +++++++++++++++++++++++++++++++++
17 REM 
18 REM Screened by <TCP>
19 REM 
20 REM !     VARIABELBESKRIVNING : 
21 REM !     =====================
22 REM 
23 REM R%,K% = KATTENS MITTKOORDINATER
24 REM R1%,K1% = R]TTANS KOORDINATER
25 REM P% = PO[NGEN    P1% = REKORD
26 REM T% = LOOP SOM BEST[MMER SPELTID
27 REM X% = SLASKVARIABEL I LOOPAR
28 REM T$ = VARIABEL F\R INPUT OCH GET
29 REM 
30 REM $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
31 GOSUB 57
32 RANDOMIZE 
33 ; CHR$(12%);CUR(12%,13%)'G\R DIG BEREDD !'
34 FOR I%=450% TO 0% STEP -1% : ; CUR(14%,19%)FIX(I%/90%)+1% : NEXT I%
35 ; CHR$(12%); : FOR X%=1% TO 23% : ; CUR(X%,0%);CHR$(151%); : NEXT X%
36 R%=34% : K%=34% : R1%=42% : K1%=42% : P%=0%
37 ; CUR(10%,15%);'h|||'CUR(11%,15%)'j'CUR(12%,15%)'*///'
38 FOR T%=1% TO 800%
39 IF INP(56%)>127% A%=INP(56%) AND 127% ELSE A%=1%
40 IF A%=72% IF K%<=5% 44 ELSE FOR X%=R%-3% TO R%+3% : SETDOT X%,K%-4% : CLRDOT X%,K%+3% : NEXT X% : K%=K%-1%
41 IF A%=85% IF R%<=6% 44 ELSE FOR X%=K%-3% TO K%+3% : SETDOT R%-4%,X% : CLRDOT R%+3%,X% : NEXT X% : R%=R%-1%
42 IF A%=74% IF K%>=76% 44 ELSE FOR X%=R%-3% TO R%+3% : CLRDOT X%,K%-3% : SETDOT X%,K%+4% : NEXT X% : K%=K%+1%
43 IF A%=78% IF R%>=68% 44 ELSE FOR X%=K%-3% TO K%+3% : CLRDOT R%-3%,X% : SETDOT R%+4%,X% : NEXT X% : R%=R%+1%
44 ON FIX(4*RND)+1% GOTO 45,46,47,48
45 CLRDOT R1%,K1% : K1%=K1%-1% : GOTO 49
46 CLRDOT R1%,K1% : K1%=K1%+1% : GOTO 49
47 CLRDOT R1%,K1% : R1%=R1%+1% : GOTO 49
48 CLRDOT R1%,K1% : R1%=R1%-1%
49 SETDOT R1%,K1%
50 IF R1%>=71% CLRDOT R1%,K1% : R1%=R1%-1%
51 IF R1%<=3% CLRDOT R1%,K1% : R1%=R1%+1%
52 IF K1%>=79% CLRDOT R1%,K1% : K1%=K1%-1%
53 IF K1%<=2% CLRDOT R1%,K1% : K1%=K1%+1%
54 IF R1%>=R%-3% AND R1%<=R%+3% AND K1%>=K%-3% AND K1%<=K%+3% P%=P%+1%
55 ; CUR(0%,15%);P%; : NEXT T%
56 GOTO 68
57 ; CHR$(12%);
58 ; '        K A T T  och  R ] T T A'
59 ; CHR$(151%);'       #######################'
60 ; : ; 'DU SKA STYRA "KATTEN" OCH F\RS\KA F]NGA "R]TTAN". KATTEN [R DEN STORA FYRKANTEN.DEN STYR DU ';
61 ; 'MED F\LJANDE TANGENTER :'
62 ; : ; '                  U                                      H J                                      N'
63 ; : ; 'I RESPEKTIVE V[DERSTRECK.'
64 ; : ; 'S] L[NGE DU LYCKAS STYRA KATTEN S] ATT  R]TTAN [R INNE I DEN, F]R DU PO[NG.'
65 ; 'PO[NGEN VISAS HELA TIDEN H\GST UPP.'
66 ; : ; 'DU F]R H]LLA P] I DRYGT 20 sek. UNDER   DEN TIDEN SKA DU ALLTS] SAMLA S] M]NGA  PO[NG SOM M\JLIGT.'
67 ; : ; 'TRYCK N]GONSTANS N[R DU [R REDO.' : POKE 65013%,0% : GET T$ : RETURN 
68 ; CUR(20%,0%)SPACE$(198%); : FOR I=1% TO 999% : NEXT I : IF P%>P1% THEN P1%=P%
69 ; CUR(21%,0%);;'DU FICK'P%' PO[NG.    REKORDET [R'P1%'.'
70 POKE 65013%,0%
71 ; : ; 'VILL DU SPELA MER (J) '; : GET T$
72 ON INSTR(1%,'JjNn'+CHR$(13%),T$)+1% GOTO 69,32,32,73,73,32
73 ; CUR(18%,0); : END