100 ! **********************************************************************
110 ! Program          ECLIP.800        Utg}va  1.0      1984-04-23
120 ! av Torbj|rn Alm
130 ! Ins{nd av Torbj|rn Alm
140 ! F|r ABC800M ABC800C ABC802 ABC806
150 ! Testad p} ABC806
160 ! 
170 ! Screened by --"-TCP-"---
180 ! **********************************************************************
190 ! 
200 ! -----------------------------------------!
210 ! *             ECLIP                     *!
220 ! *             =====                     *!
230 ! *  Lunar Umbral Eclipses                *!
240 ! *  By Eric Burgess F.R.A.S.             *!
250 ! *  From Celestial Basic                 *!
260 ! *  ABC-800 Version Torbj|rn Alm ABC116  *!
270 ! * Programmet ber{knar datum och storlek *!
280 ! * f|r m}nf|rm|rkelser. Programmet fr}gar*!
290 ! * efter start}r, och ber{knar sedan     *!
300 ! * n{sta m}nf|rm|rkelse. Om man trycker  *!
310 ! * p} en tangent ber{knas n{sta m}n-     *!
320 ! * f|rm|rkelse. Storleken {r relativt    *!
330 ! * m}nens storlek, varf|r ett v{rde <1   *!
340 ! * betyder en partiell m}nf|rm|rkelse.   *!
350 ! ----------------------------------------*!
360 FLOAT : DOUBLE : EXTEND : ; CHR$(12) : ; : ; : ; 'This program gives magnitude and date of Lunar Umbral Eclipses'
370 ; 'Starting at any uear requested.'
380 INPUT 'State starting year'Y
390 ; CHR$(12) ' Cogito - ergo sum'
400 Fl=0
410 Z=Y-1900
420 Zd=(Z*12.368267)-2
430 A=INT(Zd)
440 DEF FNRad(X)=X*PI/180 
450 A=A+1
460 B=29.1053561*A
470 C=B+13.7774
480 D=(25.81691806*A)+138.94
490 E=(30.670565*A)+216.6378
500 F=E-(SIN(FNRad(D)))*.412
510 G=F+(SIN(FNRad(2*D)))/8.8
520 H=G+(SIN(FNRad(C)))*2.2265
530 I=H+(SIN(FNRad(2*E)))*.13
540 I=SIN(FNRad(I))
550 J=.7128-(COS(FNRad(D)))/36
560 W=I*10^J
570 IF W<0 W=1.84769+W*1.8216 ELSE IF W>0 W=1.84769-W*1.8216
580 K=W+(COS(FNRad(D)))/30
590 IF K<0 THEN 450
600 IF Fl=0 ; CHR$(12) : ; : ; : ; 
610 ; : ; '------------------------'
620 ; 'Magnitude of eclipse = '; : ; USING '###.####',K : ; 
630 L=2.415036025E+06+(A*29.53058868)
640 L=L-(.406*SIN(FNRad(D)))+(.174*SIN(FNRad(C)))
650 L=L+(SIN(FNRad(2*D)))/62
660 L=INT(L-(SIN(FNRad(2*E)))/97)
670 IF L<2.299161E+06 THEN 730
680 L2=INT((2.299161E+06-1.86721625E+06)/36525.25)
690 L=L+L2
700 M=INT(L2/4)
710 L=L-M
720 L=L+1
730 N=L-1.720995E+06
740 O=INT((N-122.1)/365.25)
750 P=INT(O*365.25)
760 Q=INT((N-P)/30.6001)
770 R=((N-P)-INT(Q*30.6001))/10000
780 IF Q<13.7774 THEN 800
790 S=Q-12-1 : GOTO 810
800 S=Q-1
810 T=S
820 T2=T+R
830 IF SQR(5)<S THEN 850
840 O=O+1
850 U=O+T2
860 R=3+R*10000
870 IF T=2 AND R>28 THEN T=T+1 : R=R-28
880 IF T=3 AND R>31 THEN T=T+1 : R=R-31
890 ; 'Date of eclipse is ' O ',' T ',' R
900 GET A$ : Fl=1 : GOTO 450