1 REM Ins{nt av 2839
100 REM +----------------------------+
110 REM +-----....REMERASER....------+
120 REM +----------------------------+
130 REM +--- Ett enkelt program   ---+
140 REM +--- som avl{gsnar REM-   ---+
150 REM +--- rader i ett  prog-   ---+
160 REM +--- ram.                 ---+
170 REM +----------------------------+
180 REM +--- (c) Lars B|rje Cid   ---+
190 REM +----------------------------+
200 REM +--- Duveholm  1983-06-11 ---+
210 REM +----------------------------+
220 REM 
230 REM -- INIT --
240 REM 
250 DIM A$=120%
260 ; CHR$(12%)TAB(12%)"REM-ERASER" : ; TAB(11%)CHR$(23%)STRING$(10%,35%)
270 ; : ; TAB(6%)"Detta program avl{gsnar" : ; TAB(6%)"alla  kommentarer i ett" : ; TAB(6%)"program."
280 ; : ; TAB(6%)"Infilen m}ste vara en" : ; TAB(6%)"TEXT-Fil (.BAS)"
290 ; CUR(11%,5%)STRING$(200%,32%)CUR(11%,5%)"Ange infil (.BAS) "; : INPUT A$
300 REM 
310 REM -- FILNAMN --
320 REM 
330 IF NOT INSTR(1%,A$,".") THEN A$=A$+".BAS"
340 ONERRORGOTO 290 : OPEN A$ ASFILE 1% : A1$=A$
350 ; CUR(13%,5%)"Ange utfil (.BAS) "; : INPUT A$
360 IF NOT INSTR(1%,A$,".") THEN A$=A$+".BAS"
370 ONERRORGOTO 290 : PREPARE A$ ASFILE 2%
380 ; CUR(11%,0%)STRING$(40%*5%,32%)
390 ; CUR(11%,5%)"INFIL: "A1$ : ; : ; TAB(5%)"UTFIL: "A$
400 REM 
410 REM -- MAIN UNIT --
420 REM 
430 ONERRORGOTO 560 : INPUTLINE #1A$ : ; CUR(16%,4%)"RAD NR: "LEFT$(A$,INSTR(1%,A$," "))
440 ; CUR(18%,4%)"Remmar:"\%
450 IF INSTR(1%,A$,"REM")=0% THEN 520
460 A%=INSTR(1%,A$," ") : IF INSTR(1%,A$,"REM")=A%+1% THEN \%=\%+1% : GOTO 430
470 FOR I%=1% TO LEN(A$)-3% : Z1$=MID$(A$,I%,1%)
480 IF MID$(A$,I%,1%)=Z$ THEN E%=0%
490 IF Z1$="'" OR Z1$='"' THEN Z$=Z1$ : E%=-1%
500 IF MID$(A$,I%,3%)="REM" AND NOT E% THEN \%=\%+1% : GOTO 430
510 NEXT I%
520 ; #2A$; : GOTO 430
530 REM 
540 REM -- EOF (1) --
550 REM 
560 IF ERRCODE<>34% THEN ; : ; "FEL:"ERRCODE : CLOSE 1 : CLOSE 2 : STOP ELSE ; CUR(20%,15%)"KLART."; : END