1 REM -----------------------------
2 REM -                           -
3 REM - SCROLL DEMO  VER 1.2      -
4 REM - 1981-03-08                -
5 REM - Programutveklare __       -
6 REM - Ola hedlin , Blomsterv.27 -
7 REM - 736 00 KUNGS\R,0227/11444 -
8 REM -                           -
9 REM -----------------------------
10 REM SAVE SCROLLER
20 ; CHR$(12%) : J7%=1%
30 ; 'P] VILKEN RAD VILL DU B\RJA'
40 ; 'UTSKRIFTEN  ( 0-18 ) '
50 ; : ; : ; 'HUR M]NGA RADER VILL DU'
60 ; 'SCROLLA ( 2-'
70 ONERRORGOTO 70
80 ; CUR(2%,21%)STRING$(50%,32%)CUR(2%,21%); : INPUT A%
90 IF A%<0% OR A%>18% 70
100 ONERRORGOTO 100
110 ; CUR(6%,12%)STRING$(50%,32%)
120 ; CUR(6%,12%)RIGHT$(NUM$(20%-A%)+' ) ',2%); : INPUT B%
130 IF B%<2% OR B%>20%-A% 100
140 ; : ; : ; '\VERSKRIFTEN     RAD: 'A%
150 ; 'UNDERSKRIFTEN    RAD: 'A%+B%+3%
160 ; 'SCROLLAR ANTAL RADER: 'B%
170 ; : ; TAB(10%)'TRYCK P] RETURN'; : POKE 65013%,0% : GET H6$
180 ; CHR$(12%)
190 FOR K%=564% TO 629%
200 IF K%=583% POKE 64256%+(K%-564%),116%+((A%+2%)*2%) : GOTO 230
210 IF K%=586% POKE 64256%+(K%-564%),24%-(24%-B%) : GOTO 230
220 POKE 64256%+(K%-564%),PEEK(K%)
230 NEXT K%
240 ; CUR(A%+B%+3%,0%)'------------ UNDERSKRIFT ------------';
250 ; CUR(A%,0%)'------------ \VERSKRIFT ------------- '
260 REM  NU B\RJAR HUVUDPROG. 
270 GOSUB 340
280 ; CHR$(13%);
290 IF PEEK(65011%)>A%+B%+1% Z%=CALL(64256%) : ; CUR(A%+B%+1%,0%);
300 ; A$
310 GET H6$
320 GOTO 270
330 REM  NU SLUTAR HUVUDPROG. 
340 REM  A$ Best{mmer du 
345 IF J7% GOSUB 1000 : GOTO 360
350 A$=STRING$(39%,33%+R%) : R%=R%+1%
355 IF R%>94% R%=0% : J7%=1% : RESTORE 
357 IF R%=15% OR R%=30% OR R%=45% OR R%=60% OR R%=75% A$='I   D I D   I T   M Y   W A Y'
360 RETURN 
400 DATA 'Tryck p} "RETURN" eller n}got annat.'
410 DATA 'Det h{r {r en demonstration av en'
420 DATA 'SCROLLnings funktion i MASKINSPR]K.'
421 DATA 'Sj{lva funktionen ligger p} raderna :    '
422 DATA ' '
423 DATA '190,200,210,220,230,290 och 300.'
425 DATA ' '
430 DATA 'Du f}r anv{nda den i egna program'
440 DATA 'om du vill!'
450 DATA '  Sj{lv har jag anv{nt den i min'
460 DATA '     D I S   A S S E M B L E R'
470 DATA 'my name is :    '
480 DATA '  '
490 DATA 'Ola hedlin , Blomsterv.27'
500 DATA '736 00 KUNGS\R , Tel 0227/11444'
510 DATA 'I DID IT MY WAY!'
520 DATA '+'
1000 READ A$ : IF A$='+' J7%=0% : A$=''
1010 RETURN