1 REM Ins{nt av 507
10 REM ++++++++++++++++++++++++++++++++
20 REM ! Program ....   STEGM
30 REM ! Utg}va  1.1    810711
40 REM ! av (c) ASBJ\RN HAMBERG
50 REM ! Minne 16 Kbytes f|r flexskiva
60 REM ! +1st I/O kort typ DATABOARD
70 REM ! 4005 etc.
72 REM ! +drivsteg f|r stegmotorn.
80 REM ! Ins{nt av AH.<507>
90 REM ++++++++++++++++++++++++++++++++
100 REM 
110 REM Se vidare i filen STEGM.INF
120 REM 
130 ; CHR$(12)
140 ; CUR(5,2);"STYRNING (av stegmotor) VER 1.1"
150 ; CUR(6,2);"==============================="
160 ; CUR(9,2);"jogga eller k|ra (j/k)"; : INPUT A$
170 IF A$="j" OR A$="J" THEN 180 ELSE 420
180 B=4
190 ; CHR$(12);CUR(2,3);"ETT PROGRAM FR]N ABC80-MAFFIAN !"
200 ; CUR(3,3);"================================"
210 ; CUR(8,4);"k|r jog med 'v-pil' och 'h-pil'"
220 ; CUR(14,4);"avbryt f|r omstart med ctrl-c"
230 ; CUR(16,4);"efter STOP LINE 'XXX' och"
240 ; CUR(17,4);"ABC80"
250 ; CUR(19,4);"skriv RUN samt tryck RETURN"
260 OUT 1,2 : A=INP(56) : IF A=136 THEN 280 ELSE 270
270 IF A=8 THEN 260 ELSE 340
280 FOR I=0 TO 100 : OUT B,5
290 OUT B,9
300 OUT B,10
310 OUT B,6
320 NEXT I
330 GOTO 260
340 OUT 1,2 : A=INP(56) : IF A=137 THEN 360 ELSE 350
350 IF A=9 THEN 340 ELSE 260
360 FOR I=0 TO 100 : OUT B,6
370 OUT B,10
380 OUT B,9
390 OUT B,5
400 NEXT I
410 GOTO 340
420 ; CHR$(12)
430 ; "hur m}nga cykler"; : INPUT S
440 S=S*2
450 ; "hur l}ngt (mm)"; : INPUT D
460 D=D/.00479
470 ; "vilken startriktning 1=v{ 2=h|"; : INPUT C
480 B=4 : REM ****** motorval
490 REM 
500 REM 
510 REM ****** 1=start }t v{nster
520 REM ****** 2=start }t h|ger
530 REM 
540 ; CHR$(12);CUR(2,3);"ETT PROGRAM FR]N ABC80-MAFFIAN !"
550 ; CUR(3,3);"================================"
560 I=0
570 A=INP(7)
580 OUT 1,2
590 IF C=2 THEN 690 ELSE 630
600 GOTO 630
610 I=0
620 L=L+1 : IF L=S THEN 730
630 OUT B,5 : I=I+1 : IF I>=D THEN 670
640 OUT B,9 : I=I+1 : IF I>=D THEN 670
650 OUT B,10 : I=I+1 : IF I>=D THEN 670
660 OUT B,6 : I=I+1 : IF I>=D THEN 670 ELSE 630
670 I=0
680 L=L+1 : IF L=S THEN 730
690 OUT B,6 : I=I+1 : IF I>=D THEN 610
700 OUT B,10 : I=I+1 : IF I>=D THEN 610
710 OUT B,9 : I=I+1 : IF I>=D THEN 610
720 OUT B,5 : I=I+1 : IF I>=D THEN 610 ELSE 690
730 ; CHR$(12);CUR(2,3);"ETT PROGRAM FR]N ABC80-MAFFIAN !"
740 ; CUR(3,3);"================================"
750 ; CUR(12,0);S/2;" cykler med l{ngd ";D*.00479;" mm k|rda" : FOR I=0 TO 2000 : OUT 6,7 : NEXT I : STOP