10 ! OOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOO
20 ! O PROGR: M\NSTER.800
30 ! O Ritar fina m|nster p} sk{rmen.
40 ! O 
50 ! O (c) Johan Hedin  #525
60 ! O Mod f|r ABC 800
70 ! O Kr{ver HR-grafik
80 ! O F|rmodligen l{tt att {ven
90 ! O skapa snygga f{rgbilder p} ABC 800C
100 ! O om f{rg 1 {ndras till annat 
110 ! O i ritsatserna 470-540
120 ! O P Svebeck #2635
130 ! OOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOO
140 S1=2 : D=16 ! Default storlek och dimension
150 ! 
160 RANDOMIZE 
170 FLOAT 
180 FGPOINT 0%,0%,0%
190 FGFILL 239%,239%,0%
200 FGCTL 3%
210 ; CHR$(12%)
220 FGCTL 0%
230 ; CUR(0%,10%) "***** M\NSTER Ver 1.1, 83-01-28 *****"
240 ; CUR(3%,10%) "AVSLUTA MED ------------------------ A"
250 ; CUR(4%,10%) "STOPPA P]G]ENDE RITNING MED -------- S"
260 ; CUR(5%,10%) "NY DIMENSION OCH BYGG P] ----------- B"
270 ; CUR(6%,10%) "FORTS[TT MED -----MELLANSLAGSTANGENTEN"
280 ; CUR(7%,10%) "NY BILD MED ------------------- RETURN"
290 ON ERROR GOTO 720
300 ; CUR(9%,10%) "Storlek (1-3):<" S1% "> "; : INPUT ""S$
310 IF LEN(S$)>0% THEN S1%=VAL(S$)
320 IF S1%=1% THEN D1%=68%
330 IF S1%=2% THEN D1%=139%
340 IF S1%=3% THEN D1%=210%
350 ; CUR(11%,10%) "DIMENSION ( 6 -";D1% "):<" D% "> "; : INPUT D$
360 IF LEN(D$)>0% THEN D%=VAL(D$)
370 R1%=71%*S1% : K1%=77%*S1%
380 FGCTL 3%
390 E%=D%/2%-1% : F%=2%
400 ; CHR$(12%);
410 FOR I%=0% TO 23%
420 ; CUR(I%,0%) CHR$(23%); : NEXT I% 
430 FOR R%=0% TO E% : FOR K%=0% TO R%
440     IF RND>.3 THEN 620
450     G%=1%+(R1%-R1%/(D%+3%)*(D%+3%))/2%
460     FOR T%=G% TO R1%-D%-G% STEP D%+3%
470       H%=(K1%-K1%/(D%+3%)*(D%+3%))/2%
480       FOR Y%=H% TO K1%-D%-H% STEP D%+3%
490         ! 
500         Z%=INP(34%)
510         IF Z%=83% OR Z%=115% THEN GOTO 640 ! K{nn efter om 's' har tryckts ned
520         FGPOINT R%+T%,K%+F%+Y%,1%
530         FGPOINT K%+T%,R%+F%+Y%,1%
540         FGPOINT R%+T%,D%-K%+F%+Y%,1%
550         FGPOINT K%+T%,D%-R%+F%+Y%,1%
560         FGPOINT D%-R%+T%,K%+F%+Y%,1%
570         FGPOINT D%-K%+T%,R%+F%+Y%,1%
580         FGPOINT D%-R%+T%,D%-K%+F%+Y%,1%
590         FGPOINT D%-K%+T%,D%-R%+F%+Y%,1%
600         ! 
610     NEXT Y% : NEXT T% 
620 NEXT K% : NEXT R% 
630 IF S%=1% THEN 690
640 S%=0% : ; CUR(0%,10%) "Kommando:>"; : GET A$
650 IF ASCII(A$)=63% THEN GOTO 210
660 IF ASCII(A$)=13% THEN GOTO 170
670 IF A$="A" OR A$="a" THEN GOTO 720
680 IF A$="B" OR A$="b" THEN GOTO 210 ELSE 400
690 POKE 32721%,160% : FOR I%=0% TO 2000% : NEXT I% 
700 S%=1% : IF PEEK(65507%)<>0% THEN 640
710 GOTO 400
720 ON ERROR GOTO 750
730 FGCTL 0%
740 CHAIN "RAM:RAMSTART"
750 ON ERROR GOTO 770 : IF ERRCODE=21% THEN CHAIN "START" ELSE ; "KAN INTE FORTS[TTA, FELKOD :";ERRCODE
760 END 
770 IF ERRCODE=21% THEN ; "Hittar inte CHAIN-filen RAM:START eller START"
780 END