1 REM Ins{nt av 2839
100 REM ! -----------------------------
110 REM ! --- Ett program fr}n CDS. ---
120 REM ! --- ===================== ---
130 REM ! --- ---
140 REM ! --- Program SWAPER__.BAS ---
150 REM ! --- Version 1.4 ---
160 REM ! --- Created 1983-10-10 ---
170 REM ! --- Copyright CDS ---
180 REM ! --- Lars-B|rje Cid ---
190 REM ! --- Utrustning, DISK ---
200 REM ! -----------------------------
210 REM ! --- Programmet spara ut- ---
220 REM ! --- rymme p} disketten ---
230 REM ! --- genom att ta bort ---
240 REM ! --- blanksteg som inte ---
250 REM ! --- {r inom cita-tecken. ---
260 REM ! -----------------------------
270 REM !
280 DIM A$=122%,A0$=120%
290 GOSUB 300 : GOTO 350
300 ; CHR$(12%)TAB(6%)'** ABC80 - ASCII SWAPER **' : ; STRING$(PEEK(734%),61%)
310 RETURN
320 REM
330 REM --
340 REM
350 ; CUR(3%,5%)'Skriv "?" f|r info.'
360 ; CUR(5%,0%)'Ange infil (.BAS): '; : INPUTLINE F1$
370 IF LEFT$(F1$,1%)='?' THEN 720
380 F1$=LEFT$(F1$,LEN(F1$)-2%) : IF F1$='' END
390 IF INSTR(1%,F1$,'.')=0% F1$=F1$+'.BAS' : ; '.BAS';
400 F0$=LEFT$(F1$,INSTR(1%,F1$,'.')-1%)+'.SWP'
410 ; CUR(7%,0%)'Ange utfil ('F0$'): '; : INPUTLINE F2$ : F2$=LEFT$(F2$,LEN(F2$)-2%)
420 IF F2$='' F2$=F0$ : ; F2$; ELSE IF INSTR(1%,F2$,'.')=0% F2$=F2$+'.SWP' : ; '.SWP';
430 ONERRORGOTO 290 : OPEN F1$ ASFILE 1% : PREPARE F2$ ASFILE 2%
440 GOSUB 890
450 REM
460 REM --
470 REM
500 A0$='' : C$=''
510 ONERRORGOTO 670 : INPUTLINE #1A$ : A$=LEFT$(A$,LEN(A$)-2%)+'***'
520 R1%=R1%+1% : R2%=R1%
530 T1%=T1%+LEN(A$)-3%
540 FOR I%=1% TO LEN(A$)-3%
550 Z$=MID$(A$,I%,1%)
560 REM
570 REM --
580 REM
590 IF Z$='"' AND C$=Z$ C$='' : GOTO 630
600 IF Z$="'" AND C$=Z$ C$='' : GOTO 630
610 IF Z$="'" AND C$='' C$=Z$
620 IF Z$='"' AND C$='' C$=Z$
630 IF Z$=' ' AND C$='' B1%=B1%+1% : GOTO 650
640 A0$=A0$+Z$
650 NEXT I% : ; #2%A0$ : T2%=T2%+LEN(A0$)
660 GOSUB 910 : GOTO 500
670 IF ERRCODE<>34% ; CUR(21%,15%)'Err: 'ERRCODECHR$(7%); : END
680 ; CUR(21%,15%)'* Ready *'CUR(20%,0%); : END
690 REM
700 REM ----
710 REM
720 GOSUB 300
730 ; : ; ' INFORMATION f|r SWAPER__.BAS Vers 1.4' : ; CHR$(23%)STRING$(38%,35%)
740 ; : ; : ; ' Detta program avl{gsnar blanksteg'
750 ; ' i programfiler lagrade med "LIST"'
760 ; ' programmen tar d} upp mindre ut-'
770 ; ' rymme p} disketten.'
780 ; : ; ' Programmet tar h{nsyn till om det'
790 ; ' Finns n}gra "'" el '"' i filen och'
800 ; ' tar allts} inte bort n}got inom'
810 ; ' str{nguttryck.'
820 ; : ; ' Filstatus visas under bearbetningen'
830 ; ' f|r infilen och utfilen.'
840 ; : ; : ; ' ' : ; CHR$(1%,8%);
850 GET Z$ : IF Z$<>CHR$(13%) 850 ELSE 290
860 REM
870 REM --
880 REM
890 GOSUB 300 : ; : ; TAB(11%)'SYSTEM STATUS' : ; TAB(10%)CHR$(23%)STRING$(13%,35%)
900 ; CUR(17%,0%)'Infil: 'F1$ : ; : ; 'Utfil: 'F2$
910 ; CUR(7%,18%)'INFIL:'TAB(28%)'UTFIL:'
920 ; : ; : ; 'Antal rader:'TAB(17%)R1%TAB(27%)R2%
930 ; : ; 'Antal tecken:'TAB(17%)T1%TAB(27%)T2%
940 ; : ; 'Antal blanksteg:'TAB(17%)B1%TAB(27%)B2%
950 RETURN