10 ! ************************************************************************
20 ! *                                                                      *
30 ! *                         E  B  E  R                                   *
40 ! *                PROGRAM F\R BER[KNING AV ENERGI-                      *
50 ! *                     F\RBRUKNING I SM]HUS                             *
60 ! *                                                                      *
70 ! *                   Version 2.1 Feb 1983                               *
80 ! *                                                                      *
90 ! ************************************************************************
100 ! 
110 ! ........................................................................
120 ! .                                                                      .
130 ! .        Chains program ENORM                                          .
140 ! .                                                                      .
150 ! .        File created 1982-12-13                                       .
160 ! .                                                                      .
170 ! .        Modification history:                                         .
180 ! .  Rev.  Date      Reason                                      Sign.   .
190 ! .  1.1   83-01-18  Revidering av v{rmepumpsformeln.             NR     .
200 ! .                  <ENORM & EBER>                                      .
210 ! .                                                                      .
220 ! .  1.2   83-01-31  Vinterns f|rluster uppdelade i tv}                  .
230 ! .                  kolumner: Trans och vent.                           .
240 ! .                  Fel r{ttat p} rad 2660 (EBER 1.1)                   .
250 ! .                  Phhvvp bytt till Pvvhhp, Pfm-Pvvhhp                 .
260 ! .                  bytt till (Pfm-Pvvhhp).                      NR     .
270 ! .                  <EBER>                                              .
280 ! .                                                                      .
290 ! .  1.3   83-02-09  Stockholm% {ndrat till Sthlm, ort%                  .
300 ! .                  till ort o s v                               SM     .
310 ! .                  <ENORM & EBER>                                      .
320 ! .                                                                      .
330 ! .  2.0   83-02-10  Ny ber{kningsmetod: BKL 1982:3                      .
340 ! .                  Varaktighetsdiagramet f|r soleffekt                 .
350 ! .                  modelleras m h a 3 punkter ist{llet                 .
360 ! .                  f|r 2. Nya villkor f|r m}nadernas                   .
370 ! .                  energibalanser                               SM     .
380 ! .                  <EBER>                                              .
390 ! .                                                                      .
400 ! .  2.1   83-02-10  Ber{kning av dimensionerande radiator-              .
410 ! .                  effekt                                       SM     .
420 ! .                  <EBER & ENORM>                                      .
430 ! ........................................................................
440 ! 
450 EXTEND ! enable long identifiers
460 SINGLE ! single precision ( 7 digits)
470 ! 
480 ! ***************** COMMON AREA *****************************************
490 COMMON True,False
500 COMMON Jan,Feb,Mar,Apr,Maj,Jun,Jul,Aug,Sep,Okt,Nov,Dec
510 COMMON Sthlm.,Malm|.,Ume}.
520 COMMON Golv.,Vagg.,Fonster.,Dorr.,Ovrig.,Tak.
530 COMMON Husnamn$=100.,Ort.,Ti.
540 COMMON Ba.(10.),Redfakt.,Bosta.,Bygga.,K.(6.)
550 COMMON Venttyp$=20.,Inf.,Min.,Full.,T1.,T2.,T3.,Eta.,Vol.,Ventvol.,Flakt.
560 COMMON S.,Beta.,A.(10.),Riktning.(10.),Lutning.(10.)
570 COMMON Person.,Hush.,Hushp.,Vv.,Vvp.
580 COMMON Sbn75.,Sbn82.
590 COMMON Dred.,Plvk.,Plvks.,Pumptyp.,Pumpspar.
600 COMMON Vkf.
610 COMMON Allread.
620 COMMON Choice.
630 ! 
640 ! ******************** DIMENSIONS *************************************
650 DIM Aa.(12.),B.(12.),C.(12.),P.(12.),Db.(12.) ! Remove
660 DIM Tu.(12.,3.)
670 DIM Dag.(12.),D1.(12.),D2.(12.)
680 DIM Alfar.(8.,12.)
690 DIM Idh0.(12.),Irh0.(12.),Idh1.(12.),Irh1.(12.),Idh2.(12.)
700 DIM Ps0.(12.),Ps1.(12.),Ps2.(12.)
710 DIM Du.(12.),Wu.(12.),Wsolgo.(12.),Wvvhhgo.(12.),Wpersongo.(12.),Wvvhhpgo.(12.)
720 DIM Wsolgovi.(12.)
730 DIM Wkopt.(12.)
740 DIM Wsoltill.(12.)
750 DIM Monname$(12.)=3.
760 DIM Wforl.(12.),Wforlvit.(12.),Wforlviv.(12.)
770 ! 
780 ! ********************** INITIATE "CONSTANTS" *************************
790 True=-1 : False=0
800 Jan=1 : Feb=2 : Mar=3 : Apr=4 : Maj=5 : Jun=6
810 Jul=7 : Aug=8 : Sep=9 : Okt=10 : Nov=11 : Dec=12
820 Tak.=1. : Vagg.=2. : Golv.=3. : Fonster.=4. : Dorr.=5. : Ovrig.=6.
830 Sbn75.=1. : Sbn82.=2.
840 Malm|.=1. : Sthlm.=2. : Ume}.=3.
850 Notzero.=17. ! Anything <> 0
860 ! 
870 ! ******************* INITIATE MATRIX *********************************
880 RESTORE 
890 DATA 31,28.25,31,30,31,30,31,31,30,31,30,31
900 FOR Mon=Jan TO Dec
910   READ Dag.(Mon)
920 NEXT Mon 
930 DATA 21,23,23,26,31,30,30,30,26,28,24,26
940 FOR Mon=Jan TO Dec
950   READ D1.(Mon)
960 NEXT Mon 
970 ! 
980 DATA 26,28,31,30,31,30,31,31,30,31,30,31
990 FOR Mon=Jan TO Dec
1000   READ D2.(Mon)
1010 NEXT Mon 
1020 ! 
1030 DATA -.5,-.7,1.4,6,11,15,17.2,16.7,13.5,8.9,4.9,2
1040 DATA -2.9,-3.1,-.7,4.4,10.1,14.9,17.8,16.6,12.2,7.1,2.8,.1
1050 DATA -7.8,-7.7,-4.4,1.3,7.5,12.7,16.3,14.6,9.5,3.5,-.9,-4.3
1060 FOR O.=Malm|. TO Ume}.
1070   FOR Mon=Jan TO Dec
1080     READ Tu.(Mon,O.)
1090   NEXT Mon 
1100 NEXT O. 
1110 ! 
1120 DATA .225,.626,.976,1.688,1.345,1.613,1.312,1.456,1.340,.651,.339,.173
1130 FOR Mon=Jan TO Dec
1140   READ Idh0.(Mon)
1150 NEXT Mon 
1160 ! 
1170 DATA .608,.893,2.457,4.595,6.940,7.316,7.120,5.541,3.143,1.764,.829,.333
1180 FOR Mon=Jan TO Dec
1190   READ Irh0.(Mon)
1200 NEXT Mon 
1210 ! 
1220 DATA .160,.306,.956,1.332,2.469,2.815,2.697,1.757,1.057,.524,.240,.092
1230 FOR Mon=Jan TO Dec
1240   READ Idh1.(Mon)
1250 NEXT Mon 
1260 ! 
1270 DATA 0,0,0,0,.251,0,0,0,0,0,0,0
1280 FOR Mon=Jan TO Dec
1290   READ Irh1.(Mon)
1300 NEXT Mon 
1310 ! 
1320 DATA 0,.042,.094,.570,0,0,2.505,1.582,.530,.332,.008,.012
1330 FOR Mon=Jan TO Dec
1340   READ Idh2.(Mon)
1350 NEXT Mon 
1360 ! 
1370 DATA .079,.079,.079,.086,.133,.179,.161,.103,.079,.079,.079,.079 
1380 ! N
1390 DATA .079,.089,.160,.242,.288,.313,.305,.264,.195,.116,.080,.079 
1400 ! NO
1410 DATA .721,.651,.598,.536,.483,.461,.469,.503,.554,.626,.703,.711 
1420 ! O
1430 DATA 3.580,1.824,1.111,.720,.514,.429,.458,.605,.887,1.423,2.683,4.537
1440 ! SO
1450 DATA 5.346,2.617,1.374,.716,.445,.347,.379,.560,.999,1.934,3.978,6.771 
1460 ! S
1470 DATA 3.580,1.824,1.111,.720,.514,.429,.458,.605,.887,1.423,2.683,4.537 
1480 ! SV
1490 DATA .721,.651,.598,.536,.483,.461,.469,.503,.554,.626,.703,.711 
1500 ! V
1510 DATA .079,.089,.160,.242,.288,.313,.305,.264,.195,.116,.080,.079 
1520 ! NV
1530 FOR Rikt=1. TO 8.
1540   FOR Mon=Jan TO Dec
1550     READ Alfar.(Rikt,Mon)
1560   NEXT Mon 
1570 NEXT Rikt 
1580 ! 
1590 DATA 'Jan','Feb','Mar','Apr','Maj','Jun','Jul','Aug','Sep','Okt','Nov','Dec'
1600 FOR Mon=Jan TO Dec
1610   READ Monname$(Mon)
1620 NEXT Mon 
1630 ! 
1640 DATA ' N','NO',' O','SO',' S','SV',' V','NV'
1650 FOR Rikt.=1. TO 8.
1660   READ Vstreck$(Rikt.)
1670 NEXT Rikt. 
1680 ! 
1690 DATA 'Tak     ','V{gg    ','Golv    ','F|nster ','D|rr    ','\vrigt  '
1700 FOR Byggdel.=Tak. TO Ovrig.
1710   READ Bdel$(Byggdel.)
1720 NEXT Byggdel. 
1730 ! 
1740 DATA 'Malm|','Stockholm','Ume}'
1750 FOR O.=Malm|. TO Ume}.
1760   READ Ort$(O.)
1770 NEXT O. 
1780 ! 
1790 Eut.(1.,Malm|.)=-18.5 : Eut.(1.,Sthlm.)=-20.4 : Eut.(1.,Ume}.)=-26.2
1800 Eut.(2.,Malm|.)=-15.1 : Eut.(2.,Sthlm.)=-18.4 : Eut.(2.,Ume}.)=-24.5
1810 Eut.(3.,Malm|.)=-12.6 : Eut.(3.,Sthlm.)=-16.3 : Eut.(3.,Ume}.)=-23.5
1820 ! 
1830 ! ***************** Main program *********************************
1840 ! ................. Main loop ......................................
1850 ON ERROR GOTO 5590
1860 ON Choice. GOSUB 1890,1960,2030
1870 CHAIN "enorm"
1880 ! 
1890 ! ..................... Indata + resultat -> Printer .................
1900 OPEN "pr:" AS FILE 1.
1910 GOSUB 2070 ! Ber{kning
1920 GOSUB 3620 ! utskrift
1930 CLOSE 1.
1940 RETURN 
1950 ! 
1960 ! ............ Indata + resultat -> bildsk{rm .........................
1970 OPEN "con:" AS FILE 1.
1980 GOSUB 2070 ! Ber{kning
1990 GOSUB 3620 ! Utskrift
2000 CLOSE 1.
2010 RETURN 
2020 ! 
2030 ! .................... Indata + resultat -> diskett ....................
2040 ; "Denna funktion finns ej {nnu!"
2050 RETURN 
2060 ! 
2070 ! ****************** BER[KNING ****************************************
2080 ! ................ Nollst{llning av variabler ........................
2090 ! 
2100 ! 
2110 ! +++++++++++++++++++++ Ber{kningar g{llande hela }ret +++++++++++++++
2120 Fonsterproc.=Ba.(Fonster.)/Bygga.*100.
2130 Vaggtf.=Ba.(Vagg.)*K.(Vagg.)
2140 Fonstertf.=Ba.(Fonster.)*K.(Fonster.)
2150 Golvtf.=Ba.(Golv.)*K.(Golv.)*Redfakt.
2160 Taktf.=Ba.(Tak.)*K.(Tak.)
2170 Dorrtf.=Ba.(Dorr.)*K.(Dorr.)
2180 Ovrigtf.=Ba.(Ovrig.)*K.(Ovrig.)
2190 Tf.=Vaggtf.+Fonstertf.+Golvtf.+Taktf.+Dorrtf.+Ovrigtf.
2200 Vtinf.=Inf.*Ventvol.
2210 Vtvent.=(T2.*Min.+T3.*Full.)/24.*(1.-Eta./100.)*Ventvol.
2220 Vfinf.=.33*Vtinf.
2230 Vfvent.=.33*Vtvent.
2240 Vf.=Vfinf.+Vfvent.
2250 Pvvhh.=(Hush.*Hushp./100.+Vv.*Vvp./100.)/365.25 ! *** kWh/dygn ***
2260 Pperson.=Person./365.25 ! *** kWh/dygn ***
2270 Pvvhhp.=Pvvhh.+Pperson.
2280 ! +++++++++++++++++ Ps0, Ps1, Ps2 ber{kningar ++++++++++++++++++++++++++++
2290 FOR Mon=Jan TO Dec
2300   J=1.
2310   Alfadtot.=0. : Alfartot.=0.
2320   WHILE A.(J)<>0.
2330     Alfadtot.=Alfadtot.+FNAlfad.(Lutning.(J))*A.(J)
2340     Alfartot.=Alfartot.+Alfar.(Riktning.(J),Mon)*A.(J)
2350     Deltadsum.=Deltadsum.+Deltad.(J)
2360     J=J+1.
2370   WEND 
2380   Ps0.(Mon)=S.*Beta.*(Alfadtot.*Idh0.(Mon)+Alfartot.*Irh0.(Mon)) ! kWh/dygn !!!
2390   Ps1.(Mon)=S.*Beta.*(Alfadtot.*Idh1.(Mon)+Alfartot.*Irh1.(Mon)) ! kWh/dygn !!!
2400   Ps2.(Mon)=S.*Beta.*Alfadtot.*Idh2.(Mon) ! kWh/dygn !!!!
2410 NEXT Mon 
2420 ! +++++++++++++++++ M}nadernas energibalans ++++++++++++++++++++++++
2430 ! ................. Nollst{llning av variabler .......................
2440 FOR Byggdel.=Tak. TO Ovrig.
2450   W.(Byggdel.)=0.
2460 NEXT Byggdel. 
2470 Wvent.=0. : Winf.=0.
2480 Wforl}r.=0. : Wforlvi}r.=0. : Wforlviv}r.=0.
2490 Dutot.=0.
2500 Wutot.=0.
2510 Wgo}r.=0.
2520 Wpersongo}r.=0.
2530 Wvvhhgo}r.=0.
2540 Wsolgo}r.=0.
2550 Wsolgovi}r.=0.
2560 Du}r.=0.
2570 Wu}r.=0.
2580 Wkopt}r.=0.
2590 Wsoltill}r.=0.
2600 Wgrattot.=0.
2610 Qvi.=0.
2620 ! ............. M}nads loop ...................................
2630 FOR Mon=Jan TO Dec
2640   A.=FNMax3.(Ps0.(Mon),Ps1.(Mon),Ps2.(Mon))
2650   B.=FNMed3.(Ps0.(Mon),Ps1.(Mon),Ps2.(Mon))
2660   C.=FNMin3.(Ps0.(Mon),Ps1.(Mon),Ps2.(Mon))
2670   IF B.=Ps1.(Mon) THEN Db.=D1.(Mon)
2680   IF B.=Ps0.(Mon) THEN Db.=(D1.(Mon)*(B.-C.)+D2.(Mon)*(A.-B.))/(A.-C.)
2690   IF B.=Ps2.(Mon) THEN Db.=D2.(Mon)-D1.(Mon)*(B.-C.)/(A.-C.)
2700   Wsoltill.(Mon)=(A.+B.)*Db./2.+(B.+C.)*(D2.(Mon)-Db.)/2. ! kWh/m}n
2710   Wtm.=Tf.*FNQ.(Mon,Ort.)/1000. ! kWh/m}n
2720   Wvm.=Vf.*FNQ.(Mon,Ort.)/1000. ! -"-
2730   Wfm.=Wtm.+Wvm.
2740   Pfm.=Wfm./Dag.(Mon) ! kWh/dygn
2750   Prest.=FNMax.(Pfm.-Pvvhhp.,0.)
2760   IF Prest.=0. THEN GOSUB 3210
2770   IF (Prest.<>0.) AND (Prest.<=C.) THEN GOSUB 3290
2780   IF (Prest.<>0.) AND (C.<Prest.) AND (Prest.<B.) THEN GOSUB 3370
2790   IF (Prest.<>0.) AND (B.<=Prest.) AND (Prest.<A.) THEN GOSUB 3450
2800   IF (Prest.<>0.) AND (A.<=Prest.) THEN GOSUB 3530
2810   Aa.(Mon)=A. : B.(Mon)=B. : C.(Mon)=C. : P.(Mon)=Prest. : Db.(Mon)=Db.
2820   Wvvhhgo.(Mon)=Wvvhhpgo.(Mon)*Pvvhh./Pvvhhp.
2830   Wpersongo.(Mon)=Wvvhhpgo.(Mon)*Pperson./Pvvhhp.
2840   Wkopt.(Mon)=Wu.(Mon)+(Hush.+Vv.+Flakt.)/365.25*Dag.(Mon)
2850   Wforl.(Mon)=Wfm.
2860   Wforlvit.(Mon)=Wtm.*Du.(Mon)/Dag.(Mon)
2870   Wforlviv.(Mon)=Wvm.*Du.(Mon)/Dag.(Mon)
2880   ! ............. ]rsackumulatorer ..................................
2890   Wgo}r.=Wgo}r.+Wvvhhpgo.(Mon)+Wsolgo.(Mon)
2900   Wpersongo}r.=Wpersongo}r.+Wpersongo.(Mon)
2910   Wvvhhgo}r.=Wvvhhgo}r.+Wvvhhgo.(Mon)
2920   Wsolgo}r.=Wsolgo}r.+Wsolgo.(Mon)
2930   Wsolgovi}r.=Wsolgovi}r.+Wsolgovi.(Mon)
2940   Wsoltill}r.=Wsoltill}r.+Wsoltill.(Mon)
2950   Du}r.=Du}r.+Du.(Mon)
2960   Wu}r.=Wu}r.+Wu.(Mon)
2970   Wkopt}r.=Wkopt}r.+Wkopt.(Mon)
2980   Wforl}r.=Wforl}r.+Wforl.(Mon)
2990   Wforlvit}r.=Wforlvit}r.+Wforlvit.(Mon)
3000   Wforlviv}r.=Wforlviv}r.+Wforlviv.(Mon)
3010   Qdel.=FNQ.(Mon,Ort.)/1000.*(Du.(Mon)/Dag.(Mon))
3020   Q}r.=Q}r.+FNQ.(Mon,Ort.)
3030   Qvi.=Qvi.+Qdel.*1000.
3040   W.(Tak.)=W.(Tak.)+Taktf.*Qdel.
3050   W.(Golv.)=W.(Golv.)+Golvtf.*Qdel.
3060   W.(Fonster.)=W.(Fonster.)+Fonstertf.*Qdel.
3070   W.(Vagg.)=W.(Vagg.)+Vaggtf.*Qdel.
3080   W.(Dorr.)=W.(Dorr.)+Dorrtf.*Qdel.
3090   W.(Ovrigt.)=W.(Ovrigt.)+Ovrigtf.*Qdel.
3100   Wvent.=Wvent.+Vfvent.*Qdel.
3110   Winf.=Winf.+Vfinf.*Qdel.
3120 NEXT Mon 
3130 ! .............. Avslutande ber{kningar ..................................
3140 Kekv.=1000.*(W.(Fonster.)-Wsolgovi}r.)/(Ba.(Fonster.)*Qvi.)
3150 IF Pumptyp.=2. THEN Pumpspar.=SQR(Bosta.)*(Du}r.-Dred.)*Plvk.+SQR(Bosta.)*(365.-Du}r.+Dred.)*Plvks.+Flakt.
3160 Prad.=(Tf.+Vf.)*(Ti.-FNDut.(Vkf.))/1000.-Pvvhhp./24.
3170 ! Error handler entry
3180 RETURN ! To main
3190 ! 
3200 ! .............. Subrutiner f|r m}nadernas energibalans .............
3210 ! Prest=0
3220 Du.(Mon)=0.
3230 Wu.(Mon)=0.
3240 Wsolgo.(Mon)=0.
3250 Wsolgovi.(Mon)=0.
3260 Wvvhhpgo.(Mon)=Pfm.*Dag.(Mon)
3270 RETURN 
3280 ! 
3290 ! Prest <= C
3300 Wu.(Mon)=Prest.*(Dag.(Mon)-D2.(Mon))
3310 Du.(Mon)=Dag.(Mon)-D2.(Mon)
3320 Wsolgo.(Mon)=Prest.*D2.(Mon)
3330 Wsolgovi.(Mon)=0.
3340 Wvvhhpgo.(Mon)=Pvvhhp.*Dag.(Mon)
3350 RETURN 
3360 ! 
3370 ! C < Prest < B
3380 Wu.(Mon)=Prest.*(Dag.(Mon)-D2.(Mon))+(Prest.-C.)^2.*(D2.(Mon)-Db.)*.5/(B.-C.)
3390 Du.(Mon)=Dag.(Mon)-D2.(Mon)+(Prest.-C.)*(D2.(Mon)-Db.)/(B.-C.)
3400 Wsolgo.(Mon)=Prest.*Dag.(Mon)-Wu.(Mon)
3410 Wsolgovi.(Mon)=Prest.*Dag.(Mon)-Prest.*(Dag.(Mon)-Du.(Mon))-Wu.(Mon)
3420 Wvvhhpgo.(Mon)=Pvvhhp.*Dag.(Mon)
3430 RETURN 
3440 ! 
3450 ! B <= Prest < A
3460 Wu.(Mon)=Prest.*Dag.(Mon)-Wsoltill.(Mon)+((A.-Prest.)^2.*Db.*.5/(A.-B.))
3470 Du.(Mon)=Dag.(Mon)-(A.-Prest.)*Db./(A.-B.)
3480 Wsolgo.(Mon)=Prest.*Dag.(Mon)-Wu.(Mon)
3490 Wsolgovi.(Mon)=Prest.*Dag.(Mon)-(Dag.(Mon)-Du.(Mon))*Prest.-Wu.(Mon)
3500 Wvvhhpgo.(Mon)=Pvvhhp.*Dag.(Mon)
3510 RETURN 
3520 ! 
3530 ! A <= Prest
3540 Wu.(Mon)=Prest.*Dag.(Mon)-Wsoltill.(Mon)
3550 Du.(Mon)=Dag.(Mon)
3560 Wsolgo.(Mon)=Wsoltill.(Mon)
3570 Wsolgovi.(Mon)=Wsoltill.(Mon)
3580 Wvvhhpgo.(Mon)=Pvvhhp.*Dag.(Mon)
3590 RETURN ! 
3600 ! 
3610 ! 
3620 ! ***************** Utskrift ****************************************
3630 ! ++++++++++++++++++++ Indata +++++++++++++++++++++++++++++++++++++++++++
3635 ; #1. CHR$(15.) CHR$(27.,81.,150.)
3640 ; #1. "     Energiber{kning enligt ENORM",TIME$
3650 ; #1.
3660 ; #1. "     A N V [ N D A   I N D A T A"
3670 ; #1. "     ==========================="
3680 ; #1.
3690 ; #1. "     Objekt: ";Husnamn$
3700 ; #1. "     Ort: ";Ort$(Ort.)
3710 ; #1.
3720 ; #1. "     ALLM[NT"
3730 ; #1.
3740 ; #1. "     Prim{r bruksarea:           ";FNP$(Bosta.,3.1);" (m2)"
3750 ; #1. "     Byggnadsarea:               ";FNP$(Bygga.,3.1);" (m2)"
3760 ; #1. "     F|nsterprocent (enl SBN):    ";FNP$(Fonsterproc.,2.1);" (%)"
3770 ; #1. "     Husvolym:                   ";FNP$(Vol.,3.);"   (m3)"
3780 ; #1. "     Ventilerad volym:           ";FNP$(Ventvol.,3.);"   (m3)"
3790 ; #1. "     V{rmekapacitet:             ";FNP$(Vkf.,3.);"   (Wh/gr c, m2)"
3800 ; #1.
3810 ; #1. "     BRUKARBEROENDE DATA"
3820 ; #1.
3830 ; #1. "     Inomhustemperatur:           ";FNP$(Ti.,2.1);" (gr c)"
3840 ; #1. "     Hush}llsel:              ";FNP$(Hush.,6.);"   (kWh/}r)";
3850 ; #1. " varav ";FNP$(Hushp.,3.);" % tillg f uppv."
3860 ; #1. "     Varmvatten:              ";FNP$(Vv.,6.);"   (kWh/}r)";
3870 ; #1. " varav ";FNP$(Vvp.,3.);' %    - " -'
3880 ; #1. "     Personv{rme:             ";FNP$(Person.,6.);'   (kWh/}r) varav 100 %    - " -'
3890 ; #1. "     Fl{ktf|rluster:          ";FNP$(Flakt.,6.);'   (kWh/}r) varav   0 %    - " -'
3900 ; FNRead$(Choice.=2.)
3910 ! 
3920 ! 
3930 ; #1.
3940 ; #1. "     VENTILATONSDATA"
3950 ; #1.
3960 ; #1. "     Driftsfall   Drifttid     Luftoms.     V{rme}terv.    L{ckage"
3970 ; #1. "                  (timmar)     (ggr/tim)        (%)        (ggr/tim)"
3980 ; #1. "     Fl{kt avst.     ";FNP$(T1.,2.1);"           -";"              -          ";FNP$(Inf.,.2)
3990 ; #1. "     Fl{kt basv.     ";FNP$(T2.,2.1);"          ";FNP$(Min.,.2);"          ";FNP$(Eta.,3.);"          ";FNP$(Inf.,.2)
4000 ; #1. "     Fl{kt fullv.    ";FNP$(T3.,2.1);"          ";FNP$(Full.,.2);"          ";FNP$(Eta.,3.);"          ";FNP$(Inf.,.2)
4010 ; #1. "     ";Venttyp$;"ventilation"
4020 ; FNRead$(Choice.=2.)
4030 ; #1.
4040 ; #1. "     F\NSTERDATA"
4050 ; #1.
4060 ; #1. "     Glasparti  Orientering  Glasarea  Solfaktor  Skuggningsf.  Lutning"
4070 J.=1.
4080 WHILE A.(J.)<>0.
4090   ; #1. "        ";FNP$(J.,2.);"         ";Vstreck$(Riktning.(J.));"         " FNP$(A.(J.),2.1);
4100   ; #1. "         ";FNP$(S.,1.2);"        ";FNP$(Beta.,.2);"        ";FNP$(Lutning.(J.),2.)
4110   J.=J.+1.
4120 WEND 
4130 ; FNRead$(Choice.=2.)
4140 ; #1.
4150 ; #1. "     TRANSMISSIONSDATA"
4160 ; #1.
4170 ; #1. "     Byggdel   Area   K-v{rde    KA-v{rde   Ev. Red.faktor"
4180 FOR Byggdel.=Tak. TO Ovrig.
4190   IF Ba.(Byggdel.)<>0. THEN ; #1. "     ";Bdel$(Byggdel.);" ";FNP$(Ba.(Byggdel.),3.1);"     ";
4200   IF Ba.(Byggdel.)<>0. THEN ; #1. FNP$(K.(Byggdel.),1.2);"      ";
4210   IF Ba.(Byggdel.)<>0. THEN ; #1. FNP$(K.(Byggdel.)*Ba.(Byggdel.),2.1);"        ";
4220   IF Ba.(Byggdel.)<>0. THEN IF Byggdel.=Golv. ; #1. FNP$(Redfakt.,1.2);
4230   IF Ba.(Byggdel.)<>0. THEN ; #1.
4240 NEXT Byggdel. 
4250 ; #1. "     _____________________________________________"
4260 ; #1. "     Summa KA-v{rde:             ";FNP$(Tf.,3.1)
4270 IF Pumptyp.=1. THEN ; #1. : ; #1. "     V{rmepump f|r v{rmning av tappvatten, besparing: ";FNP$(Pumpspar.,5.);" (kWh/}r)"
4280 ; FNRead$(Choice.=2.)
4290 IF Pumptyp.<>2. THEN GOTO 4360
4300 ; #1.
4310 ; #1. "     V{rmepump f|r v{rmning av tappvatten och rumsluft"
4320 ; #1. "     Vinters{songsred:             ";FNP$(Dred.,5.);" (dygn)"
4330 ; #1. "     Planverkskonstant, vinter:    ";FNP$(Plvk.,1.3)
4340 ; #1. "     Planverkskonstant, sommar:    ";FNP$(Plvks.,1.3)
4350 ; FNRead$(Choice.=2.)
4360 ; #1. CHR$(12.)
4370 ! ++++++++++++++++ Utskrift av utdata ++++++++++++++++++++++++++++
4380 ; #1. "     Energiber{kning enligt ENORM ver 2.1",TIME$
4390 ; #1.
4400 ; #1. "     B E R [ K N A D E  U T D A T A"
4410 ; #1. "     =============================="
4420 ; #1.
4430 ; #1. "     Objekt: ";Husnamn$
4440 ; #1. "     Ort: ";Ort$(Ort.)
4450 ; FNRead$(Choice.=2.)
4460 ; #1.
4470 ; #1. "     M]NADERNAS ENERGIBALANSER (kWh)"
4480 ; #1.
4490 ; #1. "     M}n   Uppv.     F|rluster        Utnyttj. gratis-   Till-     Energi"
4500 ; #1. "           dag.   hel}r    vinter     energi, hel}r      g{ngl.  rad   k|pt"
4510 ; #1. "                        trans  vent   HH+VV  pers  sol   sol "
4520 FOR Mon=Jan TO Dec
4530   ; #1. "     ";Monname$(Mon);"   ";FNP$(Du.(Mon),2.1);" ";FNP$(Wforl.(Mon),6.);" ";
4540   ; #1. FNP$(Wforlvit.(Mon),6.);"";FNP$(Wforlviv.(Mon),6.);
4550   ; #1. " " FNP$(Wvvhhgo.(Mon),6.);
4560   ; #1. "";FNP$(Wpersongo.(Mon),6.);
4570   ; #1. "";FNP$(Wsolgo.(Mon),6.);
4580   ; #1. " ";FNP$(Wsoltill.(Mon),6.);
4590   ; #1. " ";FNP$(Wu.(Mon),6.);
4600   ; #1. " ";FNP$(Wkopt.(Mon),6.);
4610   ; #1.
4620 NEXT Mon 
4630 ; #1. "     ______________________________________________________________________"
4640 ; #1. "     Tot  ";FNP$(Du}r.,3.1);" ";FNP$(Wforl}r.,6.);" ";FNP$(Wforlvit}r.,6.);"";FNP$(Wforlviv}r.,6.);" ";
4650 ; #1. FNP$(Wvvhhgo}r.,6.);"";FNP$(Wpersongo}r.,6.);"";FNP$(Wsolgo}r.,6.);" ";
4660 ; #1. FNP$(Wsoltill}r.,6.);" ";FNP$(Wu}r.,6.);" ";FNP$(Wkopt}r.,6.)
4670 IF Pumptyp.<>0. THEN ; #1. SPACE$(42.);"Besparing p g a v{rmepump: ";FNP$(Pumpspar.,6.)
4680 IF Pumptyp.<>0. THEN ; #1. SPACE$(38.);"Slutligt behov av k|pt energi: ";FNP$(Wkopt}r.-Pumpspar.,6.)
4690 ; #1. SPACE$(70.);"====="
4700 ; FNRead$(Choice.=2.)
4710 ; #1.
4720 ; #1. "     VINTERNS F\RLUSTER (kWh)"
4730 ; #1.
4740 ; #1. "     Tak";FNP$(W.(Tak.),5.);"  V{gg";FNP$(W.(Vagg.),5.);"  Golv";FNP$(W.(Golv.),5.);
4750 ; #1. "  F|nster";FNP$(W.(Fonster.),5.);"  D|rr";FNP$(W.(Dorr.),5.);"  \vr";FNP$(W.(Ovrigt.),5.)
4760 ; #1. "     Styrd ventilation";FNP$(Wvent.,5.);"  L{ckage";FNP$(Winf.,5.)
4770 ; #1.
4780 ; #1.
4790 ; #1. "     \VRIGT"
4800 ; #1.
4810 ; #1. "     Gradtimmar under vintern: ";
4820 ; #1. USING "######,";Qvi.;
4830 ; #1. "     Gradtimmar hela }ret: ";
4840 ; #1. USING "######,";Q}r.
4850 ; #1.
4860 ; #1. "     Ekvivalent k-v{rde f|r f|nster: ";FNP$(Kekv.,1.2);" (W/m2 gr c)"
4870 ; #1.
4880 ; #1. "     Vinterns tillgodogjorda solenergi: ";FNP$(Wsolgovi}r.,5.);" (kWh)"
4890 ; #1.
4900 ; #1. "     Transmissionsfaktor (T):";FNP$(Tf.,3.1);"     Ventilationsfaktor (V):";FNP$(Vf.,3.1)
4910 ; #1. "     F|rlustfaktor (F):      ";FNP$(Tf.+Vf.,3.1);"     Ekv f|rlustfaktor (Fe):";FNP$(Tf.+Vf.-(Ba.(Fonster.)*(K.(Fonster.)-Kekv.)),3.1)
4920 ; #1.
4930 ; #1. "     Dimensionerande radiatoreffekt:  ";FNP$(Prad.,2.1);"   (kW)"
4940 ; FNRead$(Choice.=2.)
4950 ; #1. CHR$(12.)
4960 RETURN ! 
4970 ! 
4980 ! ****************** USER FUNCTIONS *************************************
4990 DEF FNP$(X.,Intfrac.) LOCAL X.,Intfrac.,A$=12
5000   ! M{rklig funktion! Returnerar tomma str{ngen men har
5010   ! sidoeffekten att x skrivs ut med USING-sats
5020   A$="######,.###"
5030   IF Intfrac.=1.2 THEN A$="#.##"
5040   IF Intfrac.=1.3 THEN A$="#.###"
5050   IF Intfrac.=2.1 THEN A$="##.#"
5060   IF Intfrac.=2. THEN A$="##"
5070   IF Intfrac.=3. THEN A$="###"
5080   IF Intfrac.=3.1 THEN A$="###.#"
5090   IF Intfrac.=5. THEN A$="#####"
5100   IF Intfrac.=6. THEN A$="######"
5110   IF Intfrac.=.2 THEN A$="_0.##"
5120   PRINT #1. USING A$;X.;
5130   RETURN ""
5140 FNEND ! P$
5150 ! 
5160 DEF FNRead$(Cond.) LOCAL Cond.,Ok$=80
5170   IF Cond. THEN INPUT "Tryck p} <RETURN> n{r du l{st klart!";Ok$
5180   RETURN CHR$(12.)
5190 FNEND ! read
5200 ! 
5210 DEF FNAlfad.(Lutning.)=.396 ! Oberoende av lutning
5220 ! 
5230 DEF FNMax.(X.,Y.) LOCAL X.,Y.
5240   IF X.>Y. THEN RETURN X. ELSE RETURN Y.
5250 FNEND ! Max
5260 ! 
5270 DEF FNMin.(X.,Y.) LOCAL X.,Y.
5280   IF X.<Y. THEN RETURN X. ELSE RETURN Y.
5290 FNEND ! Min
5300 ! 
5310 DEF FNQ.(Mon,Ort.) LOCAL Mon,Ort.
5320   RETURN FNMax.(24.*Dag.(Mon)*(Ti.-Tu.(Mon,Ort.)),0.)
5330 FNEND ! FNQ
5340 ! 
5350 DEF FNR.(Vkf.)=Vkf.*Bosta./(Vf.+Tf.) 
5360 ! 
5370 DEF FNEut.(Vkf.) LOCAL Vkf.,R.
5380   R.=FNR.(Vkf.)
5390   IF R.<=100. THEN RETURN Eut.(1.,Ort.)
5400   IF (100.<R.) AND (R.<=200.) THEN RETURN Eut.(2.,Ort.)
5410   IF 200.<R. THEN RETURN Eut.(3.,Ort.)
5420 FNEND ! FNeut
5430 ! 
5440 DEF FNT.(Vkf.) LOCAL Vkf.,R.
5450   R.=FNR.(Vkf.)
5460   IF R.<=100. THEN RETURN 72.
5470   IF (100.<R.) AND (R.<=200.) THEN RETURN 144.
5480   IF 200.<R. THEN RETURN 216.
5490 FNEND ! FNT
5500 ! 
5510 DEF FNDut.(Vkf.)=FNEut.(Vkf.)+3./(1.-EXP(-FNT.(Vkf.)/FNR.(Vkf.))) 
5520 ! 
5530 DEF FNMax3.(X.,Y.,Z.)=FNMax.(X.,FNMax.(Y.,Z.)) 
5540 ! 
5550 DEF FNMin3.(X.,Y.,Z.)=FNMin.(X.,FNMin.(Y.,Z.)) 
5560 ! 
5570 DEF FNMed3.(X.,Y.,Z.)=FNMin3.(FNMax.(X.,Y.),FNMax.(X.,Z.),FNMax.(Y.,Z.)) 
5580 ! 
5590 ! *************** ERROR HANDLER **************************************
5600 ; "Fel i ber{kningsdelen. Errcode= ";ERRCODE
5610 ; CHR$(7.)
5620 FOR Slask.=1. TO 10000. : NEXT Slask. 
5630 RESUME 3170