1 REM Ins{nt av 2839
100 REM ! -----------------------------
110 REM ! --- Ett program fr}n CDS. ---
120 REM ! --- ===================== ---
130 REM ! ---                       ---
140 REM ! --- Program  MENY2___.BAS ---
150 REM ! --- Version  1.0          ---
160 REM ! --- Created  1983-09-30   ---
170 REM ! --- Copyright  CDS        ---
180 REM ! --- Lars-B|rje Cid        ---
190 REM ! --- Helst DISK.           ---
200 REM ! ---                       ---
210 REM ! -----------------------------
220 REM !
230 REM ! -----------------------------
240 REM !
250 REM ! Detta {r ett universelt
260 REM ! fast menyprogram.
270 REM ! Variabeln N% anger hur
280 REM ! m}nga filnamn det finns.
290 REM ! Filnamnen l{ggs i data-
300 REM ! satser. OBS Max 15 st!
310 REM !
320 REM ! Variabeln E$ inneh}ller
330 REM ! Extensionen till progrmmen
340 REM ! T ex ".GAM"
350 REM ! -----------------------------
360 REM 
370 DIM R%(23%)
380 FOR I%=0% TO 23% : R%(I%)=PEEK(884%+I%*2%)+256%*PEEK(885%+I%*2%)
390 NEXT I%
400 ; CHR$(12%)'          **  ABC80 CDS-MENY  **' : ; STRING$(PEEK(734%),61%)
410 N%=15% : REM  Antal program. 
420 E$='.EXT' : REM  EXTENSION  
430 IF N%>15% N%=15% ELSE IF N%<1% N%=1%
440 DIM N$(N%)
450 REM 
460 REM  S{tt upp meny. 
470 REM 
480 FOR I%=1% TO N% : READ N$(I%)
490 ; CUR(6%+I%,15%-LEN(NUM$(I%)))I%' - 'N$(I%) : NEXT I%
500 ; CUR(3%,0%)' "-->" Ned' : ; ' "<--" Upp' : ; ' <RET> O.K' : ; ' <ESC> END';
510 R%=1% : R1%=1% : GOTO 660
520 REM 
530 REM  H{mta meny svar 
540 REM 
550 ; CUR(0%,38%)CHR$(1%,8%); : GET Z$ : IF Z$=CHR$(8%) R%=R%-1%
560 IF Z$=CHR$(27%) ; : END 
570 IF Z$=CHR$(9%) R%=R%+1%
580 IF R%<1% THEN R%=N% ELSE IF R%>N% THEN R%=1%
590 IF Z$=CHR$(13%) THEN 780
600 ; CUR(R%+6%,19%);
610 IF R1%=N% AND R%=R1% 550 ELSE IF R1%=1% AND R%=R1% 550
620 OUT 6%,0% : OUT 6%,131%
630 REM 
640 REM  Sl{ck gamla pekare. 
650 REM 
660 FOR I%=1% TO LEN(N$(R1%))
670 POKE R%(R1%+6%)+I%+17%,ASC(MID$(N$(R1%),I%,1%)) AND 127%
680 NEXT I%
690 REM 
700 REM  T{nd nya pekare. 
710 REM 
720 FOR I%=1% TO LEN(N$(R%))
730 POKE R%(R%+6%)+I%+17%,ASC(MID$(N$(R%),I%,1%)) OR 128%
740 NEXT I% : R1%=R% : GOTO 550
750 REM 
760 REM  Starta program. 
770 REM 
780 ; CUR(23%,5%)'Nu startas: 'N$(R%)CUR(1,1) : CHAIN N$(R%)+E$
790 REM 
800 REM  DATA satser f|r meny. 
810 REM 
820 DATA PROG00,PROG01,PROG02,PROG03
830 DATA PROG04,PROG05,PROG06,PROG07
840 DATA PROG08,PROG09,PROG10,PROG11
850 DATA PROG12,PROG13,SIST
860 DATA