1 REM +++++++++++++++++++++++++++++++
2 REM ! Program ....   RIVAMUR.GAM
3 REM ! Utg}va  1.3    82-01-16
4 REM ! av (c) Gunnar Str|mb{ck 1243 
5 REM ! Minne 16 Kbytes
6 REM ! screenat av Tom Sj|berg 2401
7 REM ! Ins{nt av 1243
8 REM +++++++++++++++++++++++++++++++
9 REM ID@ AV MIN BROR ERIK
10 REM Programmet {r av typ "bollspel"
11 REM 
200 REM STYRNING AV MOTTAGARE SKER MED
210 REM 'Z' OCH '-' TANGENTERNA.
220 REM DU HAR TRE BOLLAR. TV] MISSAR
230 REM [R TILL]TNA PER BOLL. VARJE 
240 REM MISS GER MINUS FEM PO[NG.
250 REM VARJE UTSLAGEN STEN GER PLUS
260 REM EN PO[NG.
270 REM HELT RIVEN MUR GER NY MUR.
280 REM FART[NDRING KAN SKE GENOM 
290 REM [NDRING AV LOOPEN P] RAD 420
300 ; CHR$(12%)
310 ; CUR(2%,3%)"VILL DU HA INSTRUKTIONER S] TRYCK"
320 ; CUR(3%,3%)"CTRL-C OCH LISTA PROGRAMMET."
330 ; CUR(8%,13%)"TRYCK TANGENT"; : GET A$
340 ; CHR$(12%)
350 RANDOMIZE 
360 REM  INIT 
370 B%=19% : C%=5% : D%=2% : E%=RND*2%+1% : F%=14% : H=0 : I=0 : J=9 : K=1
380 DIM A%(33%),B%(33%),C%(33%),D%(33%),E%(33%),F%(33%)
390 FOR X%=0% TO 22% : ; CUR(X%,2%)"!" : ; CUR(X%,29%)"!" : NEXT X%
400 ; CUR(18%,30%)"PO[NG"
410 ; CUR(10%,5%)"TRYCK N[R DU [R KLAR"; : GET A$
420 ; CUR(10%,5%)SPACE$(20%)
430 FOR X%=3% TO 27% STEP 2% : ; CUR(3%,X%)"" : ; CUR(4%,X%+1%)"" : ; CUR(5%,X%)"" : ; CUR(6%,X%+1%)""
440 ; CUR(7%,X%)"" : ; CUR(8%,X%+1%)"" : A%(X%)=X% : B%(X%+1%)=X%+1% : C%(X%)=X% : D%(X%+1%)=X%+1%
450 E%(X%)=X% : F%(X%+1%)=X%+1% : NEXT X%
460 ; CUR(10,30)"BOLL"K
470 REM  HUVUD LOOP 
480 A%=INP(56%)
490 FOR A=0 TO 20 : NEXT A
500 IF A%=218% OR A%=250% THEN GOSUB 880
510 IF A%=173% THEN GOSUB 940
520 ; CUR(21%,F%)"___"
530 ; CUR(14%,F%)"___"
540 IF B%=21% AND C%=F% OR B%=21% AND C%=F%+1% OR B%=21% AND C%=F%+2% THEN GOSUB 1000
550 IF B%=14% AND C%=F% OR B%=14% AND C%=F%+1% OR B%=14% AND C%=F%+2% THEN GOSUB 1000
560 IF B%=3% AND C%=A%(C%) THEN GOSUB 1000 : A%(C%)=-1% : GOSUB 1070
570 IF B%=4% AND C%=B%(C%) THEN GOSUB 1000 : B%(C%)=-1% : GOSUB 1070
580 IF B%=5% AND C%=C%(C%) THEN GOSUB 1000 : C%(C%)=-1% : GOSUB 1070
590 IF B%=6% AND C%=D%(C%) THEN GOSUB 1000 : D%(C%)=-1% : GOSUB 1070
600 IF B%=7% AND C%=E%(C%) THEN GOSUB 1000 : E%(C%)=-1% : GOSUB 1070
610 IF B%=8% AND C%=F%(C%) THEN GOSUB 1000 : F%(C%)=-1% : GOSUB 1070
620 ; CUR(B%,C%)" "
630 ON D% GOSUB 700,760
640 ON E% GOSUB 800,840
650 ; CUR(B%,C%)"*"
660 ; CUR(20%,30%);H;"   "
670 IF I=78 AND B%<3% OR I=78 AND B%>8% THEN I=0 : GOTO 430
680 GOTO 480 : REM  LOOP END 
690 REM  BOLL NED 
700 B%=B%+1%
710 IF B%=22% THEN D%=2% : H=H-5 : J=J-1 : ; CHR$(7)
720 IF B%=22% AND J=6 OR B%=22% AND J=3 THEN GOSUB 1090
730 IF J=0 THEN 1120
740 RETURN 
750 REM  BOLL UPP 
760 B%=B%-1%
770 IF B%=0% THEN D%=1%
780 RETURN 
790 REM  BOLL H\GER 
800 C%=C%+1%
810 IF C%=28% THEN E%=2%
820 RETURN 
830 REM  BOLL V[NSTER 
840 C%=C%-1%
850 IF C%=3% THEN E%=1%
860 RETURN 
870 REM  MOTTAGARE V[NSTER 
880 ; CUR(21%,F%)"   "
890 ; CUR(14%,F%)"   "
900 IF F%=3% THEN RETURN 
910 F%=F%-1%
920 RETURN 
930 REM  MOTTAGARE H\GER 
940 ; CUR(21%,F%)"   "
950 ; CUR(14%,F%)"   "
960 IF F%=26% THEN RETURN 
970 F%=F%+1%
980 RETURN 
990 REM  BOLLSTUDS OCH PO[NG 
1000 IF D%=1% THEN D%=2% ELSE IF D%=2% D%=1%
1010 IF B%<3% OR B%>8% THEN 1050
1020 IF C%=3% AND E%=1% THEN 1040
1030 IF C%=28% AND E%=2% THEN 1040
1040 H=H+1
1050 RETURN 
1060 REM  LJUD 
1070 I=I+1 : OUT 6,75 : FOR A=0 TO 55 : NEXT A : OUT 6,0 : RETURN 
1080 REM  NY BOLL 
1090 ; CUR(20%,30%)"    " : B%=19% : IF F%/2=INT(F%/2) THEN C%=F% ELSE C%=F%+1%
1100 D%=2% : K=K+1 : ; CUR(10,30)"BOLL"K : FOR A=0 TO 2000 : NEXT A : RETURN 
1110 REM  EN G]NG TILL??? 
1120 ; CHR$(12%) : ; CUR(10%,3%)"SPELET [R SLUT. DIN PO[NG BLEV"H
1130 ; : ; "EN G]NG TILL (JA)"; : INPUT A$ : IF A$="J" OR A$="JA" OR A$="" THEN ; CHR$(12%) : GOTO 370
1140 END