1 ! KALENDER.800 
2 ! efter ABC80-prog. 'KALENDER.UTL' av (c) Lars-Owe Gradin
6 ! F|r printer MX-80 F/T
10 ! Ger kalender f|r }ren 1600-2300 i utskrift.
11 REM F|r printer MX-80 F/T
12 REM 
13 REM Programmet modifierat av Bertil M}rtensson Lund <3562>
14 REM f|r ABC800-serien 80 tecken. Variabeln C har f|rhindrats ge det fel-
15 REM alstrande v{rdet 0 genom f|r{ndring av raderna
16 REM 115 (6), 155 (7), 260 (7), 270 (0). Gamla v{rdet inom parentes.
17 REM Vidare {r utskriften anpassad via variabeln 'kol'.
18 REM En ny rad har inf|rts enligt ABC-bladet 1/84 s 21 f|r korr av skott}r.
19 REM Vidare {r utskriften n}got {ndrad med rubrik osv. samt 6 m}n/sida.
20 REM ================================================================
21 REM 
75 ; CHR$(12%) : EXTEND : FLOAT 
76 ; : ; : ; 
77 Kol=5
80 OPEN "PR:" AS FILE 1
85 ; ,"KALENDER"
86 ; ,"========"
90 ; : ; : ; 
95 ; ,"Vilket }r mellan 1600 och 2300 vill du"
96 ; ,"ha kalender utskriven f|r (ex 1985)";
100 ON ERROR GOTO 95
105 INPUT X$ : X=VAL(X$)
110 IF X<1600 OR X>2300 GOTO 95
111 ; : ; ,"[r PRINTERN inst{lld"; : INPUT Svar$ ! BM
112 IF Svar$="J" OR Svar$="j" GOTO 115 ELSE GOTO 111 ! BM
115 C=7
120 FOR I=1600 TO X
125   IF I=X THEN 155
130   IF I/4<>INT(I/4) THEN 150
135   IF (I-1700)*(I-1800)*(I-1900)*(I-2100)*(I-2200)*(I-2300)=0 THEN 150
140   C=C+2
145   GOTO 155
150   C=C+1
155   IF C<8 THEN 165
160   C=C-7
165 NEXT I 
170 ; #1 TAB(Kol) CHR$(14) CHR$(27,69) "KALENDER F\R" X
171 ; #1
172 ; #1 CHR$(27,56) "";
175 FOR M=1 TO 12
177   IF M=7 ; #1 CHR$(12) : GET S$ ! BM
185   READ M$
190   ; #1 TAB(Kol) CHR$(14);M$;"" X : ; CHR$(20)
200   READ D
205   IF X/4<>INT(X/4) THEN 220
207   IF X/100=INT(X/100) AND NOT (X/400=INT(X/400)) THEN 220 ! Mod enl ABC-blad
210   IF M$<>"FEBRUARI" THEN 220
215   LET D=D+1
220   REM 
225   ; #1 TAB(Kol) "========================================="
230   ; #1 TAB(Kol) "*S\N   M]N   TIS   ONS   TOR   FRE   L\R*"
245   FOR E=1 TO D
250     ; #1 TAB(6*C);E;
255     LET C=C+1
260     IF C<8 THEN 275
265     ; #1
270     C=1
275   NEXT E 
280   ; #1
295   ; #1
305 NEXT M 
310 DATA "JANUARI",31,"FEBRUARI",28,"MARS",31,"APRIL",30,"MAJ",31,"JUNI",30,"JULI",31,"AUGUSTI",31,"SEPTEMBER",30
315 DATA "OKTOBER",31,"NOVEMBER",30,"DECEMBER",31
316 ; #1 CHR$(12) ! Till{gg av BM
330 CLOSE 1
335 END