1 REM Ins{nt av 855
10 REM LIST GET.UTL
20 REM ********************************
30 REM * GET.UTL / Minne 16 K         *
40 REM * Ver. 1.0 / 1984.10.16        *
50 REM * (c) Arvid Lundgren   <855>   *
60 REM * H|jdv 20A, 923 00 Storuman   *
70 REM * Tel 0951/111 17, 0951/113 20 *
80 REM ********************************
100 REM En i mitt tycke r{tt s} anv{ndbar rutin f|r inmatning av data med GET$
110 REM ************ G|r s} h{r ***********
120 REM Du vill ha inmatning av t ex ett datum (se f | min rutin DATKOLL.UTL)
125 REM [%=R{ttningskod
130 REM ; CUR(10,10)'Ange datum  <      >'
140 REM \1%=6%
142 REM \2%=10% 
144 REM \3%=23%
150 REM IF [%=1% X$=D$ (kolon) GOSUB 10100 ELSE GOSUB 10000
155 REM D$=X$
160 REM Koll om r{tt inmatning! Om fel s{tt [%=1% och GOTO 140
165 REM [%=0%
170 REM G} vidare i Ditt trevliga program!
180 REM 
10000 REM ****** SUBRUTIN F\R INSKRIVNING AV DATA MED GET X$ ******
10010 REM \1%=MAX RADL[NGD (F]R INTE VARA ST\RRE [N 79%)
10020 REM \2%=RAD NR
10030 REM \3%=KOLUMNB\RJAN
10040 REM X1$=INMATNINGSVARIABEL
10050 REM X$ =IN- OCH UTVARIABEL
10060 X$=SPACE$(0%) : REM NOLLST[LL X$
10070 REM --------------------------------------------------------
10080 REM ********** TA RUTINEN H[RIFR]N VID R[TTNING!! **********
10090 REM O B S !!  SE TILL ATT F\RE GOSUB S[TTA X$ = GAMLA TEXTEN
10100 X%=1% : REM CURSORPLACERING
10110 ; CUR(23%,0%)'(CTRL-B= -1 / CTRL-N= +1 / CTRL-X= -h|)';
10120 IF LEN(X$)>\1% X$=LEFT$(X$,\1%) : ; CHR$(7%);
10130 ; CUR(\2%,\3%)SPACE$(\1%) : IF X%=0% X%=1% ELSE IF X%>\1% X%=\1%
10140 ; CUR(\2%,\3%)X$ : ; CUR(\2%,\3%+X%-1%); : GET X1$
10142 IF X1$>CHR$(63%) AND X1$<CHR$(127%) X1$=CHR$(ASC(X1$)-32%) : REM Sm} tecken till STORA !! Ta ev. bort raden!
10150 IF X1$=CHR$(32%) 10190 ELSE IF X1$=CHR$(14%) 10200 ELSE IF X1$=CHR$(2%) 10210
10160 IF X1$=CHR$(9%) 10240 ELSE IF X1$=CHR$(13%) 10270 ELSE IF X1$=CHR$(8%) 10230
10170 IF X1$=CHR$(24%) X$=LEFT$(X$,X%-1%) : GOTO 10120 ELSE IF X1$>CHR$(32%) 10180 ELSE 10120
10180 X1$=LEFT$(X$,X%-1%)+X1$ : IF X%+1%>LEN(X$) X$=X1$ : GOTO 10220 ELSE X$=X1$+RIGHT$(X$,X%+1%) : GOTO 10220
10190 X1$=LEFT$(X$,X%-1%)+X1$ : IF X%>LEN(X$) X$=X1$ : GOTO 10220 ELSE X$=X1$+RIGHT$(X$,X%+1%) : GOTO 10220
10200 X1$=LEFT$(X$,X%-1%)+CHR$(32%) : IF X%>LEN(X$) X$=X1$ : GOTO 10120 ELSE X$=X1$+RIGHT$(X$,X%) : GOTO 10120
10210 X1$=LEFT$(X$,X%-1%) : IF X%+1%>LEN(X$) X$=X1$ : GOTO 10230 ELSE X$=X1$+RIGHT$(X$,X%+1%) : GOTO 10120
10220 X%=X%+1% : GOTO 10120
10230 X%=X%-1% : GOTO 10120
10240 IF X%>LEN(X$) X%=LEN(X$)
10250 GOTO 10220
10260 REM --- Kolla sista och f|rsta tecknet ---
10270 IF LEN(X$)=0% 10300 ELSE IF RIGHT$(X$,LEN(X$))<CHR$(33%) X$=LEFT$(X$,LEN(X$)-1%) : GOTO 10270
10272 IF LEN(X$)<2% 10300 ELSE IF LEFT$(X$,1%)<CHR$(33%) X$=RIGHT$(X$,2%) : GOTO 10272
10280 REM ---- Ta bort eventuell punkt i slutet ----
10290 IF RIGHT$(X$,LEN(X$))=CHR$(46%) X$=LEFT$(X$,LEN(X$)-1%) : GOTO 10270
10300 ; CUR(23%,0%)SPACE$(39%); : RETURN