10 REM +++++++++++++++++++++++++++++++++
11 REM ! Program ....JAKTPLAN.GAM
12 REM ! Utg}va  R  .   1982-02-17
13 REM ! av VINCENT SALDELL <1165>
14 REM ! granskat av BO HJULSTR\M <557>
15 REM ! Copyright -
16 REM ! Minne 16 Kbytes
17 REM ! Ins{nt av KALLE LINDSTR\M <837>
18 REM +++++++++++++++++++++++++++++++++
19 REM SPELPROGRAM : 
20 REM STYR DITT JAKTPLAN OCH F\RS\K
21 REM SKJUTA NED M]LET (ETT BOMBPLAN).
22 REM 
23 REM 
24 REM 
25 REM 
26 REM 
27 REM 
28 REM 
29 REM 
30 REM +++++++++++++++++++++++++
31 REM ****************************
32 REM * _____J_A_K_T_P_L_A_N____ *
33 REM * Gjort av Vincent Saldell *
34 REM * tel. 0764/23322          *
35 REM * adr. Kvarn}sv{gen 2      *
36 REM * box. 184 02 \stersk{r    *
37 REM * ________________________ *
38 REM * the MEE MEE programmer ! *
39 REM ****************************
40 \%=50%
41 ; CHR$(12)
42 A$="** JAKTPLAN * JAKTPLAN * JAKTPLAN **"
43 FOR T=1 TO LEN(A$)
44 ; CUR(2,2)LEFT$(A$,T) : ; CUR(22,2)LEFT$(A$,T) : OUT 6,0 : OUT 6,137
45 FOR R=1 TO 100
46 NEXT R
47 NEXT T
48 FOR T=1 TO 3000 : NEXT T
49 ; CUR(5,7)'The MEE MEE programmer !'CHR$(7)
50 ; CUR(10,2)'\nskas instruktioner ?'
51 GET Q$
52 IF Q$="J" OR Q$="j" THEN OUT 6,0 : OUT 6,135 ELSE 72
53 ; CHR$(12)
54 ; 'Du styr ditt jaktplan s} h{r...'
55 ; 'U=upp N=ned J=h|ger H=v{nster'
56 ; 'och avfyrar din automatkanon'
57 ; 'med <MELLANSLAG>.'
58 ; : ; '   S} h{r...'
59 ; : ; '                U'
60 ; '               H J'
61 ; '                N'
62 ; '         <MELLANSLAG>'
63 ; : ; 'Du ska f} bombplanet i ditt sikte.'
64 ; 'D{refter skall du skjuta ned det.'
65 ; : ; 'Fiendeplanen g|r sj{lvklart'
66 ; 'undanman|vrar f|r att undkomma.'
67 ; 'I siktet st}r det hur m}nga tr{ffar'
68 ; 'som du gjort.'
69 ; 'Tryck p} <UPPERCASE> f|r styrning.'
70 ; 'Tryck en tangent f|r start.'
71 GET Y$
72 ; CHR$(12)
73 RANDOMIZE 
74 Y%=50% : X%=50% : Q=200
75 A$='   !   '
76 B$='__oOo__'
77 C$='  " "  '
78 D$='         '
79 REM _______G_]_R___H_I_T____________
80 A=(.075*RND(1)-.02)
81 B=(.075*RND(1)-.02)
82 X%=X%+B
83 Y%=Y%+A
84 IF U%=1% THEN 86
85 ; CUR(Y%-2%,X%)D$CUR(Y%-1%,X%)D$CUR(Y%,X%)D$CUR(Y%+1%,X%)D$CUR(Y%+2%,X%)D$
86 IF X%<1% OR X%>32% OR Y%<1% OR Y%>17% THEN U%=1% ELSE U%=0%
87 REM ______A_V_L_[_S_N_I_N_G______
88 I%=INP(56%)
89 IF I%=213% THEN Y%=Y%+1%
90 IF I%=206% THEN Y%=Y%-1%
91 IF I%=200% THEN X%=X%+1%
92 IF I%=202% THEN X%=X%-1%
93 ; CUR(20%,0%)'RADAR'
94 IF X%<-1% THEN X%=-1% : ; CUR(21%,8%)'*' ELSE ; CUR(21%,8%)'O'
95 IF X%>34% THEN X%=34% : ; CUR(21%,10%)'*' ELSE ; CUR(21%,10%)'O'
96 IF Y%<-1% THEN Y%=-1% : ; CUR(20%,9%)'*' ELSE ; CUR(20%,9%)'O'
97 IF Y%>18% THEN Y%=18% : ; CUR(22%,9%)'*' ELSE ; CUR(22%,9%)'O'
98 IF U%=1% THEN 100
99 ; CUR(Y%,X%)B$CUR(Y%-1%,X%)A$CUR(Y%+1%,X%)C$
100 IF I%=160% THEN 111
101 REM +++++ SIKTE +++++
102 ; CUR(8,19)'!'CUR(7,19)'!'
103 ; CUR(16,19)'!'CUR(17,19)'!'
104 ; CUR(12,6)'________'CUR(12,25)'________'
105 ; CUR(10%,10%)F%
106 FOR T=1 TO Q : NEXT T
107 IF \%<1% THEN 141
108 ; CUR(22%,20%)'Skott='\%
109 GOTO 80
110 REM  SKOTT 
111 T=18 : A%=0% : B%=39%
112 \%=\%-1%
113 OUT 6,0 : OUT 6,137 : FOR R=1 TO 200 : NEXT R : OUT 6,0 : OUT 6,159
114 T=T-.29 : A%=A%+1% : B%=B%-1%
115 ; CUR(T,A%)'.'CUR(T,B%)'.'
116 FOR R=1 TO 12 : NEXT R
117 ; CUR(T,A%)' 'CUR(T,B%)' '
118 IF A%>B% THEN 120
119 GOTO 114
120 IF A%=X%+4% AND Y%=INT(T+.5) THEN OUT 6,0 : OUT 6,13 ELSE 80
121 ; CUR(9,10)'   o       /'
122 ; CUR(11,10)'c    O        q'
123 ; CUR(13,6)'_      *  :           _   .'
124 FOR T=1 TO 200
125 NEXT T
126 ; CUR(7,6)'  \        .  /'
127 ; CUR(9,8)'_   o               >    - _'
128 FOR T=1 TO 200 : NEXT T
129 ; CUR(7,3)'*           _  _O        #   b'
130 ; CUR(5,3)'  +   L              OO     _  - :'
131 ; CUR(13,6)'                                      '
132 ; CUR(11,10)'                     '
133 FOR T=1 TO 200 : NEXT T
134 ; CUR(9,10)'                '
135 ; CUR(1,1)' OOoo    $     / >        I    T  ooOO'
136 ; CUR(2,1)'      oo P      q   * __  V  L'
137 ; CUR(7,1)'                                      '
138 ; CUR(9,1)'                                      '
139 F%=F%+1%
140 OUT 6,0 : GOTO 72
141 ; CHR$(12)
142 ; "BEKLAGAR,AMUNITIONEN [R SLUT."
143 IF F%>[% THEN 152
144 ; "Du har skjutit ned "F%" bombplan."
145 ; 'Rekord"esset" hade '[%' nedskjutningar.'
146 ; : ; 'Han heter s} mycket som...'
147 ; : ; [$
148 GOTO 163
149 ; : ; M$ : ; : ; : ; 'Vill du flyga igen ?'
150 INPUTLINE S$
151 IF LEFT$(S$,1)="J" OR LEFT$(S$,1)="j" THEN \%=50% : F%=0% : GOTO 72 ELSE END 
152 ; "Du {r det nya flygaresset!"
153 ; "Du har "F%" segrar."
154 ; "Det gamla rekordet var "[%" segrar."
155 ; "Det var satt av "[$"."
156 [%=F%
157 ; : ; : ; "Det nya rekordet {r "[%" segrar !!"
158 ; : ; "Var sn{ll och skriv ditt namn."
159 ; : ; "H|gst en rad !!"
160 INPUTLINE [$
161 IF LEN([$)>28 THEN [$=LEFT$([$,28)
162 GOTO 148
163 FOR T=1 TO 1000 : NEXT T
164 ; : ; : ; "H{r kommer datorns utl}tande..."
165 FOR T=1 TO 1000 : NEXT T
166 M$="[r du hj{rnd|d ?"
167 IF F%>3% THEN M$="Ganska d}ligt !"
168 IF F%>8% THEN M$="Du kunde varit b{ttre."
169 IF F%>10% THEN M$="Det var ju medelbra."
170 IF F%>15% THEN M$="BRA ! ! ! ! ! ! "
171 IF F%>20% THEN M$="*_*_*_E_X_E_L_E_N_T_*_*_*"
172 IF F%>40% THEN M$="Du {r ett M[STARESS !!!!!!!!!!"
173 IF F%>=50% THEN M$="Helt oslagbart !!Superbra!!!!!!!!!!"
174 GOTO 149