2 ! +++++++++++++++++++++++++++++++++++
3 ! Program ....     ABCMINI.800
4 ! Utg}va  1.1      1982-01-16
5 ! av (c) Gunnar Tidner
6 ! Anpassat f|r ABC800 av Bo Kullmar
8 ! Ins{nt av Bo Kullmar, medl 1789.
9 ! Denna version fungerar b}de f|r optionsprom 7.1 och 7.2.
10 ! +++++++++++++++++++++++++++++++++++
20 EXTEND : FLOAT 
30 DIM Radin$=159%
40 Z$="/*" ! Filslutm{rke
50 ; 'Local mode!'
60 OPEN "V24:TEA70G72.22" AS FILE 1% : L%=1% ! Half Duplex
70 INPUT #L%,A$
80 IF A$="SYNK" THEN 100
90 ; A$ : IF LEN(A$)=0% THEN 50 ELSE 70
100 ; "Local mode!"
110 ; "  ***  Mottaga fil  ***"
120 POKE -30%,0%
130 ; "Filnamn vid MONITORN: "; : INPUT ''F1$
140 ; "Filnamn h{r: "; : INPUT ''F2$
150 ; #L%,"Hejsan"
160 INPUT #L%,Radin$
170 IF Radin$<>"SYNK" THEN 150
180 Z%=FNDelay%(100)
190 ; #L%,"SYNKSVAR"
200 Z%=FNDelay%(200)
210 ; #L%,F1$
220 INPUT LINE #L%,Radin$ : Radin$=LEFT$(Radin$,LEN(Radin$)-2%)
230 IF Radin$<>"OPENED" THEN ; Radin$ : ; : Z%=FNDelay%(2000) : GOTO 70
240 PREPARE F2$ AS FILE 2%
250 FOR I%=1% TO 10000%
260   Z%=FNDelay%(100)
270   ; #L%,'>'
280   INPUT LINE #L%,Radin$
290   IF LEFT$(Radin$,2%)=Z$ THEN 330
300   ; #2%,Radin$
310   ; 'Rad nr' I%
315   POKE -173%,PEEK(-173%)-1%
320 NEXT I% 
330 CLOSE 2%
340 ; "Antal rader =";I%-1%
350 ; CHR$(7%,7%); : ; "Tryck ner n}gon tangent" : GET \$
360 ; #L%,"Tack!"
370 GOTO 70
380 DEF FNDelay%(Y) LOCAL I
390   WHILE I<Y+1%
400     I=I+1
410   WEND 
420   RETURN 0%
430 FNEND