10 REM +++++++++++++++++++++++++++++++++
11 REM ! Program ....   HUVUD
12 REM ! Utg}va  2.02   1981-10-16
13 REM ! av (c) Gunnar Tidner
14 REM ! {ndrat av G|ran Sundqvist
15 REM ! Minne 16 Kbytes f|r flexskiva
16 REM +++++++++++++++++++++++++++++++++
17 REM Ett f|rs|k att bilda en standard
18 REM f|r RUBRIKBLOCK till ABC-klub-
19 REM bens program.
20 REM -------------
21 REM En utfil :   "HEADER.BAS" bildas
22 REM som sedan med MERGE sammanfogas
23 REM med huvudprogrammet innan slut-
24 REM giltig programlagring sker.
25 REM ---------------------------
26 REM Vid "Program .... " kan punkter-
27 REM na utbytas mot ett programnummer
28 REM som tillsammans med utg}venummer
29 REM listas om man anv{nder ett spec.
30 REM LIB fr}n Blackebergs Gymnasium.
31 REM --------------------------------
32 PREPARE "HEADER.BAS" ASFILE 1 : L%=1
33 ; "Programnamn:"; : INPUTLINE P$ : ; : P$=LEFT$(P$,LEN(P$)-2%)
34 IF LEN(P$)>8 ; 'max 8 tecken' : GOTO 33
35 IF LEN(P$)<1 THEN 57
36 ; "Datum:"; : INPUTLINE D$ : ; : D$=LEFT$(D$,LEN(D$)-2%)
37 ; "Version:"; : INPUTLINE V$ : ; : V$=LEFT$(V$,LEN(V$)-2%)
38 ; "Upphovsman:"; : INPUTLINE U$ : ; : U$=LEFT$(U$,LEN(U$)-2%)
39 ; "Copyright om annan {n" : ; "upphovsmannen:"; : INPUTLINE C$ : ; : C$=LEFT$(C$,LEN(C$)-2%)
40 ; "[ndrat av  :"; : INPUTLINE P1$ : ; : P1$=LEFT$(P1$,LEN(P1$)-2%)
41 ; "Krav p} utrustning"
42 ; "Flexskiva:"; : GET F$ : IF INSTR(1%,"jJnN",F$)=0 THEN 42
43 IF (ASC(F$) AND 223%)=74 THEN F$=" f|r flexskiva" ELSE F$=""
44 ; "Minnesbehov i Kbytes:"; : INPUT B
45 ; "Ins{nt av:"; : INPUTLINE I$ : ; : I$=LEFT$(I$,LEN(I$)-2%)
46 ; #L%,"1 REM +++++++++++++++++++++++++++++++++"
47 ; #L%,"2 REM ! Program ....   ";P$
48 D$=" Utg}va  "+V$+SPACE$(7-LEN(V$))+D$
49 ; #L%,"3 REM !";D$
50 IF LEN(C$)=0 THEN U$="(c) "+U$
51 ; #L%,"4 REM ! av ";U$
52 IF LEN(P1$) THEN ; #L%,"5 REM ! {ndrat av "P1$
53 IF LEN(C$) THEN ; #L%,"6 REM ! Copyright ";C$
54 ; #L%,"7 REM ! Minne";B;" Kbytes";F$
55 IF LEN(I$) THEN ; #L%,"8 REM ! Ins{nt av ";I$
56 ; #L%,"9 REM +++++++++++++++++++++++++++++++++"
57 ; "extra kommentar rad"10+I% : INPUTLINE M$ : ; : M$=LEFT$(M$,LEN(M$)-2%)
58 IF LEN(M$) THEN ; #L%,RIGHT$(NUM$(10%+I%),2);" REM ";M$ : I%=I%+1% : GOTO 57
59 CLOSE 1