1 REM +++++++++++++++++++++++++++++++++
2 REM ! Program ....   LABJAKT
3 REM ! Utg}va         1981-09-22
4 REM ! av (c) Ronny Wiik
5 REM ! {ndrat av Anders Andersson
6 REM ! Minne 16 Kbytes
7 REM ! Ins{nt av 126
8 REM +++++++++++++++++++++++++++++++++
9 REM 
10 REM Screened by +TCP+
11 REM 
12 ; CHR$(12%)"VILL DU HA INSTRUKTIONER?"; : GET S$ : IF S$="J" GOSUB 86
13 REM  UTRITNING AV RAM 
14 ; CHR$(12%)
15 FOR I%=0% TO 23%
16 ; CUR(I%,0%)CHR$(23%);
17 NEXT I%
18 A%=3% : B%=79% : C%=0% : D%=71%
19 FOR I%=A% TO B%
20 SETDOT C%,I%
21 NEXT I%
22 FOR I%=C% TO D%
23 SETDOT I%,B%
24 NEXT I%
25 FOR I%=B% TO A% STEP -1%
26 SETDOT D%,I%
27 NEXT I%
28 FOR I%=D% TO C% STEP -1%
29 SETDOT I%,A%
30 NEXT I%
31 A%=A%+4% : B%=B%-4% : C%=C%+4% : D%=D%-4%
32 IF D%=35% GOTO 34
33 GOTO 19
34 FOR I%=1% TO 22%
35 IF I%=10% OR I%=11% OR I%=12% OR I%=13% 37
36 ; CUR(I%,20%)"  ";
37 NEXT I%
38 FOR I%=2% TO 37%
39 IF I%=16% OR I%=17% OR I%=18% OR I%=19% OR I%=20% OR I%=21% OR I%=22% OR I%=23% 42
40 ; CUR(11%,I%)" ";
41 ; CUR(12%,I%)" ";
42 NEXT I%
43 A%=0% : B%=A% : C%=B% : D%=C% : I%=D%
44 REM  MAIN LOOP 
45 REM  DU STYR 
46 X%=70% : Y%=X% : Z%=13% : T%=Z% : P2%=4%
47 SETDOT 33,41 : CLRDOT 32,41
48 Q%=INP(16%)
49 IF Q%<127% THEN 55
50 CLRDOT Y%,X%
51 IF Q%=193% X%=X%-1% : IF DOT(Y%,X%) X%=X%+1%
52 IF Q%=211% X%=X%+1% : IF DOT(Y%,X%) X%=X%-1%
53 IF Q%=215% Y%=Y%-1% : IF DOT(Y%,X%) Y%=Y%+1%
54 IF Q%=218% Y%=Y%+1% : IF DOT(Y%,X%) Y%=Y%-1%
55 T1%=T% : Z1%=Z%
56 REM  DATORN STYR 
57 P%=P%+1% : IF P%=P2% P%=0% : GOTO 62 ELSE 58
58 IF T%>Y% T%=T%-1% : IF DOT(T%,Z%) T%=T%+1%
59 IF T%<Y% T%=T%+1% : IF DOT(T%,Z%) T%=T%-1%
60 IF Z%>X% Z%=Z%-1% : IF DOT(T%,Z%) Z%=Z%+1%
61 IF Z%<X% Z%=Z%+1% : IF DOT(T%,Z%) Z%=Z%-1%
62 IF T%=Y% AND Z%=X% 75
63 CLRDOT T1%,Z1% : SETDOT T%,Z% : SETDOT Y%,X%
64 REM  KONTAKT? 
65 IF DOT(1,4) D%=1%
66 IF DOT(1,78) D%=1%
67 IF DOT(70,78) D%=1%
68 IF DOT(70,4) D%=1%
69 IF D%=1% AND Y%=32% AND X%=41% D%=0% : P1%=P1%+1%
70 ; CUR(12,18);CHR$(135%);P1%;CHR$(23%);
71 FOR S=1 TO 50-(P1%+3) : NEXT S
72 P2%=P1% : IF P2%=0% OR P2%=1% P2%=2%
73 IF P1%>15% AND P3%<>3% GOSUB 99
74 GOTO 48
75 REM  DU [R D\D 
76 FOR I=0 TO 1000 : ; "SLUTT "; : NEXT I
77 FOR I=0 TO 3000 : NEXT I
78 ; CHR$(12)
79 IF P1%<5% A$="D]LIG"
80 IF P1%>=5% A$="BRA"
81 IF P1%>=10% A$="B[TTRE"
82 IF P1%>=16% A$="LITE B[TTRE"
83 IF P1%>=20% A$="B[ST"
84 ; CUR(12,7);"DU VAR ";A$;"  (";P1%;" P )" : ; : ; : ; : END 
85 REM  INSTRUKTIONER 
86 ; CHR$(12)
87 ; "SPELET G]R UT P] ATT TA SIG TILL ETT"
88 ; : ; "H\RN OCH SEDAN TA SIG TILL DET LILLA"
89 ; : ; "H]LET I CENTRUMRUTAN. N[R MAN GJORT DET"
90 ; : ; "S] \KAS PO[NGEN MED 1"
91 ; : ; "HELA TIDEN [R DET EN ANNAN DOT SOM"
92 ; : ; "JAGAR DIG OCH JU MER DIN PO[NG \KAR"
93 ; : ; "DESTO SNABBARE G]R SPELET (OCH DOTTEN)"
94 ; : ; : ; "DU FLYTTAR DOTTEN UPP]T MED W,NED]T MED"
95 ; : ; "Z OCH V[NSTER RESP. H\GER MED A,S"
96 ; : ; : ; "TRYCK P] MELLANSLAGET N[R DU [R KLAR"
97 IF INP(16)=160 RETURN ELSE 97
98 REM  CLRDOTRUTIN 
99 FOR I=1 TO 200
100 X=INT(RND*79) : IF X<4 THEN 100
101 Y=INT(RND*70) : IF Y<2 THEN 101
102 CLRDOT Y,X
103 NEXT I
104 P3%=3% : RETURN